/[gentoo-x86]/media-sound/moc/moc-2.5.0_beta1-r1.ebuild
Gentoo

Contents of /media-sound/moc/moc-2.5.0_beta1-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.11 - (show annotations) (download)
Mon Mar 16 22:09:00 2015 UTC (4 years, 10 months ago) by vapier
Branch: MAIN
CVS Tags: HEAD
Changes since 1.10: +4 -5 lines
Depend on libltdl directly #539374 by David Flogeras.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-sound/moc/moc-2.5.0_beta1-r1.ebuild,v 1.10 2013/04/13 07:36:15 ago Exp $
4
5 EAPI=4
6
7 inherit eutils autotools
8
9 MY_P=${P/_/-}
10
11 DESCRIPTION="Music On Console - ncurses interface for playing audio files"
12 HOMEPAGE="http://moc.daper.net"
13 SRC_URI="ftp://ftp.daper.net/pub/soft/moc/unstable/${MY_P}.tar.bz2"
14
15 LICENSE="GPL-2"
16 SLOT="0"
17 KEYWORDS="alpha amd64 ppc ppc64 sparc x86"
18 IUSE="aac alsa +cache curl debug ffmpeg flac jack libsamplerate mad +magic modplug musepack
19 oss sid sndfile speex timidity tremor +unicode vorbis wavpack"
20
21 RDEPEND=">=dev-libs/libltdl-2:0
22 sys-libs/ncurses[unicode?]
23 aac? ( media-libs/faad2 )
24 alsa? ( media-libs/alsa-lib )
25 cache? ( >=sys-libs/db-4 )
26 curl? ( net-misc/curl )
27 ffmpeg? ( virtual/ffmpeg )
28 flac? ( media-libs/flac )
29 jack? ( media-sound/jack-audio-connection-kit )
30 libsamplerate? ( media-libs/libsamplerate )
31 mad? ( media-libs/libmad sys-libs/zlib media-libs/libid3tag )
32 magic? ( sys-apps/file )
33 modplug? ( media-libs/libmodplug )
34 musepack? ( media-sound/musepack-tools media-libs/taglib )
35 sid? ( >=media-libs/libsidplay-2 )
36 sndfile? ( media-libs/libsndfile )
37 speex? ( media-libs/speex )
38 timidity? ( media-libs/libtimidity media-sound/timidity++ )
39 vorbis? (
40 media-libs/libogg
41 tremor? ( media-libs/tremor )
42 !tremor? ( media-libs/libvorbis )
43 )
44 wavpack? ( media-sound/wavpack )"
45 DEPEND="${RDEPEND}
46 app-arch/xz-utils
47 virtual/pkgconfig"
48
49 S=${WORKDIR}/${MY_P}
50
51 src_prepare() {
52 # moc-2.5.0 will require popt, but currently it's an unused, automagic dep
53 epatch "${FILESDIR}"/${P}-no-automagic-popt.patch
54 eautoreconf
55 }
56
57 src_configure() {
58 local myconf=(
59 --docdir="${EPREFIX}"/usr/share/doc/${PF}
60 $(use_enable debug)
61 $(use_enable cache)
62 $(use_with oss)
63 $(use_with alsa)
64 $(use_with jack)
65 $(use_with magic)
66 $(use_with unicode ncursesw)
67 $(use_with libsamplerate samplerate)
68 $(use_with aac)
69 $(use_with ffmpeg)
70 $(use_with flac)
71 $(use_with modplug)
72 $(use_with mad mp3)
73 --without-rcc
74 $(use_with musepack)
75 $(use_with sid sidplay2)
76 $(use_with sndfile)
77 $(use_with speex)
78 $(use_with timidity)
79 $(use_with vorbis vorbis $(usex tremor tremor ""))
80 $(use_with wavpack)
81 $(use_with curl)
82 )
83
84 econf "${myconf[@]}"
85 }
86
87 src_install() {
88 emake DESTDIR="${D}" install
89 dodoc AUTHORS NEWS TODO # The rest is installed by doc_DATA from "${S}"/Makefile.am
90 find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
91 }

  ViewVC Help
Powered by ViewVC 1.1.20