/[gentoo-x86]/dev-python/pyside/pyside-1.2.2-r1.ebuild
Gentoo

Contents of /dev-python/pyside/pyside-1.2.2-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Mon Jun 15 15:20:24 2015 UTC (3 years, 2 months ago) by pesa
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +2 -2 lines
Mark stable on all arches to fix build on stable systems, see bug 530764.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0xDADED6B2671CB57D!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/pyside-1.2.2-r1.ebuild,v 1.1 2015/03/22 04:22:21 yngwin Exp $
4
5 EAPI=5
6
7 PYTHON_COMPAT=( python{2_7,3_3,3_4} )
8
9 inherit cmake-utils multilib python-r1 virtualx
10
11 MY_P="${PN}-qt4.8+${PV}"
12
13 DESCRIPTION="Python bindings for the Qt framework"
14 HOMEPAGE="http://qt-project.org/wiki/PySide"
15 SRC_URI="http://download.qt-project.org/official_releases/${PN}/${MY_P}.tar.bz2"
16
17 LICENSE="LGPL-2.1"
18 SLOT="0"
19 KEYWORDS="amd64 arm ppc ~ppc64 x86 ~amd64-linux ~x86-linux"
20
21 IUSE="X declarative designer help multimedia opengl phonon script scripttools sql svg test webkit xmlpatterns"
22 REQUIRED_USE="
23 ${PYTHON_REQUIRED_USE}
24 declarative? ( X )
25 designer? ( X )
26 help? ( X )
27 multimedia? ( X )
28 opengl? ( X )
29 phonon? ( X )
30 scripttools? ( X script )
31 sql? ( X )
32 svg? ( X )
33 test? ( X )
34 webkit? ( X )
35 "
36
37 # Minimal supported version of Qt.
38 QT_PV="4.8.5:4"
39
40 RDEPEND="
41 ${PYTHON_DEPS}
42 >=dev-python/shiboken-${PV}[${PYTHON_USEDEP}]
43 >=dev-qt/qtcore-${QT_PV}
44 X? (
45 >=dev-qt/qtgui-${QT_PV}[accessibility]
46 >=dev-qt/qttest-${QT_PV}
47 )
48 declarative? ( >=dev-qt/qtdeclarative-${QT_PV} )
49 designer? ( >=dev-qt/designer-${QT_PV} )
50 help? ( >=dev-qt/qthelp-${QT_PV} )
51 multimedia? ( >=dev-qt/qtmultimedia-${QT_PV} )
52 opengl? ( >=dev-qt/qtopengl-${QT_PV} )
53 phonon? ( || (
54 media-libs/phonon[qt4(+)]
55 >=dev-qt/qtphonon-${QT_PV}
56 ) )
57 script? ( >=dev-qt/qtscript-${QT_PV} )
58 sql? ( >=dev-qt/qtsql-${QT_PV} )
59 svg? ( >=dev-qt/qtsvg-${QT_PV}[accessibility] )
60 webkit? ( >=dev-qt/qtwebkit-${QT_PV} )
61 xmlpatterns? ( >=dev-qt/qtxmlpatterns-${QT_PV} )
62 "
63 DEPEND="${RDEPEND}
64 >=dev-qt/qtgui-${QT_PV}
65 "
66
67 S=${WORKDIR}/${MY_P}
68
69 DOCS=( ChangeLog )
70
71 src_prepare() {
72 # Fix generated pkgconfig file to require the shiboken
73 # library suffixed with the correct python version.
74 sed -i -e '/^Requires:/ s/shiboken$/&@SHIBOKEN_PYTHON_SUFFIX@/' \
75 libpyside/pyside.pc.in || die
76
77 if use prefix; then
78 cp "${FILESDIR}"/rpath.cmake . || die
79 sed -i -e '1iinclude(rpath.cmake)' CMakeLists.txt || die
80 fi
81
82 epatch "${FILESDIR}/qgtkstyle-${PV}.patch" # bug 530764
83
84 cmake-utils_src_prepare
85 }
86
87 src_configure() {
88 local mycmakeargs=(
89 $(cmake-utils_use_build test TESTS)
90 $(cmake-utils_use_disable X QtGui)
91 $(cmake-utils_use_disable X QtTest)
92 $(cmake-utils_use_disable declarative QtDeclarative)
93 $(cmake-utils_use_disable designer QtDesigner)
94 $(cmake-utils_use_disable designer QtUiTools)
95 $(cmake-utils_use_disable help QtHelp)
96 $(cmake-utils_use_disable multimedia QtMultimedia)
97 $(cmake-utils_use_disable opengl QtOpenGL)
98 $(cmake-utils_use_disable phonon)
99 $(cmake-utils_use_disable script QtScript)
100 $(cmake-utils_use_disable scripttools QtScriptTools)
101 $(cmake-utils_use_disable sql QtSql)
102 $(cmake-utils_use_disable svg QtSvg)
103 $(cmake-utils_use_disable webkit QtWebKit)
104 $(cmake-utils_use_disable xmlpatterns QtXmlPatterns)
105 )
106
107 if use phonon && has_version "media-libs/phonon[qt4(+)]"; then
108 # bug 475786
109 mycmakeargs+=(
110 -DQT_PHONON_INCLUDE_DIR="${EPREFIX}/usr/include/phonon"
111 -DQT_PHONON_LIBRARY_RELEASE="${EPREFIX}/usr/$(get_libdir)/libphonon.so"
112 )
113 fi
114
115 configuration() {
116 local mycmakeargs=(
117 -DPYTHON_SUFFIX="-${EPYTHON}"
118 "${mycmakeargs[@]}"
119 )
120 cmake-utils_src_configure
121 }
122 python_foreach_impl configuration
123 }
124
125 src_compile() {
126 python_foreach_impl cmake-utils_src_compile
127 }
128
129 src_test() {
130 local PYTHONDONTWRITEBYTECODE
131 export PYTHONDONTWRITEBYTECODE
132
133 VIRTUALX_COMMAND="cmake-utils_src_test" python_foreach_impl virtualmake
134 }
135
136 src_install() {
137 installation() {
138 cmake-utils_src_install
139 mv "${ED}"usr/$(get_libdir)/pkgconfig/${PN}{,-${EPYTHON}}.pc || die
140 }
141 python_foreach_impl installation
142 }

  ViewVC Help
Powered by ViewVC 1.1.20