/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.100 - (show annotations) (download)
Sun Nov 7 19:14:31 2010 UTC (6 years, 5 months ago) by aballier
Branch: MAIN
Changes since 1.99: +3 -5 lines
use qt4-r2 eclass

(Portage version: 2.2.0_alpha4/cvs/Linux x86_64)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.99 2010/11/07 18:13:16 aballier Exp $
4
5 EAPI="3"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs gnome2 qt4-r2 flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25
26 PATCHLEVEL="89"
27 DESCRIPTION="VLC media player - Video player and streamer"
28 HOMEPAGE="http://www.videolan.org/vlc/"
29 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
30 SRC_URI=""
31 elif [[ "${MY_P}" == "${P}" ]]; then
32 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
33 else
34 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
35 fi
36
37 SRC_URI="${SRC_URI}
38 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
39
40 LICENSE="GPL-2"
41 SLOT="0"
42
43 if [ "${PV%9999}" = "${PV}" ] ; then
44 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
45 else
46 KEYWORDS=""
47 fi
48 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddb dbus dc1394
49 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
50 +gcrypt gme gnome gnutls httpd ieee1394 jack kate kde libass libcaca
51 libnotify libproxy libtiger libv4l2 lirc live lua matroska mmx
52 modplug mp3 mpeg mtp musepack ncurses ogg opengl optimisememory oss
53 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
54 schroedinger sdl sdl-image shine shout skins speex sqlite sse stream
55 svg taglib theora truetype twolame udev upnp v4l2 vaapi vcdx vlm
56 vorbis win32codecs wma-fixed +X x264 +xcb xml xosd xv zvbi"
57
58 RDEPEND="
59 sys-libs/zlib
60 >=media-libs/libdvbpsi-0.1.6
61 a52? ( >=media-libs/a52dec-0.7.4-r3 )
62 aalib? ( media-libs/aalib )
63 aac? ( >=media-libs/faad2-2.6.1 )
64 alsa? ( media-libs/alsa-lib )
65 avahi? ( >=net-dns/avahi-0.6[dbus] )
66 bidi? ( >=dev-libs/fribidi-0.10.4 )
67 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
68 dbus? ( >=sys-apps/dbus-1.0.2 )
69 dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
70 dirac? ( >=media-video/dirac-0.10.0 )
71 directfb? ( dev-libs/DirectFB sys-libs/zlib )
72 dts? ( media-libs/libdca )
73 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
74 elibc_glibc? ( >=sys-libs/glibc-2.8 )
75 ffmpeg? ( >=media-video/ffmpeg-0.6 )
76 flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
77 fluidsynth? ( media-sound/fluidsynth )
78 fontconfig? ( media-libs/fontconfig )
79 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
80 gme? ( media-libs/game-music-emu )
81 gnome? ( gnome-base/gnome-vfs )
82 gnutls? ( >=net-libs/gnutls-1.7.4 >=dev-libs/libgcrypt-1.2.0 )
83 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
84 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
85 kate? ( >=media-libs/libkate-0.1.1 )
86 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
87 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
88 libnotify? ( x11-libs/libnotify )
89 libproxy? ( net-libs/libproxy )
90 libtiger? ( media-libs/libtiger )
91 lirc? ( app-misc/lirc )
92 live? ( >=media-plugins/live-2010.10.15 )
93 lua? ( >=dev-lang/lua-5.1 )
94 matroska? ( >=dev-libs/libebml-1.0.0 >=media-libs/libmatroska-1.0.0 )
95 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
96 mp3? ( media-libs/libmad )
97 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
98 mtp? ( >=media-libs/libmtp-1.0.0 )
99 musepack? ( >=media-sound/musepack-tools-444 )
100 ncurses? ( sys-libs/ncurses )
101 ogg? ( media-libs/libogg )
102 opengl? ( virtual/opengl || ( <x11-libs/libX11-1.3.99.901[xcb] >=x11-libs/libX11-1.3.99.901 ) )
103 png? ( media-libs/libpng sys-libs/zlib )
104 projectm? ( media-libs/libprojectm )
105 pulseaudio? ( >=media-sound/pulseaudio-0.9.22 )
106 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
107 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
108 samba? ( || ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.4 ) )
109 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
110 sdl? ( >=media-libs/libsdl-1.2.8
111 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
112 shout? ( media-libs/libshout )
113 skins? (
114 x11-libs/qt-gui:4 x11-libs/qt-core:4
115 x11-libs/libXext x11-libs/libX11
116 media-libs/freetype media-fonts/dejavu
117 )
118 speex? ( media-libs/speex )
119 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
120 svg? ( >=gnome-base/librsvg-2.9.0 )
121 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
122 theora? ( >=media-libs/libtheora-1.0_beta3 )
123 truetype? ( media-libs/freetype media-fonts/dejavu )
124 twolame? ( media-sound/twolame )
125 udev? ( >=sys-fs/udev-142 )
126 upnp? ( net-libs/libupnp )
127 v4l2? ( libv4l2? ( media-libs/libv4l ) )
128 vaapi? ( x11-libs/libva >=media-video/ffmpeg-0.6 )
129 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
130 vorbis? ( media-libs/libvorbis )
131 win32codecs? ( media-libs/win32codecs )
132 X? ( x11-libs/libX11 )
133 x264? ( >=media-libs/x264-0.0.20090923 )
134 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
135 xml? ( dev-libs/libxml2 )
136 xosd? ( x11-libs/xosd )
137 zvbi? ( >=media-libs/zvbi-0.2.25 )
138 "
139
140 DEPEND="${RDEPEND}
141 !!<=media-video/vlc-1.1.99999
142 dvb? ( sys-kernel/linux-headers )
143 kde? ( >=kde-base/kdelibs-4 )
144 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
145 xcb? ( x11-proto/xproto )
146 dev-util/pkgconfig"
147
148 S="${WORKDIR}/${MY_P}"
149
150 # Displays a warning if the first use flag is set but the second is not
151 vlc_use_needs() {
152 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
153 }
154
155 # Notify the user that some useflag have been forced on
156 vlc_use_force() {
157 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
158 }
159
160 # Use when $1 depends strictly on $2
161 # if use $1 then enable $2
162 vlc_use_enable_force() {
163 use $1 && echo "--enable-$2"
164 }
165
166 pkg_setup() {
167 # Useflags we need to forcefuly enable
168 vlc_use_force remoteosd gcrypt
169 vlc_use_force gnutls gcrypt
170 vlc_use_force skins truetype
171 vlc_use_force skins qt4
172 vlc_use_force vlm stream
173 vlc_use_force vaapi ffmpeg
174
175 # Useflags that will be automagically discarded if deps are not met
176 vlc_use_needs bidi truetype
177 vlc_use_needs cddb cdda
178 vlc_use_needs fontconfig truetype
179 vlc_use_needs libv4l2 v4l2
180 vlc_use_needs libtiger kate
181 vlc_use_needs xv xcb
182
183 if use !qt4 && use !skins ; then
184 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
185 ewarn "graphical interface. Maybe that is not what you want..."
186 fi
187 }
188
189 src_unpack() {
190 unpack ${A}
191 if [ "${PV%9999}" != "${PV}" ] ; then
192 git_src_unpack
193 fi
194 }
195
196 src_prepare() {
197 if [ "${PV%9999}" != "${PV}" ] ; then
198 git_src_prepare
199 fi
200 # Make it build with libtool 1.5
201 rm -f m4/lt* m4/libtool.m4
202
203 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
204 eautoreconf
205 }
206
207 src_configure() {
208
209 # It would fail if -fforce-addr is used due to too few registers...
210 use x86 && filter-flags -fforce-addr
211
212 econf \
213 --docdir=/usr/share/doc/${PF} \
214 $(use_enable a52) \
215 $(use_enable aalib aa) \
216 $(use_enable aac faad) \
217 $(use_enable alsa) \
218 $(use_enable altivec) \
219 $(use_enable atmo) \
220 $(use_enable avahi bonjour) \
221 $(use_enable bidi fribidi) \
222 $(use_enable cdda vcd) \
223 $(use_enable cddb libcddb) \
224 $(use_enable dbus) $(use_enable dbus dbus-control) \
225 $(use_enable dirac) \
226 $(use_enable directfb) \
227 $(use_enable dc1394) \
228 $(use_enable debug) \
229 $(use_enable dts dca) \
230 $(use_enable dvb) \
231 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
232 $(use_enable fbcon fb) \
233 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
234 $(use_enable flac) \
235 $(use_enable fluidsynth) \
236 $(use_enable fontconfig) \
237 $(use_enable gme) \
238 $(use_enable gnome gnomevfs) \
239 $(use_enable gnutls) \
240 $(use_enable httpd) \
241 $(use_enable ieee1394 dv) \
242 $(use_enable jack) \
243 $(use_enable kate) \
244 $(use_with kde kde-solid) \
245 $(use_enable libass) \
246 $(use_enable libcaca caca) \
247 $(use_enable gcrypt libgcrypt) \
248 $(use_enable libnotify notify) \
249 $(use_enable libproxy) \
250 --disable-libtar \
251 $(use_enable libtiger tiger) \
252 $(use_enable libv4l2) \
253 $(use_enable lirc) \
254 $(use_enable live live555) \
255 $(use_enable lua) \
256 $(use_enable matroska mkv) \
257 $(use_enable mmx) \
258 $(use_enable modplug mod) \
259 $(use_enable mp3 mad) \
260 $(use_enable mpeg libmpeg2) \
261 $(use_enable mtp) \
262 $(use_enable musepack mpc) \
263 $(use_enable ncurses) \
264 $(use_enable ogg) \
265 $(use_enable opengl glx) \
266 $(use_enable optimisememory optimize-memory) \
267 $(use_enable oss) \
268 $(use_enable png) \
269 --disable-portaudio \
270 $(use_enable projectm) \
271 $(use_enable pulseaudio pulse) \
272 $(use_enable pvr) \
273 $(use_enable qt4) \
274 $(use_enable remoteosd) \
275 $(use_enable rtsp realrtsp) \
276 $(use_enable run-as-root) \
277 $(use_enable samba smb) \
278 $(use_enable schroedinger) \
279 $(use_enable sdl) \
280 $(use_enable sdl-image) \
281 $(use_enable shine) \
282 $(use_enable shout) \
283 $(use_enable skins skins2) \
284 $(use_enable speex) \
285 $(use_enable sqlite) \
286 $(use_enable sse) \
287 $(use_enable stream sout) \
288 $(use_enable svg) \
289 $(use_enable taglib) \
290 $(use_enable theora) \
291 $(use_enable truetype freetype) \
292 $(use_enable twolame) \
293 $(use_enable udev) \
294 $(use_enable upnp) \
295 $(use_enable v4l2) \
296 $(use_enable vcdx) \
297 $(use_enable vaapi libva) \
298 $(use_enable vlm) \
299 $(use_enable vorbis) \
300 $(use_enable win32codecs loader) \
301 $(use_enable wma-fixed) \
302 $(use_with X x) \
303 $(use_enable x264) \
304 $(use_enable xcb) \
305 $(use_enable xml libxml2) \
306 $(use_enable xosd) \
307 $(use_enable xv xvideo) \
308 $(use_enable zvbi) $(use_enable !zvbi telx) \
309 --disable-snapshot \
310 --disable-growl \
311 --disable-optimizations \
312 --enable-fast-install \
313 $(vlc_use_enable_force vlm sout) \
314 $(vlc_use_enable_force skins qt4) \
315 $(vlc_use_enable_force skins freetype) \
316 $(vlc_use_enable_force remoteosd libgcrypt) \
317 $(vlc_use_enable_force gnutls libgcrypt) \
318 $(vlc_use_enable_force vaapi avcodec)
319 }
320
321 src_install() {
322 emake DESTDIR="${D}" install || die "make install failed"
323
324 dodoc AUTHORS HACKING THANKS NEWS README \
325 doc/fortunes.txt doc/intf-vcd.txt
326
327 # Punt useless libtool's .la files
328 find "${D}" -name '*.la' -delete
329 }
330
331 pkg_postinst() {
332 gnome2_pkg_postinst
333
334 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
335 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
336 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
337 else
338 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
339 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
340 ewarn "If you do not do it, vlc will take a long time to load."
341 fi
342 }

  ViewVC Help
Powered by ViewVC 1.1.20