/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.101 - (show annotations) (download)
Sun Dec 26 13:57:23 2010 UTC (7 years, 10 months ago) by aballier
Branch: MAIN
Changes since 1.100: +8 -2 lines
Add libsidplay-2 support

(Portage version: 2.2.0_alpha10/cvs/Linux x86_64)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.100 2010/11/07 19:14:31 aballier Exp $
4
5 EAPI="3"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs gnome2 qt4-r2 flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25
26 PATCHLEVEL="89"
27 DESCRIPTION="VLC media player - Video player and streamer"
28 HOMEPAGE="http://www.videolan.org/vlc/"
29 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
30 SRC_URI=""
31 elif [[ "${MY_P}" == "${P}" ]]; then
32 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
33 else
34 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
35 fi
36
37 SRC_URI="${SRC_URI}
38 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
39
40 LICENSE="GPL-2"
41 SLOT="0"
42
43 if [ "${PV%9999}" = "${PV}" ] ; then
44 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
45 else
46 KEYWORDS=""
47 fi
48 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddb dbus dc1394
49 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
50 +gcrypt gme gnome gnutls httpd ieee1394 jack kate kde libass libcaca
51 libnotify libproxy libtiger libv4l2 lirc live lua matroska mmx
52 modplug mp3 mpeg mtp musepack ncurses ogg opengl optimisememory oss
53 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
54 schroedinger sdl sdl-image shine shout sid skins speex sqlite sse stream
55 svg taglib theora truetype twolame udev upnp v4l2 vaapi vcdx vlm
56 vorbis win32codecs wma-fixed +X x264 +xcb xml xosd xv zvbi"
57
58 RDEPEND="
59 sys-libs/zlib
60 >=media-libs/libdvbpsi-0.1.6
61 a52? ( >=media-libs/a52dec-0.7.4-r3 )
62 aalib? ( media-libs/aalib )
63 aac? ( >=media-libs/faad2-2.6.1 )
64 alsa? ( media-libs/alsa-lib )
65 avahi? ( >=net-dns/avahi-0.6[dbus] )
66 bidi? ( >=dev-libs/fribidi-0.10.4 )
67 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
68 dbus? ( >=sys-apps/dbus-1.0.2 )
69 dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
70 dirac? ( >=media-video/dirac-0.10.0 )
71 directfb? ( dev-libs/DirectFB sys-libs/zlib )
72 dts? ( media-libs/libdca )
73 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
74 elibc_glibc? ( >=sys-libs/glibc-2.8 )
75 ffmpeg? ( >=media-video/ffmpeg-0.6 )
76 flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
77 fluidsynth? ( media-sound/fluidsynth )
78 fontconfig? ( media-libs/fontconfig )
79 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
80 gme? ( media-libs/game-music-emu )
81 gnome? ( gnome-base/gnome-vfs )
82 gnutls? ( >=net-libs/gnutls-1.7.4 >=dev-libs/libgcrypt-1.2.0 )
83 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
84 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
85 kate? ( >=media-libs/libkate-0.1.1 )
86 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
87 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
88 libnotify? ( x11-libs/libnotify )
89 libproxy? ( net-libs/libproxy )
90 libtiger? ( media-libs/libtiger )
91 lirc? ( app-misc/lirc )
92 live? ( >=media-plugins/live-2010.10.15 )
93 lua? ( >=dev-lang/lua-5.1 )
94 matroska? ( >=dev-libs/libebml-1.0.0 >=media-libs/libmatroska-1.0.0 )
95 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
96 mp3? ( media-libs/libmad )
97 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
98 mtp? ( >=media-libs/libmtp-1.0.0 )
99 musepack? ( >=media-sound/musepack-tools-444 )
100 ncurses? ( sys-libs/ncurses )
101 ogg? ( media-libs/libogg )
102 opengl? ( virtual/opengl || ( <x11-libs/libX11-1.3.99.901[xcb] >=x11-libs/libX11-1.3.99.901 ) )
103 png? ( media-libs/libpng sys-libs/zlib )
104 projectm? ( media-libs/libprojectm )
105 pulseaudio? ( >=media-sound/pulseaudio-0.9.22 )
106 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
107 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
108 samba? ( || ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.4 ) )
109 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
110 sdl? ( >=media-libs/libsdl-1.2.8
111 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
112 shout? ( media-libs/libshout )
113 sid? ( media-libs/libsidplay:2 )
114 skins? (
115 x11-libs/qt-gui:4 x11-libs/qt-core:4
116 x11-libs/libXext x11-libs/libX11
117 media-libs/freetype media-fonts/dejavu
118 )
119 speex? ( media-libs/speex )
120 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
121 svg? ( >=gnome-base/librsvg-2.9.0 )
122 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
123 theora? ( >=media-libs/libtheora-1.0_beta3 )
124 truetype? ( media-libs/freetype media-fonts/dejavu )
125 twolame? ( media-sound/twolame )
126 udev? ( >=sys-fs/udev-142 )
127 upnp? ( net-libs/libupnp )
128 v4l2? ( libv4l2? ( media-libs/libv4l ) )
129 vaapi? ( x11-libs/libva >=media-video/ffmpeg-0.6 )
130 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
131 vorbis? ( media-libs/libvorbis )
132 win32codecs? ( media-libs/win32codecs )
133 X? ( x11-libs/libX11 )
134 x264? ( >=media-libs/x264-0.0.20090923 )
135 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
136 xml? ( dev-libs/libxml2 )
137 xosd? ( x11-libs/xosd )
138 zvbi? ( >=media-libs/zvbi-0.2.25 )
139 "
140
141 DEPEND="${RDEPEND}
142 !!<=media-video/vlc-1.1.99999
143 dvb? ( sys-kernel/linux-headers )
144 kde? ( >=kde-base/kdelibs-4 )
145 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
146 xcb? ( x11-proto/xproto )
147 dev-util/pkgconfig"
148
149 S="${WORKDIR}/${MY_P}"
150
151 # Displays a warning if the first use flag is set but the second is not
152 vlc_use_needs() {
153 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
154 }
155
156 # Notify the user that some useflag have been forced on
157 vlc_use_force() {
158 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
159 }
160
161 # Use when $1 depends strictly on $2
162 # if use $1 then enable $2
163 vlc_use_enable_force() {
164 use $1 && echo "--enable-$2"
165 }
166
167 pkg_setup() {
168 # Useflags we need to forcefuly enable
169 vlc_use_force remoteosd gcrypt
170 vlc_use_force gnutls gcrypt
171 vlc_use_force skins truetype
172 vlc_use_force skins qt4
173 vlc_use_force vlm stream
174 vlc_use_force vaapi ffmpeg
175
176 # Useflags that will be automagically discarded if deps are not met
177 vlc_use_needs bidi truetype
178 vlc_use_needs cddb cdda
179 vlc_use_needs fontconfig truetype
180 vlc_use_needs libv4l2 v4l2
181 vlc_use_needs libtiger kate
182 vlc_use_needs xv xcb
183
184 if use !qt4 && use !skins ; then
185 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
186 ewarn "graphical interface. Maybe that is not what you want..."
187 fi
188 }
189
190 src_unpack() {
191 unpack ${A}
192 if [ "${PV%9999}" != "${PV}" ] ; then
193 git_src_unpack
194 fi
195 }
196
197 src_prepare() {
198 if [ "${PV%9999}" != "${PV}" ] ; then
199 git_src_prepare
200 fi
201 # Make it build with libtool 1.5
202 rm -f m4/lt* m4/libtool.m4
203
204 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
205 eautoreconf
206 }
207
208 src_configure() {
209
210 # It would fail if -fforce-addr is used due to too few registers...
211 use x86 && filter-flags -fforce-addr
212
213 # needs libresid-builder from libsidplay:2 which is in another directory...
214 # FIXME!
215 use sid && append-ldflags "-L/usr/$(get_libdir)/sidplay/builders/"
216
217 econf \
218 --docdir=/usr/share/doc/${PF} \
219 $(use_enable a52) \
220 $(use_enable aalib aa) \
221 $(use_enable aac faad) \
222 $(use_enable alsa) \
223 $(use_enable altivec) \
224 $(use_enable atmo) \
225 $(use_enable avahi bonjour) \
226 $(use_enable bidi fribidi) \
227 $(use_enable cdda vcd) \
228 $(use_enable cddb libcddb) \
229 $(use_enable dbus) $(use_enable dbus dbus-control) \
230 $(use_enable dirac) \
231 $(use_enable directfb) \
232 $(use_enable dc1394) \
233 $(use_enable debug) \
234 $(use_enable dts dca) \
235 $(use_enable dvb) \
236 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
237 $(use_enable fbcon fb) \
238 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
239 $(use_enable flac) \
240 $(use_enable fluidsynth) \
241 $(use_enable fontconfig) \
242 $(use_enable gme) \
243 $(use_enable gnome gnomevfs) \
244 $(use_enable gnutls) \
245 $(use_enable httpd) \
246 $(use_enable ieee1394 dv) \
247 $(use_enable jack) \
248 $(use_enable kate) \
249 $(use_with kde kde-solid) \
250 $(use_enable libass) \
251 $(use_enable libcaca caca) \
252 $(use_enable gcrypt libgcrypt) \
253 $(use_enable libnotify notify) \
254 $(use_enable libproxy) \
255 --disable-libtar \
256 $(use_enable libtiger tiger) \
257 $(use_enable libv4l2) \
258 $(use_enable lirc) \
259 $(use_enable live live555) \
260 $(use_enable lua) \
261 $(use_enable matroska mkv) \
262 $(use_enable mmx) \
263 $(use_enable modplug mod) \
264 $(use_enable mp3 mad) \
265 $(use_enable mpeg libmpeg2) \
266 $(use_enable mtp) \
267 $(use_enable musepack mpc) \
268 $(use_enable ncurses) \
269 $(use_enable ogg) \
270 $(use_enable opengl glx) \
271 $(use_enable optimisememory optimize-memory) \
272 $(use_enable oss) \
273 $(use_enable png) \
274 --disable-portaudio \
275 $(use_enable projectm) \
276 $(use_enable pulseaudio pulse) \
277 $(use_enable pvr) \
278 $(use_enable qt4) \
279 $(use_enable remoteosd) \
280 $(use_enable rtsp realrtsp) \
281 $(use_enable run-as-root) \
282 $(use_enable samba smb) \
283 $(use_enable schroedinger) \
284 $(use_enable sdl) \
285 $(use_enable sdl-image) \
286 $(use_enable shine) \
287 $(use_enable sid) \
288 $(use_enable shout) \
289 $(use_enable skins skins2) \
290 $(use_enable speex) \
291 $(use_enable sqlite) \
292 $(use_enable sse) \
293 $(use_enable stream sout) \
294 $(use_enable svg) \
295 $(use_enable taglib) \
296 $(use_enable theora) \
297 $(use_enable truetype freetype) \
298 $(use_enable twolame) \
299 $(use_enable udev) \
300 $(use_enable upnp) \
301 $(use_enable v4l2) \
302 $(use_enable vcdx) \
303 $(use_enable vaapi libva) \
304 $(use_enable vlm) \
305 $(use_enable vorbis) \
306 $(use_enable win32codecs loader) \
307 $(use_enable wma-fixed) \
308 $(use_with X x) \
309 $(use_enable x264) \
310 $(use_enable xcb) \
311 $(use_enable xml libxml2) \
312 $(use_enable xosd) \
313 $(use_enable xv xvideo) \
314 $(use_enable zvbi) $(use_enable !zvbi telx) \
315 --disable-snapshot \
316 --disable-growl \
317 --disable-optimizations \
318 --enable-fast-install \
319 $(vlc_use_enable_force vlm sout) \
320 $(vlc_use_enable_force skins qt4) \
321 $(vlc_use_enable_force skins freetype) \
322 $(vlc_use_enable_force remoteosd libgcrypt) \
323 $(vlc_use_enable_force gnutls libgcrypt) \
324 $(vlc_use_enable_force vaapi avcodec)
325 }
326
327 src_install() {
328 emake DESTDIR="${D}" install || die "make install failed"
329
330 dodoc AUTHORS HACKING THANKS NEWS README \
331 doc/fortunes.txt doc/intf-vcd.txt
332
333 # Punt useless libtool's .la files
334 find "${D}" -name '*.la' -delete
335 }
336
337 pkg_postinst() {
338 gnome2_pkg_postinst
339
340 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
341 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
342 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
343 else
344 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
345 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
346 ewarn "If you do not do it, vlc will take a long time to load."
347 fi
348 }

  ViewVC Help
Powered by ViewVC 1.1.20