/[gentoo-x86]/dev-python/mwlib-rl/mwlib-rl-0.14.6.ebuild
Gentoo

Contents of /dev-python/mwlib-rl/mwlib-rl-0.14.6.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Wed Apr 8 08:05:14 2015 UTC (5 years, 3 months ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +3 -3 lines
Drop old Python implementations

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/mwlib-rl/mwlib-rl-0.14.6.ebuild,v 1.1 2014/06/06 14:11:10 dev-zero Exp $
4
5 EAPI="5"
6
7 PYTHON_COMPAT=( python2_7 )
8 PYTHON_REQ_USE="xml"
9
10 inherit distutils-r1
11
12 MY_PN="${PN/-/.}"
13 MY_P="${MY_PN}-${PV}"
14
15 DESCRIPTION="Generate pdfs from mediawiki markup"
16 HOMEPAGE="http://code.pediapress.com/code/ http://pypi.python.org/pypi/mwlib.rl https://github.com/pediapress/mwlib.rl/"
17 SRC_URI="https://github.com/pediapress/mwlib.rl/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
18
19 LICENSE="BSD"
20 SLOT="0"
21 KEYWORDS="~amd64 ~x86"
22 IUSE="test pdftk"
23
24 RDEPEND=">=dev-python/mwlib-0.15.8-r1[${PYTHON_USEDEP}]
25 >=dev-python/mwlib-ext-0.12.4-r1[${PYTHON_USEDEP}]
26 >=dev-python/pygments-1.4[${PYTHON_USEDEP}]
27 dev-python/simplejson[${PYTHON_USEDEP}]
28 dev-python/pillow[${PYTHON_USEDEP}]
29 media-fonts/freefont
30 || ( media-gfx/graphicsmagick[imagemagick] media-gfx/imagemagick )
31 pdftk? ( app-text/pdftk )"
32 DEPEND="${RDEPEND}
33 dev-python/setuptools[${PYTHON_USEDEP}]
34 app-arch/unzip
35 test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
36
37 S="${WORKDIR}/${MY_P}"
38
39 PATCHES=( "${FILESDIR}/0.14.3-use-system-fonts.patch" )
40 DOCS=( example-mwlib.config README.rst )
41
42 python_prepare_all() {
43 rm -r mwlib/fonts/freefont || die "removing bundled fonts failed"
44 distutils-r1_python_prepare_all
45 }
46
47 python_test() {
48 py.test || die "tests failed under ${EPYTHON}"
49 }
50
51 pkg_postinst() {
52 elog "If you need extended/non-lating rendering support, please install the"
53 elog "corresponding font packages:"
54 elog " - media-fonts/libertine-ttf"
55 elog " - media-fonts/sil-ezra"
56 elog " - media-fonts/farsi-fonts"
57 elog " - media-fonts/arphicfonts"
58 elog " - media-fonts/unfonts"
59 # TODO: need the following packages as well:
60 # ttf-indic-fonts ttf-gfs-artemisia ttf-thai-arundina
61 }

  ViewVC Help
Powered by ViewVC 1.1.20