/[gentoo-x86]/media-sound/mpg123/mpg123-1.7.3-r1.ebuild
Gentoo

Contents of /media-sound/mpg123/mpg123-1.7.3-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Wed Sep 30 15:48:02 2009 UTC (10 years ago) by ssuominen
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +1 -1 lines
FILE REMOVED
Remove old and unused because it's overwriting system libltdl breaking systems.
(Portage version: 2.2_rc42/cvs/Linux x86_64)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/mpg123-1.7.3-r1.ebuild,v 1.2 2009/09/06 17:03:43 ssuominen Exp $
4
5 EAPI=2
6
7 DESCRIPTION="a realtime MPEG 1.0/2.0/2.5 audio player for layers 1, 2 and 3."
8 HOMEPAGE="http://www.mpg123.org"
9 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
10
11 LICENSE="GPL-2 LGPL-2.1"
12 SLOT="0"
13 KEYWORDS="alpha amd64 ~arm hppa ia64 ~mips ppc ppc64 sparc x86 ~x86-fbsd"
14 IUSE="3dnow 3dnowext alsa altivec ipv6 jack mmx nas +network oss portaudio pulseaudio sdl sse"
15
16 RDEPEND="alsa? ( media-libs/alsa-lib )
17 jack? ( media-sound/jack-audio-connection-kit )
18 nas? ( media-libs/nas )
19 portaudio? ( media-libs/portaudio )
20 pulseaudio? ( media-sound/pulseaudio )
21 sdl? ( media-libs/libsdl )"
22 DEPEND="${RDEPEND}
23 dev-util/pkgconfig"
24
25 pkg_setup() {
26 # Make sure there is no mpg123 symlink left
27 local link="${ROOT}usr/bin/mpg123"
28 local msg="Removing invalid symlink ${link}"
29 if [ -L "${link}" ] && [ ! -x "${link}" ]; then
30 ebegin "${msg}"
31 rm -f "${link}" || die "${msg} failed, please open a bug."
32 eend $?
33 fi
34 }
35
36 src_prepare() {
37 sed -i -e 's:-faltivec::' configure || die "sed failed"
38 }
39
40 src_configure() {
41 local myaudio
42
43 use alsa && myaudio="${myaudio} alsa"
44 use jack && myaudio="${myaudio} jack"
45 use nas && myaudio="${myaudio} nas"
46 use oss && myaudio="${myaudio} oss"
47 use portaudio && myaudio="${myaudio} portaudio"
48 use pulseaudio && myaudio="${myaudio} pulse"
49 use sdl && myaudio="${myaudio} sdl"
50
51 local mycpu
52
53 if use altivec; then
54 mycpu="--with-cpu=altivec"
55 elif use 3dnowext; then
56 mycpu="--with-cpu=3dnowext"
57 elif use 3dnow; then
58 mycpu="--with-cpu=3dnow"
59 elif use sse; then
60 mycpu="--with-cpu=sse"
61 elif use mmx; then
62 mycpu="--with-cpu=mmx"
63 fi
64
65 econf \
66 --disable-dependency-tracking \
67 --with-optimization=0 ${mycpu} \
68 --with-audio="${myaudio}" \
69 $(use_enable network) \
70 $(use_enable ipv6)
71 }
72
73 src_install() {
74 emake DESTDIR="${D}" install || die "emake install failed"
75 dodoc AUTHORS ChangeLog NEWS* README
76 }

  ViewVC Help
Powered by ViewVC 1.1.20