/[gentoo-x86]/media-libs/xine-lib/xine-lib-1.2.6-r1.ebuild
Gentoo

Contents of /media-libs/xine-lib/xine-lib-1.2.6-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sun Feb 1 22:53:32 2015 UTC (5 years ago) by mgorny
Branch: MAIN
Introduce USE=libav to control the preferred implementation. Add subslot op to force rebuilds on ABI change.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-libs/xine-lib/xine-lib-1.2.6.ebuild,v 1.4 2014/08/22 11:40:56 ssuominen Exp $
4
5 EAPI=5
6
7 inherit flag-o-matic libtool multilib
8
9 if [[ ${PV} == *9999* ]]; then
10 EHG_REPO_URI="http://hg.debian.org/hg/xine-lib/xine-lib-1.2"
11 inherit autotools mercurial eutils
12 unset NLS_IUSE
13 NLS_DEPEND="sys-devel/gettext"
14 NLS_RDEPEND="virtual/libintl"
15 else
16 KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd"
17 SRC_URI="mirror://sourceforge/xine/${P}.tar.xz"
18 NLS_IUSE="nls"
19 NLS_DEPEND="nls? ( sys-devel/gettext )"
20 NLS_RDEPEND="nls? ( virtual/libintl )"
21 fi
22
23 DESCRIPTION="Core libraries for Xine movie player"
24 HOMEPAGE="http://xine.sourceforge.net/"
25
26 LICENSE="GPL-2"
27 SLOT="1"
28 IUSE="a52 aac aalib +alsa altivec bluray +css directfb dts dvb dxr3 fbcon flac fusion gtk imagemagick ipv6 jack jpeg libav libcaca mad +mmap mng modplug musepack opengl oss pulseaudio samba sdl speex theora truetype v4l vaapi vcd vdpau vdr vidix +vis vorbis vpx wavpack +X +xcb xinerama +xv xvmc ${NLS_IUSE}"
29
30 RDEPEND="${NLS_RDEPEND}
31 dev-libs/libxdg-basedir
32 media-libs/libdvdnav
33 sys-libs/zlib
34 !libav? ( media-video/ffmpeg:0= )
35 libav? (
36 media-libs/libpostproc:0=
37 media-video/libav:0=
38 )
39 virtual/libiconv
40 a52? ( media-libs/a52dec )
41 aac? ( media-libs/faad2 )
42 aalib? ( media-libs/aalib )
43 alsa? ( media-libs/alsa-lib )
44 bluray? ( >=media-libs/libbluray-0.2.1 )
45 css? ( >=media-libs/libdvdcss-1.2.10 )
46 directfb? ( dev-libs/DirectFB )
47 dts? ( media-libs/libdca )
48 dxr3? ( media-libs/libfame )
49 flac? ( media-libs/flac )
50 fusion? ( media-libs/FusionSound )
51 gtk? ( x11-libs/gdk-pixbuf:2 )
52 imagemagick? ( || ( media-gfx/imagemagick media-gfx/graphicsmagick ) )
53 jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
54 jpeg? ( virtual/jpeg:0 )
55 libcaca? ( media-libs/libcaca )
56 mad? ( media-libs/libmad )
57 mng? ( media-libs/libmng )
58 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
59 musepack? ( >=media-sound/musepack-tools-444 )
60 opengl? (
61 virtual/glu
62 virtual/opengl
63 )
64 pulseaudio? ( media-sound/pulseaudio )
65 samba? ( net-fs/samba )
66 sdl? ( media-libs/libsdl )
67 speex? (
68 media-libs/libogg
69 media-libs/speex
70 )
71 theora? (
72 media-libs/libogg
73 media-libs/libtheora
74 )
75 truetype? (
76 media-libs/fontconfig
77 media-libs/freetype:2
78 )
79 v4l? ( media-libs/libv4l )
80 vaapi? ( x11-libs/libva )
81 vcd? (
82 >=media-video/vcdimager-0.7.23
83 dev-libs/libcdio[-minimal]
84 )
85 vdpau? ( x11-libs/libvdpau )
86 vorbis? (
87 media-libs/libogg
88 media-libs/libvorbis
89 )
90 vpx? ( media-libs/libvpx )
91 wavpack? ( media-sound/wavpack )
92 X? (
93 x11-libs/libX11
94 x11-libs/libXext
95 )
96 xcb? ( x11-libs/libxcb )
97 xinerama? ( x11-libs/libXinerama )
98 xv? ( x11-libs/libXv )
99 xvmc? ( x11-libs/libXvMC )"
100 DEPEND="${RDEPEND}
101 ${NLS_DEPEND}
102 app-arch/xz-utils
103 virtual/pkgconfig
104 >=sys-devel/libtool-2.2.6b
105 oss? ( virtual/os-headers )
106 v4l? ( virtual/os-headers )
107 X? (
108 x11-libs/libXt
109 x11-proto/xf86vidmodeproto
110 x11-proto/xproto
111 )
112 xv? ( x11-proto/videoproto )
113 xvmc? ( x11-proto/videoproto )
114 xinerama? ( x11-proto/xineramaproto )"
115 REQUIRED_USE="vidix? ( || ( X fbcon ) )
116 xv? ( X )
117 xinerama? ( X )"
118
119 src_prepare() {
120 sed -i -e '/define VDR_ABS_FIFO_DIR/s|".*"|"/var/vdr/xine"|' src/vdr/input_vdr.c || die
121
122 if [[ ${PV} == *9999* ]]; then
123 epatch_user
124 eautoreconf
125 else
126 elibtoolize
127 fi
128
129 local x
130 for x in 0 1 2 3; do
131 sed -i -e "/^O${x}_CFLAGS=\"-O${x}\"/d" configure || die
132 done
133 }
134
135 src_configure() {
136 [[ ${CHOST} == i?86-* ]] && append-flags -fomit-frame-pointer #422519
137
138 local win32dir #197236
139 if has_multilib_profile; then
140 win32dir=/usr/$(ABI="x86" get_libdir)/win32
141 else
142 win32dir=/usr/$(get_libdir)/win32
143 fi
144
145 local myconf=()
146 [[ ${PV} == *9999* ]] || myconf=( $(use_enable nls) )
147
148 if ! use libav && has_version '>=media-video/ffmpeg-2.2:0'; then
149 myconf+=( --enable-avformat ) #507474
150 fi
151
152 econf \
153 $(use_enable ipv6) \
154 $(use_enable altivec) \
155 $(use_enable vis) \
156 --disable-optimizations \
157 $(use_enable mmap) \
158 $(use_enable oss) \
159 $(use_enable aalib) \
160 $(use_enable directfb) \
161 $(use_enable dxr3) \
162 $(use_enable fbcon fb) \
163 $(use_enable opengl) $(use_enable opengl glu) \
164 $(use_enable vidix) \
165 $(use_enable xinerama) \
166 $(use_enable xvmc) \
167 $(use_enable vdpau) \
168 $(use_enable vaapi) \
169 $(use_enable dvb) \
170 --disable-gnomevfs \
171 $(use_enable samba) \
172 --disable-v4l $(use_enable v4l v4l2) $(use_enable v4l libv4l) \
173 $(use_enable vcd) \
174 $(use_enable vdr) \
175 $(use_enable bluray) \
176 $(use_enable a52 a52dec) \
177 $(use_enable aac faad) \
178 $(use_enable gtk gdkpixbuf) \
179 $(use_enable jpeg libjpeg) \
180 $(use_enable dts) \
181 $(use_enable mad) \
182 $(use_enable modplug) \
183 $(use_enable musepack) \
184 $(use_enable mng) \
185 --disable-real-codecs \
186 --disable-w32dll \
187 $(use_enable vpx) \
188 $(use_with truetype freetype) $(use_with truetype fontconfig) \
189 $(use_with X x) \
190 $(use_with alsa) \
191 --without-esound \
192 $(use_with fusion fusionsound) \
193 $(use_with jack) \
194 $(use_with pulseaudio) \
195 $(use_with libcaca caca) \
196 $(use_with sdl) \
197 $(use_with xcb) \
198 --with-xv-path=/usr/$(get_libdir) \
199 $(use_with imagemagick) \
200 --with-external-dvdnav \
201 $(use_with flac libflac) \
202 $(use_with speex) \
203 $(use_with theora) \
204 $(use_with vorbis) \
205 --with-real-codecs-path=/usr/$(get_libdir)/codecs \
206 --with-w32-path=${win32dir} \
207 $(use_with wavpack) \
208 "${myconf[@]}"
209 }
210
211 src_compile() {
212 # enable verbose building, bug #448140
213 emake V=1
214 }
215
216 src_install() {
217 emake \
218 DESTDIR="${D}" \
219 docdir="/usr/share/doc/${PF}" \
220 htmldir="/usr/share/doc/${PF}/html" \
221 install
222
223 rm -f \
224 "${ED}"usr/lib*/libxine*.la \
225 "${ED}"usr/share/doc/${PF}/COPYING
226 }

  ViewVC Help
Powered by ViewVC 1.1.20