/[gentoo-x86]/dev-libs/libpcre/libpcre-8.21.ebuild
Gentoo

Contents of /dev-libs/libpcre/libpcre-8.21.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Fri May 25 16:39:29 2012 UTC (2 years, 10 months ago) by vapier
Branch: MAIN
Changes since 1.3: +2 -2 lines
Add missing inherits, and drop other unused ones.

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-libs/libpcre/libpcre-8.21.ebuild,v 1.3 2012/05/04 18:35:45 jdhore Exp $
4
5 EAPI="4"
6
7 inherit autotools eutils toolchain-funcs flag-o-matic libtool
8
9 DESCRIPTION="Perl-compatible regular expression library"
10 HOMEPAGE="http://www.pcre.org/"
11 MY_P="pcre-${PV/_rc/-RC}"
12 if [[ ${PV} != *_rc* ]] ; then
13 # Only the final releases are available here.
14 SRC_URI="mirror://sourceforge/pcre/${MY_P}.tar.bz2
15 ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/${MY_P}.tar.bz2"
16 else
17 SRC_URI="ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/Testing/${MY_P}.tar.bz2"
18 fi
19
20 LICENSE="BSD"
21 SLOT="3"
22 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
23 IUSE="bzip2 +cxx +jit +readline +recursion-limit static-libs unicode zlib"
24
25 RDEPEND="bzip2? ( app-arch/bzip2 )
26 zlib? ( sys-libs/zlib )
27 readline? ( sys-libs/readline )"
28 DEPEND="${RDEPEND}
29 virtual/pkgconfig
30 userland_GNU? ( >=sys-apps/findutils-4.4.0 )"
31
32 S=${WORKDIR}/${MY_P}
33
34 src_prepare() {
35 sed -i -e "s:-lpcre ::" libpcrecpp.pc.in || die
36 epatch "${FILESDIR}"/${P}-static-build.patch
37 # m4 dir isn't packaged, breaks aclocal
38 sed -i -e '/ACLOCAL_AMFLAGS/s/-I \?m4//' Makefile.am || die
39 eautoreconf # otherwise elibtoolize
40 }
41
42 src_configure() {
43 [[ ${CHOST} == *-mint* ]] && append-flags -D_GNU_SOURCE
44 econf \
45 --with-match-limit-recursion=$(use recursion-limit && echo 8192 || echo MATCH_LIMIT) \
46 $(use_enable unicode utf8) $(use_enable unicode unicode-properties) \
47 $(use_enable cxx cpp) \
48 $(use_enable zlib pcregrep-libz) \
49 $(use_enable bzip2 pcregrep-libbz2) \
50 $(use_enable static-libs static) \
51 $(use_enable jit) $(use_enable jit pcregrep-jit) \
52 $(use_enable readline pcretest-libreadline) \
53 --enable-shared \
54 --htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
55 --docdir="${EPREFIX}"/usr/share/doc/${PF}
56 }
57
58 src_install() {
59 emake DESTDIR="${D}" install
60 gen_usr_ldscript -a pcre
61 find "${D}" -type f -name '*.la' -exec rm -f {} +
62 }

  ViewVC Help
Powered by ViewVC 1.1.20