/[gentoo-x86]/dev-python/cython/cython-0.22.1.ebuild
Gentoo

Contents of /dev-python/cython/cython-0.22.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sun Jun 21 20:43:00 2015 UTC (4 years, 7 months ago) by jlec
Branch: MAIN
CVS Tags: HEAD
Version Bump

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/cython/cython-0.22.ebuild,v 1.9 2015/06/02 05:09:54 jmorgan Exp $
4
5 EAPI=5
6
7 PYTHON_COMPAT=( python2_7 python3_{3,4} )
8
9 inherit distutils-r1 flag-o-matic toolchain-funcs
10
11 MY_PN="Cython"
12 MY_P="${MY_PN}-${PV/_/}"
13
14 DESCRIPTION="A Python to C compiler"
15 HOMEPAGE="http://www.cython.org/ http://pypi.python.org/pypi/Cython"
16 SRC_URI="http://www.cython.org/release/${MY_P}.tar.gz"
17
18 LICENSE="Apache-2.0"
19 SLOT="0"
20 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
21 IUSE="doc examples test"
22
23 RDEPEND=""
24 # On testing, setuptools invokes an error in running the testsuite cited in a number of recent bugs
25 # spanning several packages. This bug has been fixed in the recent release of version 9.1
26 DEPEND="${RDEPEND}
27 >=dev-python/setuptools-9.1[${PYTHON_USEDEP}]
28 doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
29 test? ( dev-python/numpy[${PYTHON_USEDEP}] )"
30
31 S="${WORKDIR}/${MY_PN}-${PV%_*}"
32
33 python_compile() {
34 if ! python_is_python3; then
35 local CFLAGS="${CFLAGS}"
36 local CXXFLAGS="${CXXFLAGS}"
37 append-flags -fno-strict-aliasing
38 fi
39
40 # Python gets confused when it is in sys.path before build.
41 local PYTHONPATH=
42 export PYTHONPATH
43
44 distutils-r1_python_compile
45 }
46
47 python_compile_all() {
48 use doc && unset XDG_CONFIG_HOME && emake -C docs html
49 }
50
51 python_test() {
52 tc-export CC
53 "${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests \
54 || die "Tests fail with ${EPYTHON}"
55 }
56
57 python_install_all() {
58 local DOCS=( CHANGES.rst README.txt ToDo.txt USAGE.txt )
59 use doc && local HTML_DOCS=( docs/build/html/. )
60 use examples && local EXAMPLES=( Demos/. )
61 distutils-r1_python_install_all
62 }

  ViewVC Help
Powered by ViewVC 1.1.20