/[gentoo-x86]/dev-python/pylint/pylint-1.4.3.ebuild
Gentoo

Contents of /dev-python/pylint/pylint-1.4.3.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Sun Mar 22 08:12:18 2015 UTC (5 years, 3 months ago) by patrick
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +2 -2 lines
Fix astroid dep, remove old

(Portage version: 2.2.18/cvs/Linux x86_64, unsigned Manifest commit)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/pylint/pylint-1.4.3.ebuild,v 1.1 2015/03/19 05:28:35 patrick Exp $
4
5 EAPI=5
6
7 PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
8
9 inherit distutils-r1
10
11 RESTRICT="test" # needs pygtk
12
13 DESCRIPTION="Python code static checker"
14 HOMEPAGE="http://www.logilab.org/project/pylint http://pypi.python.org/pypi/pylint"
15 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
16
17 LICENSE="GPL-2"
18 SLOT="0"
19 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
20 IUSE="doc examples test"
21
22 RDEPEND="
23 >=dev-python/logilab-common-0.53.0[${PYTHON_USEDEP}]
24 >=dev-python/astroid-1.3.6[${PYTHON_USEDEP}]
25 dev-python/six[${PYTHON_USEDEP}]"
26 DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
27 doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
28 test? ( ${RDEPEND} )"
29
30 # Usual. Requ'd for impl specific failures in test phase
31 DISTUTILS_IN_SOURCE_BUILD=1
32
33 python_compile_all() {
34 # selection of straight html triggers a trivial annoying bug, we skirt it
35 use doc && emake -C doc singlehtml
36 }
37
38 python_test() {
39 # Test suite appears not to work under Python 3.
40 # https://bitbucket.org/logilab/pylint/issue/240/
41 local msg="Test suite broken with ${EPYTHON}"
42 if python_is_python3; then
43 einfo "${msg}"
44 return 0
45 fi
46
47 pytest || die "Tests failed under ${EPYTHON}"
48 }
49
50 python_install_all() {
51 doman man/{pylint,pyreverse}.1
52 use examples && local EXAMPLES=( examples/. )
53 use doc && local HTML_DOCS=( doc/_build/singlehtml/. )
54 distutils-r1_python_install_all
55 }
56
57 pkg_postinst() {
58 # Optional dependency on "tk" USE flag would break support for Jython.
59 elog "pylint-gui script requires dev-lang/python with \"tk\" USE flag enabled."
60 }

  ViewVC Help
Powered by ViewVC 1.1.20