/[gentoo-x86]/games-rpg/a-bird-story/a-bird-story-20141106.ebuild
Gentoo

Contents of /games-rpg/a-bird-story/a-bird-story-20141106.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Fri Nov 14 17:31:22 2014 UTC (5 years, 2 months ago) by hasufell
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +2 -2 lines
update licenses

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/games-rpg/a-bird-story/a-bird-story-20141106.ebuild,v 1.1 2014/11/14 17:18:19 hasufell Exp $
4
5 EAPI=5
6
7 inherit eutils unpacker multilib gnome2-utils games
8 MY_PN=ABirdStory
9 DESCRIPTION="Indie adventure short of a boy's memories, dream, and imagination"
10 HOMEPAGE="http://freebirdgames.com/games/a-bird-story/"
11 SRC_URI="${MY_PN}-${PV:0:4}-${PV:4:2}-${PV:6:2}.sh"
12
13 # missing: SIL, Xiph
14 # physfs ZLIB
15 # sdl-sound LGPL-2.1
16 LICENSE="all-rights-reserved BSD OFL-1.1 LGPL-2.1 ZLIB bundled-libs? ( FTL GPL-2 MIT ( || ( Ruby-BSD BSD-2 ) ) )"
17 SLOT="0"
18 KEYWORDS="~amd64 ~x86"
19 IUSE="bundled-libs"
20 RESTRICT="fetch bindist splitdebug"
21
22 QA_PREBUILT="${GAMES_PREFIX_OPT}/${PN}/${MY_PN}.bin*"
23 if [[ ${ARCH} == "amd64" ]] ; then
24 QA_PREBUILT="${QA_PREBUILT} ${GAMES_PREFIX_OPT}/${PN}/lib64/*"
25 else
26 QA_PREBUILT="${QA_PREBUILT} ${GAMES_PREFIX_OPT}/${PN}/lib/*"
27 fi
28
29 RDEPEND="
30 !bundled-libs? (
31 dev-games/physfs
32 dev-lang/ruby:2.1
33 dev-libs/libsigc++:2
34 >=media-libs/libsdl2-2.0.1[X,joystick,opengl,sound,threads,video]
35 media-libs/libvorbis
36 media-libs/openal
37 media-libs/sdl2-image[png]
38 media-libs/sdl2-ttf
39 sys-libs/zlib
40 x11-libs/pixman
41 )
42 virtual/opengl"
43
44 S=${WORKDIR}/data
45
46 pkg_nofetch() {
47 einfo
48 einfo "Please buy & download \"${SRC_URI}\" from:"
49 einfo " ${HOMEPAGE}"
50 einfo "and move/link it to \"${DISTDIR}\""
51 einfo
52 }
53
54 src_unpack() {
55 # mojo stuff inside makeself archive, unpack_makeself fails
56 local lastline=$(( $(grep -a -h -n -m 1 -F -e "Extra newline, because in very rare cases (OpenSolaris) stub is directly added after script" "${DISTDIR}/${A}" | cut -d':' -f1) + 1 ))
57 [[ ${lastline} ]] || die "no last line"
58 local offset=$(head -n ${lastline} "${DISTDIR}/${A}" | wc -c)
59 [[ ${offset} ]] || die "no offset"
60 dd ibs=${offset} skip=1 if="${DISTDIR}/${A}" of="${T}"/bird.zip || die
61 unpack_zip "${T}"/bird.zip
62 }
63
64 src_install() {
65 local dir=${GAMES_PREFIX_OPT}/${PN}
66 local arch=$(usex amd64 "x86_64" "x86")
67
68 insinto "${dir}"
69 doins -r noarch/*
70
71 exeinto "${dir}"
72 doexe ${arch}/${MY_PN}.$(usex amd64 "amd64" "x86")
73
74 exeinto "${dir}/$(get_libdir)"
75 if use bundled-libs ; then
76 doexe ${arch}/$(get_libdir)/*
77 else
78 doexe ${arch}/$(get_libdir)/{libsteam_api.so,libphysfs.so.1,libSDL_sound-1.0.so.1}
79 fi
80
81 games_make_wrapper ${PN} \
82 "./${MY_PN}.$(usex amd64 "amd64" "x86")" \
83 "${dir}" "${dir}/$(get_libdir)"
84 make_desktop_entry ${PN} "A bird story"
85 newicon -s 48 noarch/icon.png ${PN}.png
86
87 prepgamesdirs
88 }
89
90 pkg_preinst() {
91 games_pkg_preinst
92 gnome2_icon_savelist
93 }
94
95 pkg_postinst() {
96 games_pkg_postinst
97 gnome2_icon_cache_update
98 }
99
100 pkg_postrm() {
101 gnome2_icon_cache_update
102 }

  ViewVC Help
Powered by ViewVC 1.1.20