/[gentoo-x86]/kde-base/kdepimlibs/kdepimlibs-4.7.0.ebuild
Gentoo

Contents of /kde-base/kdepimlibs/kdepimlibs-4.7.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Sun Jul 31 20:33:33 2011 UTC (9 years, 4 months ago) by dilfridge
Branch: MAIN
Changes since 1.1: +6 -4 lines
Boost is only DEPEND, bug 368787

(Portage version: 2.1.10.8/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/kdepimlibs-4.7.0.ebuild,v 1.1 2011/07/27 14:04:34 alexxy Exp $
4
5 EAPI=4
6
7 KDE_HANDBOOK="optional"
8 CPPUNIT_REQUIRED="optional"
9 KDE_SCM="git"
10 inherit kde4-base
11
12 DESCRIPTION="Common library for KDE PIM apps."
13 HOMEPAGE="http://www.kde.org/"
14
15 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
16 LICENSE="LGPL-2.1"
17 IUSE="debug ldap semantic-desktop"
18
19 # some akonadi tests timeout, that probaly needs more work as its ~700 tests
20 RESTRICT="test"
21
22 COMMON_DEPEND="
23 >=app-crypt/gpgme-1.1.6
24 dev-libs/libgpg-error
25 >=dev-libs/libical-0.43
26 dev-libs/cyrus-sasl
27 $(add_kdebase_dep kdelibs 'semantic-desktop=')
28 semantic-desktop? (
29 >=app-office/akonadi-server-1.5.80
30 media-libs/phonon
31 x11-misc/shared-mime-info
32 )
33 ldap? ( net-nds/openldap )
34 "
35 DEPEND="${COMMON_DEPEND}
36 >=dev-libs/boost-1.35.0-r5
37 "
38 RDEPEND="${COMMON_DEPEND}"
39
40 # libakonadi-kcal moved here from akonadi in 4.3.86
41 add_blocker akonadi '<4.3.86'
42 # @since 4.3 - libkholidays is in kdepimlibs now
43 add_blocker libkholidays
44 # @since 4.4 - kontactinterfaces is in kdepimlibs now
45 add_blocker kontactinterfaces
46
47 src_prepare() {
48 kde4-base_src_prepare
49
50 # Disable hardcoded checks
51 sed -r -e '/find_package\((Akonadi|SharedDesktopOntologies|Soprano|Nepomuk)/{/macro_optional_/!s/find/macro_optional_&/}' \
52 -e '/macro_log_feature\((Akonadi|SHAREDDESKTOPONTOLOGIES|Soprano|Nepomuk)_FOUND/s/ TRUE / FALSE /' \
53 -e '/add_subdirectory\((akonadi|mailtransport)/{/macro_optional_/!s/add/macro_optional_&/}' \
54 -i CMakeLists.txt || die
55 if ! use semantic-desktop; then
56 sed -e '/include(SopranoAddOntology)/s/^/#DISABLED /' \
57 -i CMakeLists.txt || die
58 # More reliable than -DBUILD_akonadi=OFF
59 rm -r akonadi mailtransport || die
60 fi
61 }
62
63 src_configure() {
64 mycmakeargs=(
65 $(cmake-utils_use_build handbook doc)
66 $(cmake-utils_use_with ldap)
67 $(cmake-utils_use_with semantic-desktop Akonadi)
68 $(cmake-utils_use_with semantic-desktop SharedDesktopOntologies)
69 $(cmake-utils_use_with semantic-desktop Soprano)
70 $(cmake-utils_use_with semantic-desktop Nepomuk)
71 # $(cmake-utils_use_with prison)
72 -DWITH_Prison=NO
73 )
74
75 kde4-base_src_configure
76 }

  ViewVC Help
Powered by ViewVC 1.1.20