/[gentoo-x86]/media-gfx/gmic/gmic-1.5.2.5.ebuild
Gentoo

Contents of /media-gfx/gmic/gmic-1.5.2.5.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Fri May 3 08:45:30 2013 UTC (7 years, 2 months ago) by radhermit
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Remove old.

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/gmic-1.5.2.5.ebuild,v 1.1 2013/01/09 03:05:09 radhermit Exp $
4
5 EAPI="5"
6
7 inherit eutils toolchain-funcs bash-completion-r1 flag-o-matic
8
9 DESCRIPTION="GREYC's Magic Image Converter"
10 HOMEPAGE="http://gmic.sourceforge.net/"
11 SRC_URI="mirror://sourceforge/${PN}/${PN}_${PV}.tar.gz
12 doc? ( http://dev.gentoo.org/~radhermit/dist/gmic_reference-${PV}.pdf.xz )"
13
14 LICENSE="CeCILL-2 FDL-1.3"
15 SLOT="0"
16 KEYWORDS="~amd64 ~x86"
17 IUSE="doc ffmpeg fftw graphicsmagick jpeg opencv openexr png tiff X zlib"
18
19 RDEPEND="
20 ffmpeg? ( virtual/ffmpeg )
21 fftw? ( sci-libs/fftw:3.0 )
22 graphicsmagick? ( media-gfx/graphicsmagick )
23 jpeg? ( virtual/jpeg )
24 opencv? ( >=media-libs/opencv-2.3.1a-r1 )
25 openexr? (
26 media-libs/ilmbase
27 media-libs/openexr
28 )
29 png? ( media-libs/libpng )
30 tiff? ( media-libs/tiff )
31 X? (
32 x11-libs/libX11
33 x11-libs/libXext
34 )
35 zlib? ( sys-libs/zlib )"
36 DEPEND="${RDEPEND}
37 doc? ( app-arch/xz-utils )"
38
39 S=${WORKDIR}/${P}/src
40
41 src_prepare() {
42 epatch "${FILESDIR}"/${PN}-1.5.2.2-makefile.patch
43 epatch "${FILESDIR}"/${PN}-1.5.2.2-ffmpeg.patch
44
45 for i in ffmpeg fftw jpeg opencv png tiff zlib ; do
46 use $i || { sed -i -r "s/^(${i}_(C|LD)FLAGS =).*/\1/I" Makefile || die ; }
47 done
48
49 use graphicsmagick || { sed -i -r "s/^(MAGICK_(C|LD)FLAGS =).*/\1/" Makefile || die ; }
50 use openexr || { sed -i -r "s/^(EXR_(C|LD)FLAGS =).*/\1/" Makefile || die ; }
51
52 if ! use X ; then
53 sed -i -r "s/^((X11|XSHM)_(C|LD)FLAGS =).*/\1/" Makefile || die
54
55 # Disable display capabilities when X support is disabled
56 append-cppflags -Dcimg_display=0
57 fi
58 }
59
60 src_compile() {
61 emake AR="$(tc-getAR)" CC="$(tc-getCXX)" CFLAGS="${CXXFLAGS} ${CPPFLAGS}" custom lib
62 }
63
64 src_install() {
65 dobin gmic
66 newlib.so libgmic.so libgmic.so.1
67
68 insinto /usr/include
69 doins gmic.h
70
71 doman ../man/gmic.1.gz
72 dodoc ../README
73
74 use doc && dodoc "${WORKDIR}"/gmic_reference-${PV}.pdf
75
76 newbashcomp gmic_bashcompletion.sh ${PN}
77 }

  ViewVC Help
Powered by ViewVC 1.1.20