/[gentoo-x86]/dev-python/numba/numba-0.20.0.ebuild
Gentoo

Contents of /dev-python/numba/numba-0.20.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Mon Jul 6 05:53:11 2015 UTC (5 years ago) by patrick
Branch: MAIN
CVS Tags: HEAD
Bump

(Portage version: 2.2.20/cvs/Linux x86_64, unsigned Manifest commit)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/numba/numba-0.19.2.ebuild,v 1.1 2015/06/28 10:06:51 idella4 Exp $
4
5 EAPI=5
6
7 # test phase is pointless since it errors in circa 60% of 1984 tests
8 RESTRICT="test"
9
10 PYTHON_COMPAT=( python{2_7,3_3,3_4} )
11
12 inherit distutils-r1
13
14 DESCRIPTION="NumPy aware dynamic Python compiler using LLVM"
15 HOMEPAGE="http://numba.pydata.org/"
16 SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
17
18 LICENSE="BSD"
19 SLOT="0"
20 KEYWORDS="~amd64 ~x86"
21
22 IUSE="doc examples test"
23
24 RDEPEND="
25 dev-python/llvmlite[${PYTHON_USEDEP}]
26 >=dev-python/numpy-1.6[${PYTHON_USEDEP}]
27 $(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python{2_7,3_3})
28 $(python_gen_cond_dep 'dev-python/funcsigs[${PYTHON_USEDEP}]' python2_7)"
29 DEPEND="test? ( ${RDEPEND} )
30 doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
31
32 # Delete intersphinx & entry to set sphinxjp.themecore, which is absent from portage, from conf.py
33 PATCHES=( "${FILESDIR}"/${PN}-0.19.2-docbuild.patch )
34
35 python_prepare_all() {
36 # Re-set them of doc build to one provided by sphinx
37 if has_version ">=dev-python/sphinx-1.3.1"; then
38 sed -e 's:basicstrap:classic:' -i docs/source/conf.py || die
39 else
40 sed -e 's:basicstrap:default:' -i docs/source/conf.py || die
41 fi
42 distutils-r1_python_prepare_all
43 }
44
45 python_compile() {
46 if ! python_is_python3; then
47 local CFLAGS="${CFLAGS} -fno-strict-aliasing"
48 export CFLAGS
49 fi
50 distutils-r1_python_compile
51 }
52
53 python_compile_all() {
54 use doc && emake -C docs/ html
55 }
56
57 python_test() {
58 cd "${BUILD_DIR}"/lib* || die
59 ${PYTHON} -c "import numba; numba.test()" || die
60 }
61
62 python_install_all() {
63 # doc needs obsolete sphinxjp package
64 # use doc && dodoc docs/Numba.pdf
65 use examples && local EXAMPLES=( examples/. )
66 use doc && local HTML_DOCS=( docs/_build/html/. )
67
68 distutils-r1_python_install_all
69 }

  ViewVC Help
Powered by ViewVC 1.1.20