/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.115 - (show annotations) (download)
Wed Feb 16 19:07:30 2011 UTC (6 years, 2 months ago) by aballier
Branch: MAIN
Changes since 1.114: +4 -2 lines
add switcher useflag

(Portage version: 2.2.0_alpha24/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.114 2011/02/16 18:32:23 aballier Exp $
4
5 EAPI="4"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25
26 PATCHLEVEL="89"
27 DESCRIPTION="VLC media player - Video player and streamer"
28 HOMEPAGE="http://www.videolan.org/vlc/"
29 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
30 SRC_URI=""
31 elif [[ "${MY_P}" == "${P}" ]]; then
32 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
33 else
34 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
35 fi
36
37 SRC_URI="${SRC_URI}
38 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
39
40 LICENSE="GPL-2"
41 SLOT="0"
42
43 if [ "${PV%9999}" = "${PV}" ] ; then
44 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
45 else
46 KEYWORDS=""
47 fi
48 IUSE="a52 aac aalib alsa altivec atmo avahi bda bidi bluray cdda cddb dbus dc1394
49 debug dirac directfb dshow dts dvb +dvbpsi dvd dxva2 elibc_glibc +encode fbcon fluidsynth +ffmpeg flac fontconfig
50 +gcrypt gme gnome gnutls growl httpd ieee1394 jack kate kde libass libcaca
51 libnotify libproxy libtiger libv4l2 linsys lirc live lua matroska mmx
52 modplug mp3 mpeg mtp musepack ncurses ogg omxil opengl optimisememory oss
53 png projectm pulseaudio pvr +qt4 rtsp run-as-root samba
54 schroedinger sdl sdl-image shine shout sid skins speex sqlite sse
55 svg switcher taglib theora truetype twolame udev upnp v4l2 vaapi vcdx vlm
56 vorbis win32codecs wma-fixed +X x264 +xcb xml xosd xv zvbi"
57
58 RDEPEND="
59 sys-libs/zlib
60 a52? ( >=media-libs/a52dec-0.7.4-r3 )
61 aalib? ( media-libs/aalib )
62 aac? ( >=media-libs/faad2-2.6.1 )
63 alsa? ( >=media-libs/alsa-lib-1.0.23 )
64 avahi? ( >=net-dns/avahi-0.6[dbus] )
65 bidi? ( >=dev-libs/fribidi-0.10.4 )
66 bluray? ( media-libs/libbluray )
67 cddb? ( >=media-libs/libcddb-1.2.0 )
68 dbus? ( >=sys-apps/dbus-1.0.2 )
69 dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
70 dirac? ( >=media-video/dirac-0.10.0 )
71 directfb? ( dev-libs/DirectFB sys-libs/zlib )
72 dts? ( media-libs/libdca )
73 dvbpsi? ( >=media-libs/libdvbpsi-0.1.6 )
74 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
75 elibc_glibc? ( >=sys-libs/glibc-2.8 )
76 ffmpeg? ( >=media-video/ffmpeg-0.6 )
77 flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
78 fluidsynth? ( media-sound/fluidsynth )
79 fontconfig? ( media-libs/fontconfig )
80 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
81 gme? ( media-libs/game-music-emu )
82 gnome? ( gnome-base/gnome-vfs )
83 gnutls? ( >=net-libs/gnutls-1.7.4 )
84 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
85 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
86 kate? ( >=media-libs/libkate-0.1.1 )
87 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
88 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
89 libnotify? ( x11-libs/libnotify x11-libs/gtk+:2 )
90 libproxy? ( net-libs/libproxy )
91 libtiger? ( media-libs/libtiger )
92 linsys? ( >=media-libs/zvbi-0.2.28 )
93 lirc? ( app-misc/lirc )
94 live? ( >=media-plugins/live-2010.10.15 )
95 lua? ( >=dev-lang/lua-5.1 )
96 matroska? ( >=dev-libs/libebml-1.0.0 >=media-libs/libmatroska-1.0.0 )
97 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
98 mp3? ( media-libs/libmad )
99 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
100 mtp? ( >=media-libs/libmtp-1.0.0 )
101 musepack? ( >=media-sound/musepack-tools-444 )
102 ncurses? ( sys-libs/ncurses )
103 ogg? ( media-libs/libogg )
104 opengl? ( virtual/opengl || ( >=x11-libs/libX11-1.3.99.901 <x11-libs/libX11-1.3.99.901[xcb] ) )
105 png? ( media-libs/libpng sys-libs/zlib )
106 projectm? ( media-libs/libprojectm )
107 pulseaudio? ( >=media-sound/pulseaudio-0.9.22 )
108 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
109 samba? ( || ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.4 ) )
110 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
111 sdl? ( >=media-libs/libsdl-1.2.8
112 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
113 shout? ( media-libs/libshout )
114 sid? ( media-libs/libsidplay:2 )
115 speex? ( media-libs/speex )
116 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
117 svg? ( >=gnome-base/librsvg-2.9.0 )
118 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
119 theora? ( >=media-libs/libtheora-1.0_beta3 )
120 truetype? ( media-libs/freetype media-fonts/dejavu )
121 twolame? ( media-sound/twolame )
122 udev? ( >=sys-fs/udev-142 )
123 upnp? ( net-libs/libupnp )
124 libv4l2? ( media-libs/libv4l )
125 vaapi? ( x11-libs/libva )
126 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
127 vorbis? ( media-libs/libvorbis )
128 win32codecs? ( media-libs/win32codecs )
129 X? ( x11-libs/libX11 )
130 x264? ( >=media-libs/x264-0.0.20090923 )
131 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
132 xml? ( dev-libs/libxml2 )
133 xosd? ( x11-libs/xosd )
134 zvbi? ( >=media-libs/zvbi-0.2.25 )
135 "
136
137 DEPEND="${RDEPEND}
138 !!<=media-video/vlc-1.1.99999
139 alsa? ( >=media-sound/alsa-headers-1.0.23 )
140 dvb? ( sys-kernel/linux-headers )
141 kde? ( >=kde-base/kdelibs-4 )
142 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
143 xcb? ( x11-proto/xproto )
144 dev-util/pkgconfig"
145
146 REQUIRED_USE="
147 bidi? ( truetype )
148 cddb? ( cdda )
149 dvb? ( dvbpsi )
150 dxva2? ( ffmpeg )
151 fontconfig? ( truetype )
152 gnutls? ( gcrypt )
153 libtiger? ( kate )
154 libv4l2? ( v4l2 )
155 qt4? ( X )
156 skins? ( truetype qt4 )
157 switcher? ( ffmpeg )
158 vaapi? ( ffmpeg )
159 vlm? ( encode )
160 xv? ( xcb )
161 "
162
163 S="${WORKDIR}/${MY_P}"
164
165 src_unpack() {
166 unpack ${A}
167 if [ "${PV%9999}" != "${PV}" ] ; then
168 git_src_unpack
169 fi
170 }
171
172 src_prepare() {
173 if [ "${PV%9999}" != "${PV}" ] ; then
174 git_src_prepare
175 fi
176 # Make it build with libtool 1.5
177 rm -f m4/lt* m4/libtool.m4
178
179 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
180 eautoreconf
181 }
182
183 src_configure() {
184 # needs libresid-builder from libsidplay:2 which is in another directory...
185 # FIXME!
186 use sid && append-ldflags "-L/usr/$(get_libdir)/sidplay/builders/"
187
188 econf \
189 --docdir=/usr/share/doc/${PF} \
190 $(use_enable a52) \
191 $(use_enable aalib aa) \
192 $(use_enable aac faad) \
193 $(use_enable alsa) \
194 $(use_enable altivec) \
195 $(use_enable atmo) \
196 $(use_enable avahi bonjour) \
197 $(use_enable bda) \
198 $(use_enable bidi fribidi) \
199 $(use_enable bluray) \
200 $(use_enable cdda vcd) \
201 $(use_enable cddb libcddb) \
202 $(use_enable dbus) $(use_enable dbus dbus-control) \
203 $(use_enable dirac) \
204 $(use_enable directfb) \
205 $(use_enable dc1394) \
206 $(use_enable debug) \
207 $(use_enable dshow) \
208 $(use_enable dts dca) \
209 $(use_enable dvb) \
210 $(use_enable dvbpsi) \
211 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
212 $(use_enable dxva2) \
213 $(use_enable encode sout) \
214 $(use_enable fbcon fb) \
215 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
216 $(use_enable flac) \
217 $(use_enable fluidsynth) \
218 $(use_enable fontconfig) \
219 $(use_enable gme) \
220 $(use_enable gnome gnomevfs) \
221 $(use_enable gnutls) \
222 $(use_enable growl) \
223 $(use_enable httpd) \
224 $(use_enable ieee1394 dv) \
225 $(use_enable jack) \
226 $(use_enable kate) \
227 $(use_with kde kde-solid) \
228 $(use_enable libass) \
229 $(use_enable libcaca caca) \
230 $(use_enable gcrypt libgcrypt) \
231 $(use_enable libnotify notify) \
232 $(use_enable libproxy) \
233 --disable-libtar \
234 $(use_enable libtiger tiger) \
235 $(use_enable libv4l2) \
236 $(use_enable linsys) \
237 $(use_enable lirc) \
238 $(use_enable live live555) \
239 $(use_enable lua) \
240 $(use_enable matroska mkv) \
241 $(use_enable mmx) \
242 $(use_enable modplug mod) \
243 $(use_enable mp3 mad) \
244 $(use_enable mpeg libmpeg2) \
245 $(use_enable mtp) \
246 $(use_enable musepack mpc) \
247 $(use_enable ncurses) \
248 $(use_enable ogg) \
249 $(use_enable omxil) \
250 $(use_enable opengl glx) \
251 $(use_enable optimisememory optimize-memory) \
252 $(use_enable oss) \
253 $(use_enable png) \
254 --disable-portaudio \
255 $(use_enable projectm) \
256 $(use_enable pulseaudio pulse) \
257 $(use_enable pvr) \
258 $(use_enable qt4) \
259 $(use_enable rtsp realrtsp) \
260 $(use_enable run-as-root) \
261 $(use_enable samba smb) \
262 $(use_enable schroedinger) \
263 $(use_enable sdl) \
264 $(use_enable sdl-image) \
265 $(use_enable shine) \
266 $(use_enable sid) \
267 $(use_enable shout) \
268 $(use_enable skins skins2) \
269 $(use_enable speex) \
270 $(use_enable sqlite) \
271 $(use_enable sse) \
272 $(use_enable svg) \
273 $(use_enable switcher) \
274 $(use_enable taglib) \
275 $(use_enable theora) \
276 $(use_enable truetype freetype) \
277 $(use_enable twolame) \
278 $(use_enable udev) \
279 $(use_enable upnp) \
280 $(use_enable v4l2) \
281 $(use_enable vcdx) \
282 $(use_enable vaapi libva) \
283 $(use_enable vlm) \
284 $(use_enable vorbis) \
285 $(use_enable win32codecs loader) \
286 $(use_enable wma-fixed) \
287 $(use_with X x) \
288 $(use_enable x264) \
289 $(use_enable xcb) \
290 $(use_enable xml libxml2) \
291 $(use_enable xosd) \
292 $(use_enable xv xvideo) \
293 $(use_enable zvbi) $(use_enable !zvbi telx) \
294 --disable-snapshot \
295 --disable-optimizations \
296 --enable-fast-install
297 }
298
299 src_install() {
300 emake DESTDIR="${D}" install || die "make install failed"
301
302 dodoc AUTHORS HACKING THANKS NEWS README \
303 doc/fortunes.txt doc/intf-vcd.txt
304
305 # Punt useless libtool's .la files
306 find "${D}" -name '*.la' -delete
307 }
308
309 pkg_postinst() {
310 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
311 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
312 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
313 else
314 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
315 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
316 ewarn "If you do not do it, vlc will take a long time to load."
317 fi
318 }

  ViewVC Help
Powered by ViewVC 1.1.20