/[gentoo-x86]/gnome-extra/libgda/libgda-5.1.1-r1.ebuild
Gentoo

Contents of /gnome-extra/libgda/libgda-5.1.1-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Sun Feb 9 13:00:05 2014 UTC (5 years, 2 months ago) by pacho
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +1 -1 lines
FILE REMOVED
Version bump, drop old

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/libgda-5.1.1-r1.ebuild,v 1.2 2013/06/30 15:24:19 jlec Exp $
4
5 EAPI="5"
6 GNOME2_LA_PUNT="yes"
7 GCONF_DEBUG="yes"
8 PYTHON_COMPAT=( python{2_6,2_7} )
9 #VALA_MIN_API_VERSION="0.16"
10 #VALA_MAX_API_VERSION="0.16" # configure explicitly checks for 0.16
11 #VALA_USE_DEPEND="vapigen"
12
13 inherit autotools db-use eutils flag-o-matic gnome2 java-pkg-opt-2 python-single-r1 # vala
14
15 DESCRIPTION="GNOME database access library"
16 HOMEPAGE="http://www.gnome-db.org/"
17 LICENSE="GPL-2+ LGPL-2+"
18
19 IUSE="berkdb bindist canvas firebird gnome-keyring gtk graphviz http +introspection json ldap mdb mysql oci8 postgres reports sourceview ssl" # vala
20 REQUIRED_USE="
21 reports? ( ${PYTHON_REQUIRED_USE} )
22 canvas? ( gtk )
23 firebird? ( !bindist )
24 graphviz? ( gtk )
25 sourceview? ( gtk )"
26 # firebird license is not GPL compatible
27 SLOT="5/4" # subslot = libgda-5.0 soname version
28 KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
29
30 RDEPEND="
31 app-text/iso-codes
32 >=dev-libs/glib-2.32:2
33 >=dev-libs/libxml2-2
34 dev-libs/libxslt
35 sys-libs/readline:=
36 sys-libs/ncurses:=
37 berkdb? ( sys-libs/db )
38 !bindist? ( firebird? ( dev-db/firebird ) )
39 gtk? (
40 >=x11-libs/gtk+-3.0.0:3
41 canvas? ( x11-libs/goocanvas:2.0= )
42 sourceview? ( x11-libs/gtksourceview:3.0 )
43 graphviz? ( media-gfx/graphviz )
44 )
45 gnome-keyring? ( app-crypt/libsecret )
46 http? ( >=net-libs/libsoup-2.24:2.4 )
47 introspection? ( >=dev-libs/gobject-introspection-1.30 )
48 json? ( dev-libs/json-glib )
49 ldap? ( net-nds/openldap:= )
50 mdb? ( >app-office/mdbtools-0.5:= )
51 mysql? ( virtual/mysql:= )
52 postgres? ( dev-db/postgresql-base:= )
53 reports? (
54 ${PYTHON_DEPS}
55 dev-java/fop
56 dev-python/reportlab )
57 ssl? ( dev-libs/openssl:= )
58 >=dev-db/sqlite-3.6.22:3=
59 "
60 DEPEND="${RDEPEND}
61 >=app-text/gnome-doc-utils-0.9
62 dev-util/gtk-doc-am
63 >=dev-util/intltool-0.40.6
64 virtual/pkgconfig
65 java? ( virtual/jdk:1.6 )"
66 # vala? ( $(vala_depend) )
67
68 # FIXME: lots of tests failing. Check if they still fail in 5.1.2
69 RESTRICT="test"
70
71 pkg_setup() {
72 java-pkg-opt-2_pkg_setup
73 use reports && python-single-r1_pkg_setup
74 }
75
76 src_prepare() {
77 G2CONF="${G2CONF}
78 --disable-scrollkeeper
79 --disable-static
80 --enable-system-sqlite
81 $(use_with berkdb bdb /usr)
82 $(use_with canvas goocanvas)
83 $(use_with firebird firebird /usr)
84 $(use_with gnome-keyring)
85 $(use_with graphviz)
86 $(use_with gtk ui)
87 $(use_with http libsoup)
88 $(use_enable introspection)
89 $(use_with java java $JAVA_HOME)
90 $(use_enable json)
91 $(use_with ldap)
92 $(use_with mdb mdb /usr)
93 $(use_with mysql mysql /usr)
94 $(use_with postgres postgres /usr)
95 $(use_enable ssl crypto)
96 $(use_with sourceview gtksourceview)
97 --disable-default-binary
98 --disable-vala"
99 # vala bindings fail to build
100
101 use berkdb && append-cppflags "-I$(db_includedir)"
102 use oci8 || G2CONF="${G2CONF} --without-oracle"
103
104 use reports ||
105 sed -e '/SUBDIRS =/ s/trml2html//' \
106 -e '/SUBDIRS =/ s/trml2pdf//' \
107 -i libgda-report/RML/Makefile.{am,in} || die
108
109 # Prevent file collisions with libgda:4
110 epatch "${FILESDIR}/${PN}-4.99.1-gda-browser-help-collision.patch"
111 epatch "${FILESDIR}/${PN}-4.99.1-gda-browser-doc-collision.patch"
112 epatch "${FILESDIR}/${PN}-4.99.1-control-center-icon-collision.patch"
113 # Move files with mv (since epatch can't handle rename diffs) and
114 # update pre-generated gtk-doc files (for non-git versions of libgda)
115 local f
116 for f in tools/browser/doc/gda-browser* ; do
117 mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
118 done
119 for f in tools/browser/doc/html/gda-browser.devhelp* ; do
120 sed -e 's:name="gda-browser":name="gda-browser-5.0":' \
121 -i ${f} || die "sed ${f} failed"
122 mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
123 done
124 for f in control-center/data/*_gda-control-center.png ; do
125 mv ${f} ${f/_gda-control-center.png/_gda-control-center-5.0.png} ||
126 die "mv ${f} failed"
127 done
128
129 eautoreconf
130 gnome2_src_prepare
131 java-pkg-opt-2_src_prepare
132 # use vala && vala_src_prepare
133 }
134
135 src_install() {
136 gnome2_src_install
137 if use reports; then
138 for t in trml2{html,pdf}; do
139 python_scriptinto /usr/share/libgda-5.0/gda_${t}
140 python_doscript libgda-report/RML/${t}/${t}.py
141 done
142 fi
143 }

  ViewVC Help
Powered by ViewVC 1.1.20