/[gentoo-x86]/games-kids/gcompris/gcompris-14.12.ebuild
Gentoo

Contents of /games-kids/gcompris/gcompris-14.12.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Wed Feb 25 15:54:55 2015 UTC (3 years, 2 months ago) by ago
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +2 -2 lines
Stable for x86, wrt bug #540436

(Portage version: 2.2.14/cvs/Linux x86_64, RepoMan options: --include-arches="x86", signed Manifest commit with key 7194459F)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/games-kids/gcompris/gcompris-14.12.ebuild,v 1.4 2015/02/21 12:30:55 ago Exp $
4
5 EAPI=5
6 PYTHON_COMPAT=( python2_7 )
7 PYTHON_REQ_USE="sqlite,threads"
8
9 inherit autotools eutils python-single-r1 games
10
11 DESCRIPTION="full featured educational application for children from 2 to 10"
12 HOMEPAGE="http://gcompris.net/"
13 SRC_URI="http://gcompris.net/download/${P}.tar.bz2"
14
15 LICENSE="GPL-3+"
16 SLOT="0"
17 KEYWORDS="amd64 ppc x86"
18 IUSE="gstreamer"
19 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
20
21 RDEPEND="x11-libs/gtk+:2
22 gnome-base/librsvg[gtk(+)]
23 gstreamer? (
24 media-libs/gstreamer:0.10
25 media-libs/gst-plugins-good:0.10
26 media-plugins/gst-plugins-ogg:0.10
27 media-plugins/gst-plugins-alsa:0.10
28 media-plugins/gst-plugins-vorbis:0.10 )
29 !gstreamer? (
30 media-libs/sdl-mixer
31 media-libs/libsdl:0 )
32 dev-libs/libxml2
33 dev-libs/popt
34 virtual/libintl
35 dev-db/sqlite:3
36 dev-python/pygtk[${PYTHON_USEDEP}]"
37 DEPEND="${RDEPEND}
38 gnome-base/gnome-common
39 dev-perl/XML-Parser
40 sys-devel/gettext
41 sys-apps/texinfo
42 app-text/texi2html
43 virtual/pkgconfig"
44 RDEPEND="${RDEPEND}
45 media-gfx/tuxpaint
46 sci-electronics/gnucap"
47
48 pkg_setup() {
49 python-single-r1_pkg_setup
50 games_pkg_setup
51 }
52
53 src_prepare() {
54 # Drop DEPRECATED flags, bug #387817
55 sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' \
56 src/gcompris/Makefile.am || die
57
58 epatch "${FILESDIR}"/${P}-build.patch
59 cp /usr/share/gettext/config.rpath .
60 eautoreconf
61 sed -i \
62 -e 's#^itlocaledir =.*$#itlocaledir = @localedir@#' \
63 po/Makefile.in.in || die
64
65 # Fix desktop files
66 sed -i \
67 -e '/Encoding/d' \
68 gcompris.desktop.in \
69 gcompris-edit.desktop.in || die
70 }
71
72 src_configure() {
73 GNUCHESS="${GAMES_BINDIR}/gcompris-gnuchess" \
74 egamesconf \
75 --datarootdir="${GAMES_DATADIR}" \
76 --datadir="${GAMES_DATADIR}" \
77 --localedir=/usr/share/locale \
78 --infodir=/usr/share/info \
79 --with-python="${PYTHON}" \
80 $(use_enable !gstreamer sdlmixer) \
81 --enable-sqlite \
82 --enable-py-build-only
83 }
84
85 src_install() {
86 default
87 prune_libtool_files --modules
88 prepgamesdirs
89 }

  ViewVC Help
Powered by ViewVC 1.1.20