/[gentoo-x86]/gnome-base/gnome-panel/gnome-panel-2.26.2.ebuild
Gentoo

Contents of /gnome-base/gnome-panel/gnome-panel-2.26.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Mon Nov 2 21:52:22 2009 UTC (9 years, 7 months ago) by eva
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +1 -1 lines
FILE REMOVED
New version for GNOME 2.28.
(Portage version: 2.2_rc48/cvs/Linux x86_64)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.26.2.ebuild,v 1.2 2009/06/03 23:09:10 eva Exp $
4
5 EAPI="2"
6 GCONF_DEBUG="no"
7
8 inherit autotools eutils gnome2
9
10 MY_P="${PN}-2.24.2"
11 MY_P_PO="${PN}-2.26.1"
12 DESCRIPTION="The GNOME panel"
13 HOMEPAGE="http://www.gnome.org/"
14 SRC_URI="${SRC_URI}
15 mirror://gentoo/${MY_P}-logout+po.tar.bz2
16 mirror://gentoo/${MY_P_PO}-po.patch.bz2"
17
18 LICENSE="GPL-2 FDL-1.1 LGPL-2"
19 SLOT="0"
20 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
21 IUSE="doc eds networkmanager policykit"
22
23 RDEPEND=">=gnome-base/gnome-desktop-2.24.0
24 >=x11-libs/pango-1.15.4
25 >=dev-libs/glib-2.18.0
26 >=x11-libs/gtk+-2.15.1
27 >=dev-libs/libgweather-2.24.1
28 dev-libs/libxml2
29 >=gnome-base/libglade-2.5
30 >=gnome-base/libgnome-2.13
31 >=gnome-base/libgnomeui-2.5.4
32 >=gnome-base/libbonoboui-2.1.1
33 >=gnome-base/orbit-2.4
34 >=x11-libs/libwnck-2.19.5
35 >=gnome-base/gconf-2.6.1
36 >=gnome-base/gnome-menus-2.11.1
37 >=gnome-base/libbonobo-2.20.4
38 gnome-base/librsvg
39 >=dev-libs/dbus-glib-0.71
40 >=sys-apps/dbus-1.1.2
41 x11-libs/libXau
42 >=x11-libs/cairo-1.0.0
43 eds? ( >=gnome-extra/evolution-data-server-1.6 )
44 networkmanager? ( >=net-misc/networkmanager-0.6 )
45 policykit? (
46 >=sys-auth/policykit-0.7
47 >=gnome-extra/policykit-gnome-0.7 )"
48 DEPEND="${RDEPEND}
49 >=dev-lang/perl-5
50 gnome-base/gnome-common
51 >=app-text/gnome-doc-utils-0.3.2
52 >=dev-util/pkgconfig-0.9
53 >=dev-util/intltool-0.40
54 ~app-text/docbook-xml-dtd-4.1.2
55 >=dev-util/gtk-doc-am-1
56 doc? ( >=dev-util/gtk-doc-1 )"
57
58 DOCS="AUTHORS ChangeLog HACKING NEWS README"
59
60 pkg_setup() {
61 G2CONF="${G2CONF}
62 --disable-scrollkeeper
63 --disable-schemas-install
64 --with-in-process-applets=clock,notification-area,wncklet
65 $(use_enable policykit polkit)
66 $(use_enable networkmanager network-manager)
67 $(use_enable eds)"
68 }
69
70 src_prepare() {
71 gnome2_src_prepare
72
73 # Allow logout/shutdown without gnome-session 2.24, bug #246170
74 epatch "${WORKDIR}/${MY_P}-logout.patch"
75 epatch "${WORKDIR}/${MY_P_PO}-po.patch"
76 echo "gnome-panel/panel-logout.c" >> po/POTFILES.in
77
78 # Fixes build on BSD, bug #256859
79 epatch "${FILESDIR}/${PN}-2.24.3-daylight.patch"
80
81 # Fixes shutdown without gdm, bug #259138
82 epatch "${FILESDIR}/${PN}-2.24.3-shutdown.patch"
83
84 intltoolize --force --copy --automake || die "intltoolize failed"
85
86 # FIXME: tarball generated with broken gtk-doc, revisit me.
87 if use doc; then
88 sed "/^TARGET_DIR/i \GTKDOC_REBASE=/usr/bin/gtkdoc-rebase" \
89 -i gtk-doc.make || die "sed 1 failed"
90 else
91 sed "/^TARGET_DIR/i \GTKDOC_REBASE=$(type -P true)" \
92 -i gtk-doc.make || die "sed 2 failed"
93 fi
94
95 # Make it libtool-1 compatible, bug #271652
96 rm -v m4/lt* m4/libtool.m4 || die "removing libtool macros failed"
97
98 AT_M4DIR="m4" eautoreconf
99 }
100
101 pkg_postinst() {
102 local entries="${ROOT}etc/gconf/schemas/panel-default-setup.entries"
103 local gconftool="${ROOT}usr/bin/gconftool-2"
104
105 if [ -e "$entries" ]; then
106 einfo "setting panel gconf defaults..."
107
108 GCONF_CONFIG_SOURCE="$("${gconftool}" --get-default-source | sed "s;:/;:${ROOT};")"
109
110 "${gconftool}" --direct --config-source \
111 "${GCONF_CONFIG_SOURCE}" --load="${entries}"
112 fi
113
114 # Calling this late so it doesn't process the GConf schemas file we already
115 # took care of.
116 gnome2_pkg_postinst
117 }

  ViewVC Help
Powered by ViewVC 1.1.20