/[gentoo-x86]/dev-python/subunit/subunit-0.0.21-r1.ebuild
Gentoo

Contents of /dev-python/subunit/subunit-0.0.21-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.6 - (show annotations) (download)
Tue Apr 14 12:51:23 2015 UTC (5 years, 2 months ago) by ago
Branch: MAIN
CVS Tags: HEAD
Changes since 1.5: +2 -2 lines
Stable for ia64, wrt bug #540290

(Portage version: 2.2.14/cvs/Linux x86_64, RepoMan options: --include-arches="ia64", signed Manifest commit with key 7194459F)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/subunit/subunit-0.0.21-r1.ebuild,v 1.5 2015/04/13 09:09:32 ago Exp $
4
5 EAPI=5
6
7 PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
8
9 inherit distutils-r1 eutils multilib-minimal
10
11 DESCRIPTION="A streaming protocol for test results"
12 HOMEPAGE="https://launchpad.net/subunit http://pypi.python.org/pypi/python-subunit"
13 SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
14
15 LICENSE="Apache-2.0 BSD"
16 SLOT="0"
17 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 x86 ~x86-fbsd"
18 IUSE="static-libs test"
19
20 RDEPEND=">=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
21 dev-python/extras[${PYTHON_USEDEP}]"
22 DEPEND="${RDEPEND}
23 dev-python/setuptools[${PYTHON_USEDEP}]
24 dev-lang/perl:=
25 >=dev-libs/check-0.9.11[${MULTILIB_USEDEP}]
26 >=dev-util/cppunit-1.13.2[${MULTILIB_USEDEP}]
27 >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
28 test? ( dev-python/testscenarios[${PYTHON_USEDEP}] )"
29
30 # Take out rogue & trivial failing tests that exit the suite before it even gets started
31 PATCHES=( "${FILESDIR}"/${PV}-tests.patch )
32
33 src_prepare() {
34 sed -i -e 's/os.chdir(os.path.dirname(__file__))//' setup.py || die
35
36 # Install perl modules in vendor_perl, bug 534654.
37 export INSTALLDIRS=vendor
38
39 # needed for perl modules
40 distutils-r1_src_prepare
41 multilib_copy_sources
42 }
43
44 multilib_src_configure() {
45 ECONF_SOURCE=${S} \
46 econf \
47 --enable-shared \
48 $(use_enable static-libs static)
49 }
50
51 multilib_src_compile() {
52 default
53 multilib_is_native_abi && distutils-r1_src_compile
54 }
55
56 python_test() {
57 local -x PATH="${PWD}/shell/share:${PATH}"
58 local -x PYTHONPATH=python
59 "${PYTHON}" -m testtools.run all_tests.test_suite || die "Testing failed with ${EPYTHON}"
60 }
61
62 multilib_src_test() {
63 multilib_is_native_abi && distutils-r1_src_test
64 }
65
66 multilib_src_install() {
67 local targets=(
68 install-include_subunitHEADERS
69 install-pcdataDATA
70 install-exec-local
71 install-libLTLIBRARIES
72 )
73 emake DESTDIR="${D}" "${targets[@]}"
74
75 multilib_is_native_abi && distutils-r1_src_install
76 }
77
78 multilib_src_install_all() {
79 einstalldocs
80 prune_libtool_files
81 }

  ViewVC Help
Powered by ViewVC 1.1.20