/[gentoo-x86]/media-gfx/gmic/gmic-1.5.9.2.ebuild
Gentoo

Contents of /media-gfx/gmic/gmic-1.5.9.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Mon Jun 16 07:48:29 2014 UTC (6 years ago) by radhermit
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Remove old.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/gmic-1.5.9.2.ebuild,v 1.1 2014/06/16 06:37:59 radhermit Exp $
4
5 EAPI=5
6
7 inherit eutils toolchain-funcs bash-completion-r1 flag-o-matic
8
9 DESCRIPTION="GREYC's Magic Image Converter"
10 HOMEPAGE="http://gmic.sourceforge.net/"
11 SRC_URI="mirror://sourceforge/${PN}/${PN}_${PV}.tar.gz"
12
13 LICENSE="CeCILL-2 FDL-1.3"
14 SLOT="0"
15 KEYWORDS="~amd64 ~x86"
16 IUSE="ffmpeg fftw graphicsmagick jpeg opencv openexr png tiff X zlib"
17
18 RDEPEND="
19 ffmpeg? ( virtual/ffmpeg )
20 fftw? ( sci-libs/fftw:3.0[threads] )
21 graphicsmagick? ( media-gfx/graphicsmagick )
22 jpeg? ( virtual/jpeg )
23 opencv? ( >=media-libs/opencv-2.3.1a-r1 )
24 openexr? (
25 media-libs/ilmbase
26 media-libs/openexr
27 )
28 png? ( media-libs/libpng )
29 tiff? ( media-libs/tiff )
30 X? (
31 x11-libs/libX11
32 x11-libs/libXext
33 )
34 zlib? ( sys-libs/zlib )"
35 DEPEND="${RDEPEND}"
36
37 S=${WORKDIR}/${P}/src
38
39 src_prepare() {
40 epatch "${FILESDIR}"/${PN}-1.5.9.1-makefile.patch
41 epatch "${FILESDIR}"/${PN}-1.5.8.2-ffmpeg.patch
42
43 for i in ffmpeg fftw jpeg opencv png tiff zlib ; do
44 use $i || { sed -i -r "s/^(${i}_(C|LD)FLAGS =).*/\1/I" Makefile || die ; }
45 done
46
47 use graphicsmagick || { sed -i -r "s/^(MAGICK_(C|LD)FLAGS =).*/\1/" Makefile || die ; }
48 use openexr || { sed -i -r "s/^(EXR_(C|LD)FLAGS =).*/\1/" Makefile || die ; }
49
50 if ! use X ; then
51 sed -i -r "s/^((X11|XSHM)_(C|LD)FLAGS =).*/\1/" Makefile || die
52
53 # disable display capabilities when X support is disabled
54 append-cppflags -Dcimg_display=0
55 fi
56 }
57
58 src_compile() {
59 emake AR="$(tc-getAR)" CC="$(tc-getCXX)" CFLAGS="${CXXFLAGS}" OPT_CFLAGS= DEBUG_CFLAGS= linux lib
60 }
61
62 src_install() {
63 dobin gmic
64 newlib.so libgmic.so libgmic.so.1
65
66 insinto /usr/include
67 doins gmic.h
68
69 doman ../man/gmic.1.gz
70 dodoc ../README
71
72 newbashcomp ../resources/gmic_bashcompletion.sh ${PN}
73 }

  ViewVC Help
Powered by ViewVC 1.1.20