/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.214 - (show annotations) (download)
Wed Mar 12 16:15:16 2014 UTC (3 years, 1 month ago) by tomwij
Branch: MAIN
Changes since 1.213: +4 -5 lines
Removed newer rdp patch from 9999 as it has been patched upstream. Fixes bug #503464, reported by David Heidelberger (okias). Updated SLOT dependencies per consensus with ssuominen.

(Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.213 2014/03/10 13:44:47 ssuominen Exp $
4
5 EAPI="5"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM="git-r3"
10
11 if [ "${PV%.9999}" != "${PV}" ] ; then
12 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
13 else
14 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
15 fi
16 fi
17
18 inherit eutils multilib autotools toolchain-funcs flag-o-matic virtualx ${SCM}
19
20 MY_PV="${PV/_/-}"
21 MY_PV="${MY_PV/-beta/-test}"
22 MY_P="${PN}-${MY_PV}"
23
24 DESCRIPTION="VLC media player - Video player and streamer"
25 HOMEPAGE="http://www.videolan.org/vlc/"
26 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
27 SRC_URI=""
28 elif [[ "${MY_P}" == "${P}" ]]; then
29 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.xz"
30 else
31 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.xz"
32 fi
33
34 LICENSE="LGPL-2.1 GPL-2"
35 SLOT="0/5-7" # vlc - vlccore
36
37 if [ "${PV%9999}" = "${PV}" ] ; then
38 KEYWORDS="~amd64 ~arm ~ppc -sparc ~x86 ~amd64-fbsd ~x86-fbsd"
39 else
40 KEYWORDS=""
41 fi
42
43 IUSE="a52 aalib alsa altivec atmo +audioqueue avahi +avcodec
44 +avformat bidi bluray cdda cddb chromaprint dbus dc1394 debug
45 directfb directx dts dvb +dvbpsi dvd dxva2 elibc_glibc egl +encode faad fdk
46 fluidsynth +ffmpeg flac fontconfig +gcrypt gme gnome gnutls
47 growl httpd ieee1394 ios-vout jack jpeg kate kde libass libcaca libnotify
48 libsamplerate libtiger linsys libtar lirc live lua +macosx
49 +macosx-audio +macosx-dialog-provider +macosx-eyetv +macosx-quartztext
50 +macosx-qtkit +macosx-vout matroska media-library mmx modplug mp3 mpeg
51 mtp musepack ncurses neon ogg omxil opencv opengl optimisememory opus
52 png +postproc projectm pulseaudio +qt4 qt5 rdp rtsp run-as-root samba
53 schroedinger sdl sdl-image sftp shout sid skins speex sse svg +swscale
54 taglib theora tremor truetype twolame udev upnp vaapi v4l vcdx vdpau
55 vlm vnc vorbis vpx wma-fixed +X x264 +xcb xml xv zvbi"
56
57 RDEPEND="
58 !<media-video/ffmpeg-1.2:0
59 dev-libs/libgpg-error:0
60 net-dns/libidn:0
61 >=sys-libs/zlib-1.2.5.1-r2:0[minizip]
62 virtual/libintl:0
63 a52? ( >=media-libs/a52dec-0.7.4-r3:0 )
64 aalib? ( media-libs/aalib:0 )
65 alsa? ( >=media-libs/alsa-lib-1.0.24:0 )
66 avahi? ( >=net-dns/avahi-0.6:0[dbus] )
67 avcodec? ( virtual/ffmpeg:0 )
68 avformat? ( virtual/ffmpeg:0 )
69 bidi? ( >=dev-libs/fribidi-0.10.4:0 )
70 bluray? ( >=media-libs/libbluray-0.3.0:0 )
71 cddb? ( >=media-libs/libcddb-1.2.0:0 )
72 chromaprint? ( >=media-libs/chromaprint-0.6:0 )
73 dbus? ( >=sys-apps/dbus-1.0.2:0 )
74 dc1394? ( >=sys-libs/libraw1394-2.0.1:0 >=media-libs/libdc1394-2.1.0:2 )
75 directfb? ( dev-libs/DirectFB:0 sys-libs/zlib:0 )
76 dts? ( media-libs/libdca:0 )
77 dvbpsi? ( >=media-libs/libdvbpsi-0.2.1:0 )
78 dvd? ( media-libs/libdvdread:0 >=media-libs/libdvdnav-0.1.9:0 )
79 egl? ( virtual/opengl:0 )
80 elibc_glibc? ( >=sys-libs/glibc-2.8:2.2 )
81 faad? ( >=media-libs/faad2-2.6.1:0 )
82 fdk? ( media-libs/fdk-aac:0 )
83 flac? ( media-libs/libogg:0 >=media-libs/flac-1.1.2:0 )
84 fluidsynth? ( >=media-sound/fluidsynth-1.1.2:0 )
85 fontconfig? ( media-libs/fontconfig:1.0 )
86 gcrypt? ( >=dev-libs/libgcrypt-1.2.0:0 )
87 gme? ( media-libs/game-music-emu:0 )
88 gnome? ( gnome-base/gnome-vfs:2 dev-libs/glib:2 )
89 gnutls? ( >=net-libs/gnutls-3.0.20:0 )
90 ieee1394? ( >=sys-libs/libraw1394-2.0.1:0 >=sys-libs/libavc1394-0.5.3:0 )
91 ios-vout? ( virtual/opengl:0 )
92 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1:0 )
93 jpeg? ( virtual/jpeg:0 )
94 kate? ( >=media-libs/libkate-0.3.0:0 )
95 libass? ( >=media-libs/libass-0.9.8:0 media-libs/fontconfig:1.0 )
96 libcaca? ( >=media-libs/libcaca-0.99_beta14:0 )
97 libnotify? ( x11-libs/libnotify:0 x11-libs/gtk+:2 x11-libs/gdk-pixbuf:2 dev-libs/glib:2 )
98 libsamplerate? ( media-libs/libsamplerate:0 )
99 libtar? ( >=dev-libs/libtar-1.2.11-r3:0 )
100 libtiger? ( >=media-libs/libtiger-0.3.1:0 )
101 linsys? ( >=media-libs/zvbi-0.2.28:0 )
102 lirc? ( app-misc/lirc:0 )
103 live? ( >=media-plugins/live-2011.12.23:0 )
104 lua? ( >=dev-lang/lua-5.1:0 )
105 macosx-vout? ( virtual/opengl:0 )
106 matroska? ( >=dev-libs/libebml-1.0.0:0= >=media-libs/libmatroska-1.0.0:0= )
107 modplug? ( >=media-libs/libmodplug-0.8.8.1:0 )
108 mp3? ( media-libs/libmad:0 )
109 mpeg? ( >=media-libs/libmpeg2-0.3.2:0 )
110 mtp? ( >=media-libs/libmtp-1.0.0:0 )
111 musepack? ( >=media-sound/musepack-tools-444:0 )
112 ncurses? ( sys-libs/ncurses:5[unicode] )
113 ogg? ( media-libs/libogg:0 )
114 opencv? ( >media-libs/opencv-2.0:0 )
115 opengl? ( virtual/opengl:0 >=x11-libs/libX11-1.3.99.901:0 )
116 opus? ( >=media-libs/opus-1.0.3:0 )
117 png? ( media-libs/libpng:0= sys-libs/zlib:0 )
118 postproc? ( || ( >=media-video/ffmpeg-1.2:0= media-libs/libpostproc:0 ) )
119 projectm? ( media-libs/libprojectm:0 media-fonts/dejavu:0 )
120 pulseaudio? ( >=media-sound/pulseaudio-0.9.22:0 )
121 qt4? ( >=dev-qt/qtgui-4.6.0:4 >=dev-qt/qtcore-4.6.0:4 )
122 qt5? ( >=dev-qt/qtgui-5.1.0:5 >=dev-qt/qtcore-5.1.0:5 dev-qt/qtwidgets:5 )
123 rdp? ( net-misc/freerdp:0= )
124 samba? ( || ( >=net-fs/samba-3.4.6:0[smbclient] >=net-fs/samba-4.0.0:0[client] ) )
125 schroedinger? ( >=media-libs/schroedinger-1.0.10:0 )
126 sdl? ( >=media-libs/libsdl-1.2.10:0
127 sdl-image? ( >=media-libs/sdl-image-1.2.10:0 sys-libs/zlib:0 ) )
128 sftp? ( net-libs/libssh2:0 )
129 shout? ( media-libs/libshout:0 )
130 sid? ( media-libs/libsidplay:2 )
131 skins? ( x11-libs/libXext:0 x11-libs/libXpm:0 x11-libs/libXinerama:0 )
132 speex? ( media-libs/speex:0 )
133 svg? ( >=gnome-base/librsvg-2.9.0:2 )
134 swscale? ( virtual/ffmpeg:0 )
135 taglib? ( >=media-libs/taglib-1.6.1:0 sys-libs/zlib:0 )
136 theora? ( >=media-libs/libtheora-1.0_beta3:0 )
137 tremor? ( media-libs/tremor:0 )
138 truetype? ( media-libs/freetype:2 virtual/ttf-fonts:0
139 !fontconfig? ( media-fonts/dejavu:0 ) )
140 twolame? ( media-sound/twolame:0 )
141 udev? ( >=virtual/udev-142:0 )
142 upnp? ( net-libs/libupnp:0 )
143 v4l? ( media-libs/libv4l:0 )
144 vaapi? ( x11-libs/libva:0 virtual/ffmpeg[vaapi] )
145 vcdx? ( >=dev-libs/libcdio-0.78.2:0 >=media-video/vcdimager-0.7.22:0 )
146 vdpau? ( >=x11-libs/libvdpau-0.6:0 !<media-video/libav-10_beta1 )
147 vnc? ( >=net-libs/libvncserver-0.9.9:0 )
148 vorbis? ( media-libs/libvorbis:0 )
149 vpx? ( media-libs/libvpx:0 )
150 X? ( x11-libs/libX11:0 )
151 x264? ( >=media-libs/x264-0.0.20090923:0= )
152 xcb? ( >=x11-libs/libxcb-1.6:0 >=x11-libs/xcb-util-0.3.4:0 >=x11-libs/xcb-util-keysyms-0.3.4:0 )
153 xml? ( dev-libs/libxml2:2 )
154 zvbi? ( >=media-libs/zvbi-0.2.25:0 )
155 "
156
157 DEPEND="${RDEPEND}
158 kde? ( >=kde-base/kdelibs-4:4 )
159 xcb? ( x11-proto/xproto:0 )
160 app-arch/xz-utils:0
161 dev-lang/yasm:*
162 >=sys-devel/gettext-0.18.3:*
163 virtual/pkgconfig:*
164 "
165
166 REQUIRED_USE="
167 aalib? ( X )
168 bidi? ( truetype )
169 cddb? ( cdda )
170 dvb? ( dvbpsi )
171 dxva2? ( avcodec )
172 egl? ( X )
173 ffmpeg? ( avcodec avformat swscale postproc )
174 fontconfig? ( truetype )
175 gnutls? ( gcrypt )
176 httpd? ( lua )
177 libcaca? ( X )
178 libtar? ( skins )
179 libtiger? ( kate )
180 qt4? ( X !qt5 )
181 qt5? ( X !qt4 )
182 sdl? ( X )
183 skins? ( truetype X ^^ ( qt4 qt5 ) )
184 vaapi? ( avcodec X )
185 vlm? ( encode )
186 xv? ( xcb )
187 "
188
189 S="${WORKDIR}/${MY_P}"
190
191 pkg_setup() {
192 if [[ "$(tc-getCC)" == *"gcc"* ]] ; then
193 if [[ $(gcc-major-version) < 4 || ( $(gcc-major-version) == 4 && $(gcc-minor-version) < 5 ) ]] ; then
194 die "You need to have at least >=sys-devel/gcc-4.5 to build and/or have a working vlc, see bug #426754."
195 fi
196 fi
197 }
198
199 src_unpack() {
200 if [ "${PV%9999}" != "${PV}" ] ; then
201 git-r3_src_unpack
202 else
203 unpack ${A}
204 fi
205 }
206
207 src_prepare() {
208 # Support for Qt5.
209 if use qt5 ; then
210 export UIC="/usr/lib64/qt5/bin/uic"
211 export MOC="/usr/lib64/qt5/bin/moc"
212 fi
213
214 # Remove unnecessary warnings about unimplemented pragmas on gcc for now.
215 # Need to recheck this with gcc 4.9 and every subsequent minor bump of gcc.
216 #
217 # config.h:792: warning: ignoring #pragma STDC FENV_ACCESS [-Wunknown-pragmas]
218 # config.h:793: warning: ignoring #pragma STDC FP_CONTRACT [-Wunknown-pragmas]
219 #
220 # http://gcc.gnu.org/c99status.html
221 if [[ "$(tc-getCC)" == *"gcc"* ]] ; then
222 sed -i 's/ifndef __FAST_MATH__/if 0/g' configure.ac || die
223 fi
224
225 # _FORTIFY_SOURCE is set to 2 by default on Gentoo, remove redefine warnings.
226 sed -i '/_FORTIFY_SOURCE.*, 2,/d' configure.ac || die
227
228 # Bootstrap when we are on a git checkout.
229 if [[ "${PV%9999}" != "${PV}" ]] ; then
230 ./bootstrap
231 fi
232
233 # Make it build with libtool 1.5
234 rm -f m4/lt* m4/libtool.m4 || die
235
236 # We are not in a real git checkout due to the absence of a .git directory.
237 touch src/revision.txt || die
238
239 # Fix build system mistake.
240 epatch "${FILESDIR}"/${PN}-2.1.0-fix-libtremor-libs.patch
241
242 # Patch up incompatibilities and reconfigure autotools.
243 epatch "${FILESDIR}"/${PN}-2.1.0-libva-1.2.1-compat.patch
244
245 # Fix up broken audio when skipping using a fixed reversed bisected commit.
246 epatch "${FILESDIR}"/${PN}-2.1.0-TomWij-bisected-PA-broken-underflow.patch
247
248 # Disable avcodec checks when avcodec is not used.
249 sed -i 's/^#if LIBAVCODEC_VERSION_CHECK(.*)$/#if 0/' modules/codec/avcodec/fourcc.c || die
250
251 # Don't use --started-from-file when not using dbus.
252 if ! use dbus ; then
253 sed -i 's/ --started-from-file//' share/vlc.desktop.in || die
254 fi
255
256 eautoreconf
257
258 # Disable automatic running of tests.
259 find . -name 'Makefile.in' -exec sed -i 's/\(..*\)check-TESTS/\1/' {} \; || die
260 }
261
262 src_configure() {
263 # Compatibility fix for Samba 4.
264 use samba && append-cppflags "-I/usr/include/samba-4.0"
265
266 # Needs libresid-builder from libsidplay:2 which is in another directory...
267 # FIXME!
268 append-ldflags "-L/usr/$(get_libdir)/sidplay/builders/"
269
270 if use truetype || use projectm ; then
271 local dejavu="/usr/share/fonts/dejavu/"
272 myconf="--with-default-font=${dejavu}/DejaVuSans.ttf \
273 --with-default-font-family=Sans \
274 --with-default-monospace-font=${dejavu}/DejaVuSansMono.ttf
275 --with-default-monospace-font-family=Monospace"
276 fi
277
278 local qt_flag=""
279 if use qt4 || use qt5 ; then
280 qt_flag="--enable-qt"
281 fi
282
283 econf \
284 ${myconf} \
285 --enable-vlc \
286 --docdir=/usr/share/doc/${PF} \
287 --disable-dependency-tracking \
288 --disable-optimizations \
289 --disable-update-check \
290 --enable-fast-install \
291 --enable-screen \
292 $(use_enable a52) \
293 $(use_enable aalib aa) \
294 $(use_enable alsa) \
295 $(use_enable altivec) \
296 $(use_enable atmo) \
297 $(use_enable audioqueue) \
298 $(use_enable avahi bonjour) \
299 $(use_enable avcodec) \
300 $(use_enable avformat) \
301 $(use_enable bidi fribidi) \
302 $(use_enable bluray) \
303 $(use_enable cdda vcd) \
304 $(use_enable cddb libcddb) \
305 $(use_enable chromaprint) \
306 $(use_enable dbus) \
307 $(use_enable directfb) \
308 $(use_enable directx) \
309 $(use_enable dc1394) \
310 $(use_enable debug) \
311 $(use_enable dts dca) \
312 $(use_enable dvbpsi) \
313 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
314 $(use_enable dxva2) \
315 $(use_enable egl) \
316 $(use_enable encode sout) \
317 $(use_enable faad) \
318 $(use_enable fdk fdkaac) \
319 $(use_enable flac) \
320 $(use_enable fluidsynth) \
321 $(use_enable fontconfig) \
322 $(use_enable gcrypt libgcrypt) \
323 $(use_enable gme) \
324 $(use_enable gnome gnomevfs) \
325 $(use_enable gnutls) \
326 $(use_enable growl) \
327 $(use_enable httpd) \
328 $(use_enable ieee1394 dv1394) \
329 $(use_enable ios-vout ios-vout2) \
330 $(use_enable jack) \
331 $(use_enable jpeg) \
332 $(use_enable kate) \
333 $(use_with kde kde-solid) \
334 $(use_enable libass) \
335 $(use_enable libcaca caca) \
336 $(use_enable libnotify notify) \
337 $(use_enable libsamplerate samplerate) \
338 $(use_enable libtar) \
339 $(use_enable libtiger tiger) \
340 $(use_enable linsys) \
341 $(use_enable lirc) \
342 $(use_enable live live555) \
343 $(use_enable lua) \
344 $(use_enable macosx-audio) \
345 $(use_enable macosx-dialog-provider) \
346 $(use_enable macosx-eyetv) \
347 $(use_enable macosx-qtkit) \
348 $(use_enable macosx-quartztext) \
349 $(use_enable macosx-vout) \
350 $(use_enable matroska mkv) \
351 $(use_enable mmx) \
352 $(use_enable modplug mod) \
353 $(use_enable mp3 mad) \
354 $(use_enable mpeg libmpeg2) \
355 $(use_enable mtp) \
356 $(use_enable musepack mpc) \
357 $(use_enable ncurses) \
358 $(use_enable neon) \
359 $(use_enable ogg) $(use_enable ogg mux_ogg) \
360 $(use_enable omxil) \
361 $(use_enable omxil omxil-vout) \
362 $(use_enable opencv) \
363 $(use_enable opengl glx) $(use_enable opengl glspectrum) \
364 $(use_enable opus) \
365 $(use_enable optimisememory optimize-memory) \
366 $(use_enable png) \
367 $(use_enable postproc) \
368 $(use_enable projectm) \
369 $(use_enable pulseaudio pulse) \
370 ${qt_flag} \
371 $(use_enable rdp freerdp) \
372 $(use_enable rtsp realrtsp) \
373 $(use_enable run-as-root) \
374 $(use_enable samba smbclient) \
375 $(use_enable schroedinger) \
376 $(use_enable sdl) \
377 $(use_enable sdl-image) \
378 $(use_enable sid) \
379 $(use_enable sftp) \
380 $(use_enable shout) \
381 $(use_enable skins skins2) \
382 $(use_enable speex) \
383 $(use_enable sse) \
384 $(use_enable svg) \
385 $(use_enable swscale) \
386 $(use_enable taglib) \
387 $(use_enable theora) \
388 $(use_enable tremor) \
389 $(use_enable truetype freetype) \
390 $(use_enable twolame) \
391 $(use_enable udev) \
392 $(use_enable upnp) \
393 $(use_enable v4l v4l2) \
394 $(use_enable vaapi libva) \
395 $(use_enable vcdx) \
396 $(use_enable vdpau) \
397 $(use_enable vlm) \
398 $(use_enable vnc) \
399 $(use_enable vorbis) \
400 $(use_enable vpx) \
401 $(use_enable wma-fixed) \
402 $(use_with X x) \
403 $(use_enable x264) \
404 $(use_enable xcb) \
405 $(use_enable xml libxml2) \
406 $(use_enable xv xvideo) \
407 $(use_enable zvbi) $(use_enable !zvbi telx) \
408 --disable-asdcp \
409 --disable-coregraphicslayer-vout \
410 --disable-coverage \
411 --disable-cprof \
412 --disable-crystalhd \
413 --disable-decklink \
414 --disable-gles1 \
415 --disable-gles2 \
416 --disable-goom \
417 --disable-ios-audio \
418 --disable-kai \
419 --disable-kva \
420 --disable-maintainer-mode \
421 --disable-merge-ffmpeg \
422 --disable-mfx \
423 --disable-opensles \
424 --disable-oss \
425 --disable-quicktime \
426 --disable-rpi-omxil \
427 --disable-shine \
428 --disable-sndio \
429 --disable-x265 \
430 --disable-vda \
431 --disable-vsxu \
432 --disable-wasapi
433
434 # ^ We don't have these disabled libraries in the Portage tree yet.
435 }
436
437 src_test() {
438 Xemake check-TESTS
439 }
440
441 DOCS="AUTHORS THANKS NEWS README doc/fortunes.txt doc/intf-vcd.txt"
442
443 src_install() {
444 default
445
446 # Punt useless libtool's .la files
447 find "${D}" -name '*.la' -delete
448 }
449
450 pkg_postinst() {
451 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
452 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
453 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
454 else
455 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
456 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
457 ewarn "If you do not do it, vlc will take a long time to load."
458 fi
459 }

  ViewVC Help
Powered by ViewVC 1.1.20