/[gentoo-x86]/media-gfx/gimp/gimp-2.8.0-r1.ebuild
Gentoo

Contents of /media-gfx/gimp/gimp-2.8.0-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Tue May 29 06:47:50 2012 UTC (5 years, 7 months ago) by sping
Branch: MAIN
Changes since 1.2: +1 -2 lines
media-gfx/gimp: Support yi locale (bug #418053)

(Portage version: 2.1.10.56/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.8.0-r1.ebuild,v 1.2 2012/05/28 21:46:36 sping Exp $
4
5 EAPI="3"
6 PYTHON_DEPEND="python? 2:2.5"
7
8 inherit versionator autotools eutils gnome2 fdo-mime multilib python
9
10 DESCRIPTION="GNU Image Manipulation Program"
11 HOMEPAGE="http://www.gimp.org/"
12 SRC_URI="mirror://gimp/v$(get_version_component_range 1-2)/${P}.tar.bz2"
13 LICENSE="GPL-3 LGPL-3"
14 SLOT="2"
15 KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
16
17 LANGS="am ar ast az be bg br ca ca@valencia cs csb da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka kk km kn ko lt lv mk ml ms my nb nds ne nl nn oc pa pl pt pt_BR ro ru rw si sk sl sr sr@latin sv ta te th tr tt uk vi xh yi zh_CN zh_HK zh_TW"
18 IUSE="alsa aalib altivec bzip2 curl dbus debug doc exif gnome gs jpeg jpeg2k lcms mmx mng pdf png python smp sse svg tiff udev webkit wmf xpm"
19
20 for lang in ${LANGS}; do
21 IUSE+=" linguas_${lang}"
22 done
23
24 RDEPEND=">=dev-libs/glib-2.30.2:2
25 >=dev-libs/atk-2.2.0
26 >=x11-libs/gtk+-2.24.10:2
27 >=x11-libs/gdk-pixbuf-2.24.1:2
28 >=x11-libs/cairo-1.10.2
29 >=x11-libs/pango-1.29.4
30 xpm? ( x11-libs/libXpm )
31 >=media-libs/freetype-2.1.7
32 >=media-libs/fontconfig-2.2.0
33 sys-libs/zlib
34 dev-libs/libxml2
35 dev-libs/libxslt
36 x11-themes/hicolor-icon-theme
37 >=media-libs/babl-0.1.10
38 >=media-libs/gegl-0.2.0
39 aalib? ( media-libs/aalib )
40 alsa? ( media-libs/alsa-lib )
41 curl? ( net-misc/curl )
42 dbus? ( dev-libs/dbus-glib )
43 gnome? ( gnome-base/gvfs )
44 webkit? ( >=net-libs/webkit-gtk-1.6.1:2 )
45 jpeg? ( virtual/jpeg:0 )
46 jpeg2k? ( media-libs/jasper )
47 exif? ( >=media-libs/libexif-0.6.15 )
48 lcms? ( >=media-libs/lcms-1.16:0 )
49 mng? ( media-libs/libmng )
50 pdf? ( >=app-text/poppler-0.12.4[cairo] )
51 png? ( >=media-libs/libpng-1.2.37:0 )
52 python? ( >=dev-python/pygtk-2.10.4:2 )
53 tiff? ( >=media-libs/tiff-3.5.7:0 )
54 svg? ( >=gnome-base/librsvg-2.34.2:2 )
55 wmf? ( >=media-libs/libwmf-0.2.8 )
56 x11-libs/libXcursor
57 sys-libs/zlib
58 bzip2? ( app-arch/bzip2 )
59 gs? ( app-text/ghostscript-gpl )
60 udev? ( sys-fs/udev[gudev] )"
61 DEPEND="${RDEPEND}
62 sys-apps/findutils
63 virtual/pkgconfig
64 >=dev-util/intltool-0.40.1
65 >=sys-devel/gettext-0.17
66 doc? ( >=dev-util/gtk-doc-1 )
67 >=sys-devel/libtool-2.2
68 >=sys-devel/automake-1.11
69 dev-util/gtk-doc-am" # due to our call to eautoreconf below (bug #386453)
70
71 DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
72
73 S="${WORKDIR}"/${P}
74
75 pkg_setup() {
76 G2CONF="--enable-default-binary \
77 --with-x \
78 $(use_with aalib aa) \
79 $(use_with alsa) \
80 $(use_enable altivec) \
81 $(use_with bzip2) \
82 $(use_with curl libcurl) \
83 $(use_with dbus) \
84 $(use_with gnome gvfs) \
85 $(use_with webkit) \
86 $(use_with jpeg libjpeg) \
87 $(use_with jpeg2k libjasper) \
88 $(use_with exif libexif) \
89 $(use_with lcms) \
90 $(use_with gs) \
91 $(use_enable mmx) \
92 $(use_with mng libmng) \
93 $(use_with pdf poppler) \
94 $(use_with png libpng) \
95 $(use_enable python) \
96 $(use_enable smp mp) \
97 $(use_enable sse) \
98 $(use_with svg librsvg) \
99 $(use_with tiff libtiff) \
100 $(use_with udev gudev) \
101 $(use_with wmf) \
102 --with-xmc \
103 $(use_with xpm libxpm) \
104 --without-xvfb-run"
105
106 if use python; then
107 python_set_active_version 2
108 python_pkg_setup
109 fi
110 }
111
112 src_prepare() {
113 epatch "${FILESDIR}"/${PN}-2.7.4-no-deprecation.patch # bug 395695, comment 9 and 16
114 epatch "${FILESDIR}"/${PN}-2.8.0-bzip2.patch # bug 414525
115 eautoreconf # If you remove this: remove dev-util/gtk-doc-am from DEPEND, too
116
117 echo '#!/bin/sh' > py-compile
118 gnome2_src_prepare
119 }
120
121 _clean_up_locales() {
122 elog "Cleaning up locales..."
123 for lang in ${LANGS}; do
124 use "linguas_${lang}" && {
125 elog "- keeping ${lang}"
126 continue
127 }
128 rm -Rf "${D}"/usr/share/locale/"${lang}" || die
129 done
130 }
131
132 src_install() {
133 gnome2_src_install
134
135 if use python; then
136 python_convert_shebangs -r $(python_get_version) "${ED}"
137 python_need_rebuild
138 fi
139
140 # Workaround for bug #321111 to give GIMP the least
141 # precedence on PDF documents by default
142 mv "${D}"/usr/share/applications/{,zzz-}gimp.desktop || die
143
144 find "${D}" -name '*.la' -delete || die
145
146 _clean_up_locales
147 }
148
149 pkg_postinst() {
150 gnome2_pkg_postinst
151
152 use python && python_mod_optimize /usr/$(get_libdir)/gimp/2.0/python \
153 /usr/$(get_libdir)/gimp/2.0/plug-ins
154 }
155
156 pkg_postrm() {
157 gnome2_pkg_postrm
158
159 use python && python_mod_cleanup /usr/$(get_libdir)/gimp/2.0/python \
160 /usr/$(get_libdir)/gimp/2.0/plug-ins
161 }

  ViewVC Help
Powered by ViewVC 1.1.20