/[gentoo-x86]/gnome-base/gnome-applets/gnome-applets-3.6.0-r1.ebuild
Gentoo

Contents of /gnome-base/gnome-applets/gnome-applets-3.6.0-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Wed Dec 25 10:04:52 2013 UTC (5 years, 5 months ago) by pacho
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +1 -1 lines
FILE REMOVED
Drop old and a version that can no longer be used due 3.6 removal

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-applets/gnome-applets-3.6.0-r1.ebuild,v 1.4 2013/09/08 17:04:29 eva Exp $
4
5 EAPI="5"
6 GCONF_DEBUG="no"
7 GNOME2_LA_PUNT="no" # bug 340725, no other la files
8 PYTHON_COMPAT=( python2_{6,7} )
9
10 inherit eutils gnome2 python-single-r1
11
12 DESCRIPTION="Applets for the GNOME Desktop and Panel"
13 HOMEPAGE="http://www.gnome.org/"
14
15 LICENSE="GPL-2 FDL-1.1 LGPL-2"
16 SLOT="0"
17 IUSE="+cpufreq gnome ipv6 networkmanager policykit"
18 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
19 # 3.6 is tagged in upstream git, but the tarballs have not been uploaded :/
20 SRC_URI="http://dev.gentoo.org/~tetromino/distfiles/${PN}/${P}-unofficial.tar.xz"
21
22 # null applet still needs bonobo support for gnome-panel?
23 #
24 # Latest gnome-panel needed due to commit 45a4988a6
25 # atk, cairo, pango used in multiple applets
26 RDEPEND="
27 >=x11-libs/gtk+-3.0.0:3
28 dev-libs/atk
29 >=dev-libs/glib-2.22:2
30 >=gnome-base/gconf-2.8:2
31 >=gnome-base/gnome-panel-2.91.91
32 x11-libs/cairo
33 >=x11-libs/libxklavier-4
34 >=x11-libs/libwnck-2.91.0:3
35 >=x11-libs/libnotify-0.7:=
36 x11-libs/pango
37 >=sys-apps/dbus-1.1.2
38 >=dev-libs/dbus-glib-0.74
39 >=dev-libs/libxml2-2.5
40 >=x11-themes/gnome-icon-theme-2.15.91
41 =dev-libs/libgweather-3.6*:=
42 x11-libs/libX11
43
44 cpufreq? ( sys-power/cpufrequtils )
45 gnome? (
46 gnome-base/gnome-settings-daemon
47
48 >=gnome-extra/gucharmap-2.33.0:2.90
49 >=gnome-base/libgtop-2.11.92
50
51 ${PYTHON_DEPS}
52 dev-python/pygobject:3[${PYTHON_USEDEP}]
53 gnome-base/gconf[introspection]
54 gnome-base/gnome-panel[introspection]
55 x11-libs/gdk-pixbuf[introspection]
56 x11-libs/gtk+:3[introspection]
57 x11-libs/pango[introspection] )
58 networkmanager? ( >=net-misc/networkmanager-0.7.0 )
59 policykit? ( >=sys-auth/polkit-0.92 )
60 "
61 DEPEND="${RDEPEND}
62 app-text/docbook-xml-dtd:4.1.2
63 app-text/docbook-xml-dtd:4.3
64 >=app-text/gnome-doc-utils-0.3.2
65 >=app-text/scrollkeeper-0.1.4
66 >=dev-util/intltool-0.35
67 dev-libs/libxslt
68 virtual/pkgconfig
69 "
70
71 src_prepare() {
72 # Remove silly check for pygobject:2
73 # https://bugzilla.gnome.org/show_bug.cgi?id=660550
74 sed -e 's/pygobject-2.0/pygobject-3.0/' -i configure || die "sed failed"
75 gnome2_src_prepare
76 }
77
78 src_configure() {
79 # We don't want HAL or battstat.
80 # mixer applet uses gstreamer, conflicts with the mixer provided by g-s-d
81 # GNOME 3 has a hard-dependency on pulseaudio, so gstmixer applet is useless
82 gnome2_src_configure \
83 --without-hal \
84 --disable-battstat \
85 --disable-mixer-applet \
86 $(use_enable ipv6) \
87 $(use_enable networkmanager) \
88 $(use_enable policykit polkit) \
89 $(usex cpufreq "" --disable-cpufreq)
90 }
91
92 src_test() {
93 unset DBUS_SESSION_BUS_ADDRESS
94 default
95 }
96
97 src_install() {
98 python_fix_shebang invest-applet
99
100 gnome2_src_install
101
102 local APPLETS="accessx-status charpick cpufreq drivemount geyes
103 gweather invest-applet mini-commander
104 multiload null_applet stickynotes trashapplet"
105
106 # mixer is out because gnome3 uses pulseaudio
107 # modemlights is out because it needs system-tools-backends-1
108 # battstat is disabled because we don't want HAL anywhere
109
110 for applet in ${APPLETS} ; do
111 docinto ${applet}
112
113 for d in AUTHORS ChangeLog NEWS README README.themes TODO ; do
114 [ -s ${applet}/${d} ] && dodoc ${applet}/${d}
115 done
116 done
117 }

  ViewVC Help
Powered by ViewVC 1.1.20