/[gentoo-x86]/media-sound/pragha/pragha-1.3.0.ebuild
Gentoo

Contents of /media-sound/pragha/pragha-1.3.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Mon May 11 17:11:31 2015 UTC (5 years, 6 months ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +3 -3 lines
Future-update dep on libxfce4ui to [gtk3(+)]. Add slot operators.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-sound/pragha/pragha-1.3.0.ebuild,v 1.4 2014/07/01 16:45:22 ssuominen Exp $
4
5 EAPI=5
6 inherit autotools xfconf
7
8 DESCRIPTION="A lightweight music player (with support for the Xfce desktop environment)"
9 HOMEPAGE="http://pragha.wikispaces.com/ http://github.com/matiasdelellis/pragha"
10 SRC_URI="http://github.com/matiasdelellis/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
11
12 LICENSE="GPL-3"
13 SLOT="0"
14 KEYWORDS="~amd64 ~x86"
15 IUSE="debug +glyr +keybinder lastfm libnotify mtp +peas +playlist +udev"
16
17 COMMON_DEPEND=">=dev-db/sqlite-3.4:3
18 >=dev-libs/glib-2.32
19 >=dev-libs/libcdio-0.90
20 >=dev-libs/libcdio-paranoia-0.90
21 media-libs/gst-plugins-base:1.0
22 >=media-libs/libcddb-1.3.0
23 >=media-libs/taglib-1.7.0
24 >=x11-libs/gtk+-3.4:3
25 x11-libs/libX11
26 >=xfce-base/libxfce4ui-4.11[gtk3(+)]
27 glyr? ( >=media-libs/glyr-1.0.1 )
28 keybinder? ( >=dev-libs/keybinder-0.2.0:3 )
29 lastfm? ( >=media-libs/libclastfm-0.5 )
30 libnotify? ( >=x11-libs/libnotify-0.7 )
31 mtp? ( >=media-libs/libmtp-1.1.0 )
32 peas? ( >=dev-libs/libpeas-1.0.0[gtk] )
33 playlist? ( >=dev-libs/totem-pl-parser-2.26 )
34 udev? ( virtual/libgudev:= )"
35 RDEPEND="${COMMON_DEPEND}
36 media-plugins/gst-plugins-meta:1.0"
37 DEPEND="${COMMON_DEPEND}
38 dev-util/intltool
39 >=dev-util/xfce4-dev-tools-4.10
40 sys-devel/gettext
41 virtual/pkgconfig"
42 REQUIRED_USE="glyr? ( peas )
43 libnotify? ( peas )
44 mtp? ( udev )
45 udev? ( peas )"
46
47 pkg_setup() {
48 XFCONF=(
49 --docdir="${EPREFIX}"/usr/share/doc/${PF}
50 $(use_enable debug)
51 $(use_enable peas libpeas-1.0)
52 $(use_enable glyr libglyr)
53 $(use_enable lastfm libclastfm)
54 $(use_enable playlist totem-plparser)
55 --with-gstreamer=1.0
56 )
57
58 if use peas; then
59 XFCONF+=(
60 $(use_enable libnotify)
61 $(use_enable keybinder)
62 $(use_enable udev gudev-1.0)
63 $(use_enable mtp libmtp)
64 )
65 else
66 XFCONF+=(
67 --disable-libnotify
68 --disable-keybinder
69 --disable-gudev-1.0
70 --disable-libmtp
71 )
72 fi
73 }
74
75 src_prepare() {
76 sed -i -e '/CFLAGS/s:-g -ggdb -O0::' configure.ac || die
77
78 # Prevent glib-gettextize from running wrt #423115
79 export AT_M4DIR=${EPREFIX}/usr/share/xfce4/dev-tools/m4macros
80 intltoolize --automake --copy --force
81 _elibtoolize --copy --force --install
82 eaclocal; eautoconf; eautoheader; eautomake
83
84 xfconf_src_prepare
85 }

  ViewVC Help
Powered by ViewVC 1.1.20