/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.118 - (show annotations) (download)
Wed Feb 16 19:45:50 2011 UTC (4 years, 2 months ago) by aballier
Branch: MAIN
Changes since 1.117: +3 -2 lines
readd some deps for skins useflag that were lost

(Portage version: 2.2.0_alpha24/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.117 2011/02/16 19:37:11 aballier Exp $
4
5 EAPI="4"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25
26 PATCHLEVEL="89"
27 DESCRIPTION="VLC media player - Video player and streamer"
28 HOMEPAGE="http://www.videolan.org/vlc/"
29 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
30 SRC_URI=""
31 elif [[ "${MY_P}" == "${P}" ]]; then
32 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
33 else
34 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
35 fi
36
37 SRC_URI="${SRC_URI}
38 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
39
40 LICENSE="GPL-2"
41 SLOT="0"
42
43 if [ "${PV%9999}" = "${PV}" ] ; then
44 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
45 else
46 KEYWORDS=""
47 fi
48 IUSE="a52 aac aalib alsa altivec atmo avahi bda bidi bluray cdda cddb dbus dc1394
49 debug dirac direct2d directfb directx dshow dts dvb +dvbpsi dvd dxva2 elibc_glibc egl +encode fbcon fluidsynth +ffmpeg flac fontconfig
50 +gcrypt gme gnome gnutls growl httpd ieee1394 jack kate kde libass libcaca
51 libnotify libproxy libtiger libv4l2 linsys lirc live lua matroska mmx
52 modplug mp3 mpeg mtp musepack ncurses ogg omxil opengl optimisememory oss
53 png projectm pulseaudio pvr +qt4 rtsp run-as-root samba
54 schroedinger sdl sdl-image shine shout sid skins speex sqlite sse
55 svg switcher taglib theora truetype twolame udev upnp v4l2 vaapi vcdx vlm
56 vorbis waveout win32codecs wingdi wma-fixed +X x264 +xcb xml xosd xv zvbi"
57
58 RDEPEND="
59 sys-libs/zlib
60 a52? ( >=media-libs/a52dec-0.7.4-r3 )
61 aalib? ( media-libs/aalib )
62 aac? ( >=media-libs/faad2-2.6.1 )
63 alsa? ( >=media-libs/alsa-lib-1.0.23 )
64 avahi? ( >=net-dns/avahi-0.6[dbus] )
65 bidi? ( >=dev-libs/fribidi-0.10.4 )
66 bluray? ( media-libs/libbluray )
67 cddb? ( >=media-libs/libcddb-1.2.0 )
68 dbus? ( >=sys-apps/dbus-1.0.2 )
69 dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
70 dirac? ( >=media-video/dirac-0.10.0 )
71 directfb? ( dev-libs/DirectFB sys-libs/zlib )
72 dts? ( media-libs/libdca )
73 dvbpsi? ( >=media-libs/libdvbpsi-0.1.6 )
74 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
75 egl? ( virtual/opengl )
76 elibc_glibc? ( >=sys-libs/glibc-2.8 )
77 ffmpeg? ( >=media-video/ffmpeg-0.6 )
78 flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
79 fluidsynth? ( media-sound/fluidsynth )
80 fontconfig? ( media-libs/fontconfig )
81 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
82 gme? ( media-libs/game-music-emu )
83 gnome? ( gnome-base/gnome-vfs )
84 gnutls? ( >=net-libs/gnutls-1.7.4 )
85 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
86 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
87 kate? ( >=media-libs/libkate-0.1.1 )
88 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
89 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
90 libnotify? ( x11-libs/libnotify x11-libs/gtk+:2 )
91 libproxy? ( net-libs/libproxy )
92 libtiger? ( media-libs/libtiger )
93 linsys? ( >=media-libs/zvbi-0.2.28 )
94 lirc? ( app-misc/lirc )
95 live? ( >=media-plugins/live-2010.10.15 )
96 lua? ( >=dev-lang/lua-5.1 )
97 matroska? ( >=dev-libs/libebml-1.0.0 >=media-libs/libmatroska-1.0.0 )
98 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
99 mp3? ( media-libs/libmad )
100 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
101 mtp? ( >=media-libs/libmtp-1.0.0 )
102 musepack? ( >=media-sound/musepack-tools-444 )
103 ncurses? ( sys-libs/ncurses )
104 ogg? ( media-libs/libogg )
105 opengl? ( virtual/opengl || ( >=x11-libs/libX11-1.3.99.901 <x11-libs/libX11-1.3.99.901[xcb] ) )
106 png? ( media-libs/libpng sys-libs/zlib )
107 projectm? ( media-libs/libprojectm )
108 pulseaudio? ( >=media-sound/pulseaudio-0.9.22 )
109 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
110 samba? ( || ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.4 ) )
111 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
112 sdl? ( >=media-libs/libsdl-1.2.8
113 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
114 shout? ( media-libs/libshout )
115 sid? ( media-libs/libsidplay:2 )
116 skins? ( x11-libs/libXext x11-libs/libXpm )
117 speex? ( media-libs/speex )
118 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
119 svg? ( >=gnome-base/librsvg-2.9.0 )
120 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
121 theora? ( >=media-libs/libtheora-1.0_beta3 )
122 truetype? ( media-libs/freetype media-fonts/dejavu )
123 twolame? ( media-sound/twolame )
124 udev? ( >=sys-fs/udev-142 )
125 upnp? ( net-libs/libupnp )
126 libv4l2? ( media-libs/libv4l )
127 vaapi? ( x11-libs/libva )
128 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
129 vorbis? ( media-libs/libvorbis )
130 win32codecs? ( media-libs/win32codecs )
131 X? ( x11-libs/libX11 )
132 x264? ( >=media-libs/x264-0.0.20090923 )
133 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
134 xml? ( dev-libs/libxml2 )
135 xosd? ( x11-libs/xosd )
136 zvbi? ( >=media-libs/zvbi-0.2.25 )
137 "
138
139 DEPEND="${RDEPEND}
140 !!<=media-video/vlc-1.1.99999
141 alsa? ( >=media-sound/alsa-headers-1.0.23 )
142 dvb? ( sys-kernel/linux-headers )
143 kde? ( >=kde-base/kdelibs-4 )
144 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
145 xcb? ( x11-proto/xproto )
146 dev-util/pkgconfig"
147
148 REQUIRED_USE="
149 bidi? ( truetype )
150 cddb? ( cdda )
151 dvb? ( dvbpsi )
152 dxva2? ( ffmpeg )
153 fontconfig? ( truetype )
154 gnutls? ( gcrypt )
155 libtiger? ( kate )
156 libv4l2? ( v4l2 )
157 qt4? ( X )
158 skins? ( truetype qt4 X )
159 switcher? ( ffmpeg )
160 vaapi? ( ffmpeg )
161 vlm? ( encode )
162 xv? ( xcb )
163 "
164
165 S="${WORKDIR}/${MY_P}"
166
167 src_unpack() {
168 unpack ${A}
169 if [ "${PV%9999}" != "${PV}" ] ; then
170 git_src_unpack
171 fi
172 }
173
174 src_prepare() {
175 if [ "${PV%9999}" != "${PV}" ] ; then
176 git_src_prepare
177 fi
178 # Make it build with libtool 1.5
179 rm -f m4/lt* m4/libtool.m4
180
181 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
182 eautoreconf
183 }
184
185 src_configure() {
186 # needs libresid-builder from libsidplay:2 which is in another directory...
187 # FIXME!
188 use sid && append-ldflags "-L/usr/$(get_libdir)/sidplay/builders/"
189
190 econf \
191 --docdir=/usr/share/doc/${PF} \
192 $(use_enable a52) \
193 $(use_enable aalib aa) \
194 $(use_enable aac faad) \
195 $(use_enable alsa) \
196 $(use_enable altivec) \
197 $(use_enable atmo) \
198 $(use_enable avahi bonjour) \
199 $(use_enable bda) \
200 $(use_enable bidi fribidi) \
201 $(use_enable bluray) \
202 $(use_enable cdda vcd) \
203 $(use_enable cddb libcddb) \
204 $(use_enable dbus) $(use_enable dbus dbus-control) \
205 $(use_enable dirac) \
206 $(use_enable direct2d) \
207 $(use_enable directfb) \
208 $(use_enable directx) \
209 $(use_enable dc1394) \
210 $(use_enable debug) \
211 $(use_enable dshow) \
212 $(use_enable dts dca) \
213 $(use_enable dvb) \
214 $(use_enable dvbpsi) \
215 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
216 $(use_enable dxva2) \
217 $(use_enable egl) \
218 $(use_enable encode sout) \
219 $(use_enable fbcon fb) \
220 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
221 $(use_enable flac) \
222 $(use_enable fluidsynth) \
223 $(use_enable fontconfig) \
224 $(use_enable gme) \
225 $(use_enable gnome gnomevfs) \
226 $(use_enable gnutls) \
227 $(use_enable growl) \
228 $(use_enable httpd) \
229 $(use_enable ieee1394 dv) \
230 $(use_enable jack) \
231 $(use_enable kate) \
232 $(use_with kde kde-solid) \
233 $(use_enable libass) \
234 $(use_enable libcaca caca) \
235 $(use_enable gcrypt libgcrypt) \
236 $(use_enable libnotify notify) \
237 $(use_enable libproxy) \
238 --disable-libtar \
239 $(use_enable libtiger tiger) \
240 $(use_enable libv4l2) \
241 $(use_enable linsys) \
242 $(use_enable lirc) \
243 $(use_enable live live555) \
244 $(use_enable lua) \
245 $(use_enable matroska mkv) \
246 $(use_enable mmx) \
247 $(use_enable modplug mod) \
248 $(use_enable mp3 mad) \
249 $(use_enable mpeg libmpeg2) \
250 $(use_enable mtp) \
251 $(use_enable musepack mpc) \
252 $(use_enable ncurses) \
253 $(use_enable ogg) \
254 $(use_enable omxil) \
255 $(use_enable opengl glx) \
256 $(use_enable optimisememory optimize-memory) \
257 $(use_enable oss) \
258 $(use_enable png) \
259 --disable-portaudio \
260 $(use_enable projectm) \
261 $(use_enable pulseaudio pulse) \
262 $(use_enable pvr) \
263 $(use_enable qt4) \
264 $(use_enable rtsp realrtsp) \
265 $(use_enable run-as-root) \
266 $(use_enable samba smb) \
267 $(use_enable schroedinger) \
268 $(use_enable sdl) \
269 $(use_enable sdl-image) \
270 $(use_enable shine) \
271 $(use_enable sid) \
272 $(use_enable shout) \
273 $(use_enable skins skins2) \
274 $(use_enable speex) \
275 $(use_enable sqlite) \
276 $(use_enable sse) \
277 $(use_enable svg) \
278 $(use_enable switcher) \
279 $(use_enable taglib) \
280 $(use_enable theora) \
281 $(use_enable truetype freetype) \
282 $(use_enable twolame) \
283 $(use_enable udev) \
284 $(use_enable upnp) \
285 $(use_enable v4l2) \
286 $(use_enable vcdx) \
287 $(use_enable vaapi libva) \
288 $(use_enable vlm) \
289 $(use_enable vorbis) \
290 $(use_enable waveout) \
291 $(use_enable win32codecs loader) \
292 $(use_enable wingdi) \
293 $(use_enable wma-fixed) \
294 $(use_with X x) \
295 $(use_enable x264) \
296 $(use_enable xcb) \
297 $(use_enable xml libxml2) \
298 $(use_enable xosd) \
299 $(use_enable xv xvideo) \
300 $(use_enable zvbi) $(use_enable !zvbi telx) \
301 --disable-snapshot \
302 --disable-optimizations \
303 --enable-fast-install
304 }
305
306 src_install() {
307 emake DESTDIR="${D}" install || die "make install failed"
308
309 dodoc AUTHORS HACKING THANKS NEWS README \
310 doc/fortunes.txt doc/intf-vcd.txt
311
312 # Punt useless libtool's .la files
313 find "${D}" -name '*.la' -delete
314 }
315
316 pkg_postinst() {
317 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
318 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
319 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
320 else
321 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
322 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
323 ewarn "If you do not do it, vlc will take a long time to load."
324 fi
325 }

  ViewVC Help
Powered by ViewVC 1.1.20