/[gentoo-x86]/media-sound/murmur/murmur-1.2.3-r2.ebuild
Gentoo

Contents of /media-sound/murmur/murmur-1.2.3-r2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Fri Feb 24 16:51:25 2012 UTC (8 years, 9 months ago) by tgurr
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Revbump removing mDNSResponder wrt upcomming last rite, bug #405393.

(Portage version: 2.2.0_alpha86/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-sound/murmur/murmur-1.2.3-r2.ebuild,v 1.1 2012/02/20 19:10:16 tgurr Exp $
4
5 EAPI="4"
6
7 inherit eutils qt4-r2
8
9 MY_P="${PN/murmur/mumble}-${PV/_/~}"
10
11 DESCRIPTION="Mumble is an open source, low-latency, high quality voice chat software"
12 HOMEPAGE="http://mumble.sourceforge.net/"
13 SRC_URI="mirror://sourceforge/mumble/${MY_P}.tar.gz"
14
15 LICENSE="BSD"
16 SLOT="0"
17 KEYWORDS="~amd64 ~x86"
18 IUSE="+dbus debug +ice pch zeroconf"
19
20 RDEPEND=">=dev-libs/openssl-1.0.0b
21 >=dev-libs/protobuf-2.2.0
22 sys-apps/lsb-release
23 >=sys-libs/libcap-2.15
24 x11-libs/qt-core:4[ssl]
25 || ( x11-libs/qt-sql:4[sqlite] x11-libs/qt-sql:4[mysql] )
26 x11-libs/qt-xmlpatterns:4
27 dbus? ( x11-libs/qt-dbus:4 )
28 ice? ( dev-libs/Ice )
29 zeroconf? ( || ( net-dns/avahi[mdnsresponder-compat] net-misc/mDNSResponder ) )"
30
31 DEPEND="${RDEPEND}
32 >=dev-libs/boost-1.41.0
33 dev-util/pkgconfig"
34
35 S="${WORKDIR}/${MY_P}"
36
37 PATCHES=(
38 "${FILESDIR}"/${PN}-1.2.3-ice-3.4.2-compat.patch
39 "${FILESDIR}"/mumble-1.2.3-remove-certs.patch
40 "${FILESDIR}"/mumble-1.2.3-fix-cert-validation.patch
41 )
42
43 pkg_setup() {
44 enewgroup murmur
45 enewuser murmur -1 -1 /var/lib/murmur murmur
46 }
47
48 src_prepare() {
49 qt4-r2_src_prepare
50
51 sed -i -e 's:mumble-server:murmur:g' \
52 "${S}"/scripts/murmur.{conf,ini.system} || die
53 }
54
55 src_configure() {
56 local conf_add
57
58 use dbus || conf_add="${conf_add} no-dbus"
59 use debug && conf_add="${conf_add} symbols debug" || conf_add="${conf_add} release"
60 use ice || conf_add="${conf_add} no-ice"
61 use pch || conf_add="${conf_add} no-pch"
62 use zeroconf || conf_add="${conf_add} no-bonjour"
63
64 eqmake4 main.pro -recursive \
65 CONFIG+="${conf_add} no-client"
66 }
67
68 src_compile() {
69 # parallel make workaround, upstream bug #3190498
70 emake -j1
71 }
72
73 src_install() {
74 dodoc README CHANGES
75
76 docinto scripts
77 dodoc scripts/*.php scripts/*.pl
78
79 local dir
80 if use debug; then
81 dir=debug
82 else
83 dir=release
84 fi
85
86 dobin "${dir}"/murmurd
87
88 insinto /etc/murmur/
89 newins scripts/murmur.ini.system murmur.ini
90
91 insinto /etc/logrotate.d/
92 newins "${FILESDIR}"/murmur.logrotate murmur
93
94 insinto /etc/dbus-1/system.d/
95 doins scripts/murmur.conf
96
97 insinto /usr/share/murmur/
98 doins src/murmur/Murmur.ice
99
100 newinitd "${FILESDIR}"/murmur.initd murmur
101 newconfd "${FILESDIR}"/murmur.confd murmur
102
103 keepdir /var/lib/murmur /var/run/murmur /var/log/murmur
104 fowners -R murmur /var/lib/murmur /var/run/murmur /var/log/murmur
105 fperms 750 /var/lib/murmur /var/run/murmur /var/log/murmur
106
107 doman man/murmurd.1
108 }
109
110 pkg_postinst() {
111 echo
112 elog "Useful scripts are located in /usr/share/doc/${PF}/scripts."
113 elog "Please execute:"
114 elog "murmurd -ini /etc/murmur/murmur.ini -supw <pw>"
115 elog "chown murmur:murmur /var/lib/murmur/murmur.sqlite"
116 elog "to set the build-in 'SuperUser' password before starting murmur."
117 elog "Please restart dbus before starting murmur, or else dbus"
118 elog "registration will fail."
119 echo
120 }

  ViewVC Help
Powered by ViewVC 1.1.20