/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.16 - (show annotations) (download)
Sun Jun 28 19:33:36 2009 UTC (7 years, 11 months ago) by pva
Branch: MAIN
Changes since 1.15: +4 -4 lines
Sort USE flags alphabetically as requested by Alexis Ballier.
(Portage version: 2.2_rc33/cvs/Linux i686)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.15 2009/06/27 10:37:09 alexxy Exp $
4
5 EAPI="1"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
11 EGIT_BOOTSTRAP="bootstrap"
12 if [ "${PV%.9999}" != "${PV}" ] ; then
13 EGIT_BRANCH=${PV%.9999}-bugfix
14 else
15 EGIT_BRANCH=master
16 fi
17 fi
18
19 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
20
21 MY_PV="${PV/_/-}"
22 MY_PV="${MY_PV/-beta/-test}"
23 MY_P="${PN}-${MY_PV}"
24 VLC_SNAPSHOT_TIME="0013"
25
26 PATCHLEVEL="59"
27 M4_TARBALL_VERSION="1"
28 DESCRIPTION="VLC media player - Video player and streamer"
29 HOMEPAGE="http://www.videolan.org/vlc/"
30 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
31 SRC_URI=""
32 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
33 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
34 MY_P="${P/_alpha*/}-git"
35 elif [[ "${MY_P}" == "${P}" ]]; then
36 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
37 else
38 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
39 fi
40
41 SRC_URI="${SRC_URI}
42 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2
43 mirror://gentoo/${PN}-m4-${M4_TARBALL_VERSION}.tar.bz2"
44
45 LICENSE="GPL-2"
46 SLOT="0"
47
48 KEYWORDS=""
49 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddax cddb cdio dbus dc1394
50 debug dirac directfb dts dvb dvd fbcon fluidsynth +ffmpeg flac fontconfig +gcrypt ggi gnome gnutls hal httpd
51 id3tag jack kate libass libcaca libnotify libproxy libsysfs libv4l2 lirc live lua matroska mmx modplug mp3 mpeg mtp
52 musepack ncurses nsplugin ogg opengl optimisememory oss pda png pulseaudio pvr +qt4
53 remoteosd rtsp run-as-root samba schroedinger sdl sdl-image seamonkey shine shout skins speex sse stream svg svga taglib
54 theora truetype twolame upnp v4l v4l2 vcdinfo vcdx vlm vorbis win32codecs wma-fixed
55 X x264 xcb xinerama xml xosd xv zvbi"
56
57 RDEPEND="
58 sys-libs/zlib
59 media-libs/libdvbpsi
60 a52? ( >=media-libs/a52dec-0.7.4-r3 )
61 aalib? ( media-libs/aalib )
62 aac? ( >=media-libs/faad2-2.6.1 )
63 alsa? ( media-libs/alsa-lib )
64 avahi? ( >=net-dns/avahi-0.6 )
65 bidi? ( >=dev-libs/fribidi-0.10.4 )
66 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
67 cddax? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
68 cdio? ( >=dev-libs/libcdio-0.78.2 )
69 dbus? ( >=sys-apps/dbus-1.0.2 )
70 dc1394? ( sys-libs/libraw1394
71 <media-libs/libdc1394-1.9.99 )
72 dirac? ( >=media-video/dirac-0.10.0 )
73 directfb? ( dev-libs/DirectFB )
74 dts? ( media-libs/libdca )
75 dvd? ( media-libs/libdvdread
76 media-libs/libdvdcss
77 >=media-libs/libdvdnav-0.1.9
78 media-libs/libdvdplay )
79 ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20090201 )
80 flac? ( media-libs/libogg
81 >=media-libs/flac-1.1.2 )
82 fluidsynth? ( media-sound/fluidsynth )
83 fontconfig? ( media-libs/fontconfig )
84 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
85 ggi? ( media-libs/libggi )
86 gnome? ( gnome-base/gnome-vfs )
87 gnutls? ( >=net-libs/gnutls-1.7.4 )
88 hal? ( sys-apps/hal )
89 id3tag? ( media-libs/libid3tag
90 sys-libs/zlib )
91 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
92 kate? ( >=media-libs/libkate-0.1.1 )
93 libass? ( >=media-libs/libass-0.9.5 media-libs/fontconfig )
94 libcaca? ( media-libs/libcaca )
95 libnotify? ( x11-libs/libnotify )
96 libproxy? ( net-libs/libproxy )
97 libsysfs? ( sys-fs/sysfsutils )
98 lirc? ( app-misc/lirc )
99 live? ( >=media-plugins/live-2008.07.06 )
100 lua? ( >=dev-lang/lua-5.1 )
101 matroska? (
102 >=dev-libs/libebml-0.7.6
103 >=media-libs/libmatroska-0.8.0 )
104 modplug? ( media-libs/libmodplug )
105 mp3? ( media-libs/libmad )
106 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
107 mtp? ( >=media-libs/libmtp-0.3.0 )
108 musepack? ( media-libs/libmpcdec )
109 ncurses? ( sys-libs/ncurses )
110 nsplugin? (
111 seamonkey? ( =www-client/seamonkey-1* )
112 !seamonkey? ( >=net-libs/xulrunner-1.8 )
113 )
114 ogg? ( media-libs/libogg )
115 pda? ( x11-libs/gtk+:2 )
116 png? ( media-libs/libpng )
117 pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
118 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
119 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
120 samba? ( net-fs/samba )
121 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
122 sdl? ( >=media-libs/libsdl-1.2.8
123 sdl-image? ( media-libs/sdl-image ) )
124 shout? ( media-libs/libshout )
125 skins? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
126 speex? ( media-libs/speex )
127 svg? ( >=gnome-base/librsvg-2.9.0 )
128 svga? ( media-libs/svgalib )
129 taglib? ( >=media-libs/taglib-1.5 )
130 theora? ( >=media-libs/libtheora-1.0_beta3 )
131 truetype? ( media-libs/freetype
132 media-fonts/ttf-bitstream-vera )
133 twolame? ( media-sound/twolame )
134 upnp? ( net-libs/libupnp )
135 v4l2? ( libv4l2? ( media-libs/libv4l ) )
136 vcdinfo? ( >=media-video/vcdimager-0.7.22 )
137 vorbis? ( media-libs/libvorbis )
138 win32codecs? ( media-libs/win32codecs )
139 X? (
140 x11-libs/libX11
141 x11-libs/libXext
142 xv? ( x11-libs/libXv )
143 xinerama? ( x11-libs/libXinerama )
144 opengl? ( virtual/opengl )
145 )
146 x264? ( media-libs/x264 )
147 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
148 xml? ( dev-libs/libxml2 )
149 xosd? ( x11-libs/xosd )
150 zvbi? ( >=media-libs/zvbi-0.2.25 )
151 "
152
153 # Disabled features and reasons:
154 # xvmc? ( x11-libs/libXvMC )
155 # Will probably compile only on x86
156
157 DEPEND="${RDEPEND}
158 dvb? ( sys-kernel/linux-headers )
159 v4l? ( sys-kernel/linux-headers )
160 v4l2? ( sys-kernel/linux-headers )
161 X? ( xinerama? ( x11-proto/xineramaproto ) )
162 xcb? ( x11-proto/xproto )
163 dev-util/pkgconfig"
164
165 S="${WORKDIR}/${MY_P}"
166
167 # Displays a warning if the first use flag is set but the second is not
168 vlc_use_needs() {
169 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
170 }
171
172 # Notify the user that some useflag have been forced on
173 vlc_use_force() {
174 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
175 }
176
177 # Use when $2 depends strictly on $3
178 # if use $1 then enable $2 and $3, otherwise disable $2
179 vlc_use_enable_force() {
180 if use $1 ; then
181 echo "--enable-$2 --enable-$3"
182 else
183 echo "--disable-$2"
184 fi
185 }
186
187 pkg_setup() {
188 if has_version '<=media-video/vlc-0.9.9999'; then
189 eerror "Please unmerge vlc-0.9.x first before installing ${P}"
190 eerror "If you don't do that, some plugins will get linked against"
191 eerror "the old ${PN} version and will not work."
192 die "Unmerge vlc 0.9.x first"
193 fi
194 vlc_use_needs skins truetype
195 vlc_use_force skins qt4
196 vlc_use_needs cddax cdio
197 vlc_use_needs vcdx cdio
198 vlc_use_needs vcdx vcdinfo
199 vlc_use_needs vcdinfo cdio
200 vlc_use_needs bidi truetype
201 vlc_use_force remoteosd gcrypt
202 vlc_use_needs fontconfig truetype
203 vlc_use_needs libv4l2 v4l2
204 use cddb && use !cdda && use !cddax && ewarn "USE=cddb requires either cdda or cddax, cddb will be disabled."
205 if use qt4 || use skins ; then
206 qt4_pkg_setup
207 else
208 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
209 ewarn "graphical interface. Maybe that is not what you want..."
210 fi
211 }
212
213 src_unpack() {
214 unpack ${A}
215 if [ "${PV%9999}" != "${PV}" ] ; then
216 git_src_unpack
217 fi
218 cd "${S}"
219
220 # Make it build with libtool 1.5
221 rm -f m4/lt* m4/libtool.m4
222
223 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
224 AT_M4DIR="m4 ${WORKDIR}/${PN}-m4" eautoreconf
225 }
226
227 src_compile () {
228
229 # It would fail if -fforce-addr is used due to too few registers...
230 use x86 && filter-flags -fforce-addr
231
232 local MOZILLA_PC
233
234 if use nsplugin; then
235 if use seamonkey; then
236 MOZILLA_PC=seamonkey-plugin
237 else
238 if has_version 'net-libs/xulrunner:1.9' ; then
239 MOZILLA_PC=libxul
240 else
241 MOZILLA_PC=xulrunner-plugin
242 fi
243 fi
244 fi
245
246 econf \
247 $(use_enable a52) \
248 $(use_enable aalib aa) \
249 $(use_enable aac faad) \
250 $(use_enable alsa) \
251 $(use_enable altivec) \
252 --disable-asademux \
253 $(use_enable atmo) \
254 $(use_enable avahi bonjour) \
255 $(use_enable bidi fribidi) \
256 $(use_enable cdda vcd) \
257 $(use_enable cddax)\
258 $(use_enable cddb libcddb) \
259 $(use_enable cdio libcdio) \
260 --disable-csri \
261 $(use_enable dbus) $(use_enable dbus dbus-control) \
262 $(use_enable dirac) \
263 $(use_enable directfb) \
264 $(use_enable dc1394) \
265 $(use_enable debug) \
266 $(use_enable dts dca) \
267 --disable-dv \
268 $(use_enable dvb) \
269 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
270 $(use_enable fbcon fb) \
271 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
272 $(use_enable flac) \
273 $(use_enable fluidsynth) \
274 $(use_enable fontconfig) \
275 $(use_enable ggi) \
276 $(use_enable gnome gnomevfs) \
277 $(use_enable gnutls) \
278 $(use_enable hal) \
279 $(use_enable httpd) \
280 $(use_enable id3tag) \
281 $(use_enable jack) \
282 $(use_enable kate) \
283 $(use_enable libass) \
284 $(use_enable libcaca caca) \
285 $(use_enable gcrypt libgcrypt) \
286 $(use_enable libnotify notify) \
287 $(use_enable libproxy) \
288 --disable-libtar \
289 $(use_enable libsysfs) \
290 $(use_enable libv4l2) \
291 $(use_enable lirc) \
292 $(use_enable live live555) \
293 $(use_enable lua) \
294 $(use_enable matroska mkv) \
295 $(use_enable mmx) \
296 $(use_enable modplug mod) \
297 $(use_enable mp3 mad) \
298 $(use_enable mpeg libmpeg2) \
299 $(use_enable mtp) \
300 $(use_enable musepack mpc) \
301 $(use_enable ncurses) \
302 $(use_enable nsplugin mozilla) --with-mozilla-pkg="${MOZILLA_PC}" \
303 $(use_enable ogg) \
304 $(use_enable opengl glx) $(use_enable opengl) $(use_enable opengl galaktos) \
305 $(use_enable optimisememory optimize-memory) \
306 $(use_enable oss) \
307 $(use_enable pda) \
308 $(use_enable png) \
309 --disable-portaudio \
310 $(use_enable pulseaudio pulse) \
311 $(use_enable pvr) \
312 $(use_enable qt4) \
313 $(use_enable rtsp realrtsp) \
314 $(use_enable run-as-root) \
315 $(use_enable samba smb) \
316 $(use_enable schroedinger) \
317 $(use_enable sdl) \
318 $(use_enable sdl-image) \
319 $(use_enable shine) \
320 $(use_enable shout) \
321 $(use_enable skins skins2) \
322 $(use_enable speex) \
323 $(use_enable sse) \
324 $(use_enable stream sout) \
325 $(use_enable svg) \
326 $(use_enable svga svgalib) \
327 $(use_enable taglib) \
328 $(use_enable theora) \
329 $(use_enable truetype freetype) \
330 $(use_enable twolame) \
331 $(use_enable upnp) \
332 $(use_enable v4l) \
333 $(use_enable v4l2) \
334 $(use_enable vcdinfo) \
335 $(use_enable vcdx) \
336 $(use_enable vorbis) \
337 $(use_enable win32codecs loader) \
338 $(use_enable wma-fixed) \
339 $(use_enable X x11) $(use_enable X screen) \
340 $(use_enable x264) \
341 $(use_enable xcb) \
342 $(use_enable xinerama) \
343 $(use_enable xml libxml2) \
344 $(use_enable xosd) \
345 $(use_enable xv xvideo) \
346 --disable-xvmc \
347 $(use_enable zvbi) \
348 --disable-snapshot \
349 --disable-growl \
350 --disable-optimizations \
351 --enable-fast-install \
352 $(vlc_use_enable_force vlm vlm sout) \
353 $(vlc_use_enable_force skins skins2 qt4) \
354 $(vlc_use_enable_force remoteosd remoteosd libgcrypt)
355
356 emake || die "make of VLC failed"
357 }
358
359 src_install() {
360 emake DESTDIR="${D}" install || die "make install failed"
361
362 dodoc AUTHORS MAINTAINERS HACKING THANKS NEWS README \
363 doc/fortunes.txt doc/intf-cdda.txt doc/intf-vcd.txt
364
365 rm -rf "${D}/usr/share/doc/vlc" \
366 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
367
368 if use nsplugin; then
369 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
370 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
371 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
372 fi
373
374 use skins || rm -rf "${D}/usr/share/vlc/skins2"
375
376 for res in 16 32 48; do
377 insinto /usr/share/icons/hicolor/${res}x${res}/apps/
378 newins "${S}"/share/vlc${res}x${res}.png vlc.png
379 done
380 }

  ViewVC Help
Powered by ViewVC 1.1.20