/[gentoo-x86]/dev-python/pygments/pygments-1.6_p20140324.ebuild
Gentoo

Contents of /dev-python/pygments/pygments-1.6_p20140324.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.9 - (show annotations) (download)
Fri Oct 31 16:09:05 2014 UTC (6 years, 1 month ago) by ago
Branch: MAIN
Changes since 1.8: +2 -2 lines
Stable for ppc64, wrt bug #524416

(Portage version: 2.2.8-r2/cvs/Linux x86_64, RepoMan options: --include-arches="ppc64", signed Manifest commit with key 7194459F)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/pygments/pygments-1.6_p20140324.ebuild,v 1.8 2014/10/16 18:27:28 maekke Exp $
4
5 EAPI=5
6 PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3,3_4} pypy pypy2_0 )
7
8 inherit distutils-r1 bash-completion-r1 vcs-snapshot
9
10 MY_PN="Pygments"
11 MY_P="${MY_PN}-${PV}"
12
13 DESCRIPTION="Pygments is a syntax highlighting package written in Python"
14 HOMEPAGE="http://pygments.org/ http://pypi.python.org/pypi/Pygments"
15 #SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
16 SRC_URI="https://bitbucket.org/birkenfeld/pygments-main/get/b839f47dbb3a10830db7dc3114f0ad4f470bcfa5.tar.gz -> ${P}.tar.gz"
17
18 LICENSE="BSD"
19 SLOT="0"
20 KEYWORDS="~alpha ~amd64 arm hppa ~ia64 ~mips ~ppc ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
21 IUSE="doc test"
22
23 RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
24 DEPEND="${RDEPEND}
25 doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
26 test? (
27 dev-python/nose[${PYTHON_USEDEP}]
28 virtual/ttf-fonts
29 dev-texlive/texlive-latexrecommended
30 )"
31
32 #S="${WORKDIR}/${MY_P}"
33
34 python_compile() {
35 distutils-r1_python_compile
36 if [[ ${EPYTHON} == python3.2 ]]; then
37 # python3.2 does not like u"" literals
38 2to3 --no-diffs -n -w -f unicode "${BUILD_DIR}/lib" || die
39 fi
40 }
41
42 python_compile_all() {
43 use doc && emake -C doc html
44 }
45
46 python_test() {
47 cp -r -l tests "${BUILD_DIR}"/ || die
48
49 if python_is_python3; then
50 # Notes:
51 # -W is not supported by python3.1
52 # -n causes Python to write into hardlinked files
53 2to3 --no-diffs -w "${BUILD_DIR}"/tests/*.py || die
54 fi
55
56 nosetests -w "${BUILD_DIR}"/tests || die "Tests fail with ${EPYTHON}"
57 }
58
59 python_install_all() {
60 use doc && local HTML_DOCS=( doc/_build/html/. )
61
62 distutils-r1_python_install_all
63 newbashcomp external/pygments.bashcomp ${PN}
64 }

  ViewVC Help
Powered by ViewVC 1.1.20