/[gentoo-x86]/media-libs/flac/flac-1.3.0.ebuild
Gentoo

Contents of /media-libs/flac/flac-1.3.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.14 - (show annotations) (download)
Wed Dec 24 17:08:42 2014 UTC (4 years, 9 months ago) by radhermit
Branch: MAIN
CVS Tags: HEAD
Changes since 1.13: +1 -1 lines
FILE REMOVED
Remove old.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-libs/flac/flac-1.3.0.ebuild,v 1.13 2014/06/18 19:27:19 mgorny Exp $
4
5 EAPI=5
6 AUTOTOOLS_AUTORECONF=1
7 AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
8
9 inherit autotools-multilib
10
11 DESCRIPTION="free lossless audio encoder and decoder"
12 HOMEPAGE="http://flac.sourceforge.net"
13 SRC_URI="http://downloads.xiph.org/releases/${PN}/${P}.tar.xz"
14
15 LICENSE="BSD FDL-1.2 GPL-2 LGPL-2.1"
16 SLOT="0"
17 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd"
18 IUSE="3dnow altivec +cxx debug ogg sse static-libs"
19
20 RDEPEND="ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
21 abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20130224-r1
22 !app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )"
23 DEPEND="${RDEPEND}
24 app-arch/xz-utils
25 abi_x86_32? ( dev-lang/nasm )
26 !elibc_uclibc? ( sys-devel/gettext )
27 virtual/pkgconfig"
28
29 src_prepare() {
30 local PATCHES=(
31 "${FILESDIR}"/${P}-asneeded.patch
32 "${FILESDIR}"/${P}-dontbuild-tests.patch
33 "${FILESDIR}"/${P}-dontbuild-examples.patch
34 )
35
36 AT_M4DIR="m4" autotools-multilib_src_prepare
37 }
38
39 src_configure() {
40 local myeconfargs=(
41 $(use_enable debug)
42 $(use_enable sse)
43 $(use_enable 3dnow)
44 $(use_enable altivec)
45 --disable-doxygen-docs
46 --disable-xmms-plugin
47 $(use_enable cxx cpplibs)
48 $(use_enable ogg)
49 --disable-examples
50 )
51 autotools-multilib_src_configure
52 }
53
54 src_test() {
55 if [[ ${UID} != 0 ]]; then
56 autotools-multilib_src_test -j1
57 else
58 ewarn "Tests will fail if ran as root, skipping."
59 fi
60 }
61
62 src_install() {
63 autotools-multilib_src_install \
64 docdir=/usr/share/doc/${PF}/html
65 }

  ViewVC Help
Powered by ViewVC 1.1.20