/[gentoo-x86]/dev-python/qscintilla-python/qscintilla-python-2.9.ebuild
Gentoo

Contents of /dev-python/qscintilla-python/qscintilla-python-2.9.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Sat Jul 25 00:08:23 2015 UTC (4 years, 11 months ago) by pesa
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +2 -2 lines
Update HOMEPAGE.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0xDADED6B2671CB57D!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/qscintilla-python-2.9.ebuild,v 1.1 2015/04/30 13:50:25 pesa Exp $
4
5 EAPI=5
6 PYTHON_COMPAT=( python{2_7,3_3,3_4} )
7
8 inherit python-r1 qmake-utils
9
10 MY_P=QScintilla-gpl-${PV}
11
12 DESCRIPTION="Python bindings for Qscintilla"
13 HOMEPAGE="http://www.riverbankcomputing.com/software/qscintilla/intro"
14 SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
15
16 LICENSE="|| ( GPL-2 GPL-3 )"
17 SLOT="0"
18 KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
19 IUSE="debug"
20
21 DEPEND="
22 ${PYTHON_DEPS}
23 >=dev-python/sip-4.16:=[${PYTHON_USEDEP}]
24 >=dev-python/PyQt4-4.11.3[X,${PYTHON_USEDEP}]
25 dev-qt/qtcore:4
26 dev-qt/qtgui:4
27 ~x11-libs/qscintilla-${PV}:=
28 "
29 RDEPEND="${DEPEND}"
30
31 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
32
33 S=${WORKDIR}/${MY_P}/Python
34
35 src_prepare() {
36 python_copy_sources
37 }
38
39 src_configure() {
40 configuration() {
41 local myconf=(
42 "${PYTHON}" configure.py
43 --qmake="$(qt4_get_bindir)"/qmake
44 --destdir="$(python_get_sitedir)"/PyQt4
45 --sip-incdir="$(python_get_includedir)"
46 --pyqt=PyQt4
47 --no-timestamp
48 $(use debug && echo --debug)
49 )
50 echo "${myconf[@]}"
51 "${myconf[@]}" || die
52
53 # Run eqmake4 to respect toolchain, build flags, and prevent stripping
54 eqmake4
55 }
56 python_foreach_impl run_in_build_dir configuration
57 }
58
59 src_compile() {
60 python_foreach_impl run_in_build_dir default
61 }
62
63 src_install() {
64 installation() {
65 emake INSTALL_ROOT="${D}" install
66 python_optimize
67 }
68 python_foreach_impl run_in_build_dir installation
69 }

  ViewVC Help
Powered by ViewVC 1.1.20