/[gentoo-x86]/games-puzzle/enigma/enigma-1.21.ebuild
Gentoo

Contents of /games-puzzle/enigma/enigma-1.21.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Tue Mar 24 14:52:40 2015 UTC (4 years, 9 months ago) by mr_bones_
Branch: MAIN
CVS Tags: HEAD
Changes since 1.3: +2 -2 lines
mark stable; clean old

(Portage version: 2.2.14/cvs/Linux x86_64, unsigned Manifest commit)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/games-puzzle/enigma/enigma-1.21.ebuild,v 1.3 2015/03/12 10:07:11 ago Exp $
4
5 EAPI=5
6 inherit autotools eutils gnome2-utils games
7
8 DESCRIPTION="puzzle game similar to Oxyd"
9 HOMEPAGE="http://www.nongnu.org/enigma/"
10 SRC_URI="mirror://sourceforge/enigma-game/${P}.tar.gz"
11
12 LICENSE="GPL-2+"
13 SLOT="0"
14 KEYWORDS="amd64 ~ppc x86"
15 IUSE="nls"
16
17 COMMON_DEPS="media-libs/sdl-ttf
18 media-libs/libsdl[video]
19 media-libs/sdl-mixer
20 media-libs/sdl-image[jpeg,png]
21 media-libs/libpng:0=
22 sys-libs/zlib
23 net-misc/curl
24 || ( >=dev-libs/xerces-c-3[icu] >=dev-libs/xerces-c-3[-icu,-iconv] )
25 net-libs/enet
26 nls? ( virtual/libintl )"
27 DEPEND="${COMMON_DEPS}
28 sys-devel/gettext"
29 RDEPEND="${COMMON_DEPS}
30 media-fonts/dejavu
31 media-fonts/ttf-bitstream-vera
32 x11-misc/xdg-utils"
33
34 src_prepare() {
35 cp /usr/share/gettext/config.rpath .
36 epatch "${FILESDIR}"/${P}-build.patch
37 sed -i \
38 -e "s:DOCDIR:\"/usr/share/doc/${P}/html\":" \
39 src/main.cc || die
40 eautoreconf
41 }
42
43 src_configure() {
44 egamesconf \
45 --with-system-enet \
46 $(use_enable nls)
47 }
48
49 src_install() {
50 DOCS="ACKNOWLEDGEMENTS AUTHORS CHANGES README doc/HACKING" \
51 default
52 dosym \
53 /usr/share/fonts/dejavu/DejaVuSansCondensed.ttf \
54 "${GAMES_DATADIR}"/${PN}/fonts/DejaVuSansCondensed.ttf
55 dosym \
56 /usr/share/fonts/ttf-bitstream-vera/Vera.ttf \
57 "${GAMES_DATADIR}"/${PN}/fonts/vera_sans.ttf
58 dohtml -r doc/*
59 doman doc/enigma.6
60 prepgamesdirs
61 }
62
63 pkg_preinst() {
64 games_pkg_preinst
65 gnome2_icon_savelist
66 }
67
68 pkg_postinst() {
69 games_pkg_postinst
70 gnome2_icon_cache_update
71 }
72
73 pkg_postrm() {
74 gnome2_icon_cache_update
75 }

  ViewVC Help
Powered by ViewVC 1.1.20