/[gentoo-x86]/media-video/gpac/gpac-9999.ebuild
Gentoo

Contents of /media-video/gpac/gpac-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Tue Oct 7 22:17:32 2014 UTC (5 years, 9 months ago) by lu_zero
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +2 -1 lines
Drop = from the --disable-foo=*) match, fix bug #524728

(Portage version: 2.2.12/cvs/Linux x86_64, unsigned Manifest commit)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/gpac/gpac-9999.ebuild,v 1.1 2014/10/05 21:39:37 lu_zero Exp $
4
5 EAPI=4
6
7 if [[ ${PV} == *9999 ]] ; then
8 SCM="subversion"
9 ESVN_REPO_URI="svn://svn.code.sf.net/p/gpac/code/trunk/gpac"
10 KEYWORDS=""
11 else
12 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
13 KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
14 fi
15
16 inherit eutils flag-o-matic multilib toolchain-funcs ${SCM}
17
18 DESCRIPTION="GPAC is an implementation of the MPEG-4 Systems standard developed from scratch in ANSI C"
19 HOMEPAGE="http://gpac.wp.mines-telecom.fr/"
20
21 LICENSE="GPL-2"
22 SLOT="0"
23 IUSE="a52 aac alsa debug dvb ffmpeg ipv6 jack jpeg jpeg2k mad opengl oss png pulseaudio sdl ssl static-libs theora truetype vorbis xml xvid"
24
25 S="${WORKDIR}"/${PN}
26
27 RDEPEND="
28 a52? ( media-libs/a52dec )
29 aac? ( >=media-libs/faad2-2.0 )
30 alsa? ( media-libs/alsa-lib )
31 dvb? ( media-tv/linuxtv-dvb-apps )
32 ffmpeg? ( virtual/ffmpeg )
33 jack? ( media-sound/jack-audio-connection-kit )
34 jpeg? ( virtual/jpeg )
35 mad? ( >=media-libs/libmad-0.15.1b )
36 opengl? ( virtual/opengl media-libs/freeglut virtual/glu )
37 >=media-libs/libogg-1.1
38 png? ( >=media-libs/libpng-1.4 )
39 vorbis? ( >=media-libs/libvorbis-1.1 )
40 theora? ( media-libs/libtheora )
41 truetype? ( >=media-libs/freetype-2.1.4 )
42 xml? ( >=dev-libs/libxml2-2.6.0 )
43 xvid? ( >=media-libs/xvid-1.0.1 )
44 sdl? ( media-libs/libsdl )
45 jpeg2k? ( media-libs/openjpeg:0 )
46 ssl? ( dev-libs/openssl )
47 pulseaudio? ( media-sound/pulseaudio )
48 x11-libs/libXt
49 x11-libs/libX11
50 x11-libs/libXv
51 x11-libs/libXext"
52 # disabled upstream, see applications/Makefile
53 # wxwidgets? ( =x11-libs/wxGTK-2.8* )
54
55 DEPEND="${RDEPEND}"
56
57 my_use() {
58 local flag="$1" pflag="${2:-$1}"
59 if use ${flag}; then
60 echo "--use-${pflag}=system"
61 else
62 echo "--use-${pflag}=no"
63 fi
64 }
65
66 src_prepare() {
67 epatch "${FILESDIR}"/110_all_implicitdecls.patch \
68 "${FILESDIR}"/${PN}-0.5.1-build-fixes.patch
69 sed -i -e "s:\(--disable-.*\)=\*):\1):" configure || die
70 }
71
72 src_configure() {
73 tc-export CC CXX AR RANLIB
74
75 econf \
76 --enable-svg \
77 --enable-pic \
78 --disable-amr \
79 --use-js=no \
80 --use-ogg=system \
81 $(use_enable alsa) \
82 $(use_enable debug) \
83 $(use_enable ipv6) \
84 $(use_enable jack jack yes) \
85 $(use_enable opengl) \
86 $(use_enable oss oss-audio) \
87 $(use_enable pulseaudio pulseaudio yes) \
88 $(use_enable sdl) \
89 $(use_enable ssl) \
90 $(use_enable static-libs static-lib) \
91 --disable-wx \
92 $(my_use a52) \
93 $(my_use aac faad) \
94 $(my_use dvb dvbx) \
95 $(my_use ffmpeg) \
96 $(my_use jpeg) \
97 $(my_use jpeg2k openjpeg) \
98 $(my_use mad) \
99 $(my_use png) \
100 $(my_use theora) \
101 $(my_use truetype ft) \
102 $(my_use vorbis) \
103 $(my_use xvid) \
104 --extra-cflags="${CFLAGS}" \
105 --cc="$(tc-getCC)" \
106 --libdir="/$(get_libdir)"
107 }
108
109 src_install() {
110 emake STRIP="true" DESTDIR="${D}" install
111 emake STRIP="true" DESTDIR="${D}" install-lib
112 dodoc AUTHORS BUGS Changelog README TODO INSTALLME
113 dodoc doc/*.txt
114 dohtml doc/*.html
115 }

  ViewVC Help
Powered by ViewVC 1.1.20