/[gentoo-x86]/media-gfx/pixie/pixie-2.2.6-r1.ebuild
Gentoo

Contents of /media-gfx/pixie/pixie-2.2.6-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.9 - (show annotations) (download)
Wed Feb 29 02:21:04 2012 UTC (8 years, 7 months ago) by jer
Branch: MAIN
Changes since 1.8: +3 -2 lines
Do not link statically (bug #383035).

(Portage version: 2.2.0_alpha89/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-gfx/pixie/pixie-2.2.6-r1.ebuild,v 1.8 2011/03/20 20:13:49 jlec Exp $
4
5 EAPI="2"
6
7 WANT_AUTOMAKE="1.10"
8
9 inherit eutils multilib autotools
10
11 MY_PN="Pixie"
12 S="${WORKDIR}/${MY_PN}"
13
14 DESCRIPTION="RenderMan like photorealistic renderer"
15 HOMEPAGE="http://pixie.sourceforge.net/"
16 SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-src-${PV}.tgz"
17
18 LICENSE="GPL-2"
19 IUSE="X static-libs"
20 SLOT="0"
21 KEYWORDS="amd64 ~ppc sparc x86"
22
23 RDEPEND="virtual/jpeg
24 media-libs/tiff
25 media-libs/libpng
26 x11-libs/fltk:1[opengl]
27 media-libs/openexr
28 virtual/opengl
29 sys-libs/zlib
30 X? (
31 x11-libs/libXext
32 x11-libs/libICE
33 x11-libs/libSM
34 x11-libs/libX11
35 x11-libs/libXau
36 x11-libs/libxcb
37 x11-libs/libXdmcp
38 x11-libs/libXi
39 x11-libs/libXmu
40 x11-libs/libXt
41 )"
42 DEPEND="${RDEPEND}
43 sys-devel/flex
44 sys-devel/bison"
45
46 src_prepare() {
47 # FIX: missing @includedir@
48 # https://sf.net/tracker/?func=detail&aid=2923415&group_id=59462&atid=491094
49 epatch "${FILESDIR}/${P}-autotools.patch"
50 eautoreconf
51
52 # FIX: removing pre-compiled shaders
53 # shaders must be removed before of their compilation or make
54 # parallelism can break the regeneration process, with resulting
55 # missing shaders.
56 rm "${S}"/shaders/*.sdr
57 }
58
59 src_configure() {
60 # NOTE: the option program-transform-name is used to avoid binary name
61 # conflict with package: mail-client/nmh (see #295996)
62 econf \
63 $(use_with X x) \
64 $(use_enable static-libs static) \
65 --includedir=/usr/include/pixie \
66 --libdir=/usr/$(get_libdir)/pixie \
67 --with-docdir=/usr/share/doc/${PF}/html \
68 --with-shaderdir=/usr/share/Pixie/shaders \
69 --with-ribdir=/usr/share/Pixie/ribs \
70 --with-texturedir=/usr/share/Pixie/textures \
71 --with-displaysdir=/usr/$(get_libdir)/pixie/displays \
72 --with-modulesdir=/usr/$(get_libdir)/pixie/modules \
73 --enable-openexr-threads \
74 --disable-static-fltk \
75 --mandir=/usr/share/man \
76 --bindir=/usr/bin \
77 --program-transform-name="s/show/pixie-show/"
78 }
79
80 src_compile() {
81 emake || die "emake failed"
82
83 # regenerating Pixie shaders - see upstream bug report:
84 # https://sf.net/tracker/?func=detail&aid=2923407&group_id=59462&atid=491094
85 einfo "Re-building Pixie Shaders for v${PV} format"
86 emake -f "${FILESDIR}/Makefile.shaders" -C "${S}/shaders" || die "shaders rebuild failed"
87 }
88
89 src_install() {
90 emake DESTDIR="${D}" install || die "installation failed."
91
92 insinto /usr/share/Pixie/textures
93 doins "${S}"/textures/*
94
95 # remove useless .la files
96 find "${D}" -name '*.la' -delete || die "removal of libtool archive files failed"
97
98 dodoc README AUTHORS ChangeLog || die
99 }

  ViewVC Help
Powered by ViewVC 1.1.20