/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.24 - (show annotations) (download)
Tue Jul 21 09:31:48 2009 UTC (8 years, 2 months ago) by aballier
Branch: MAIN
Changes since 1.23: +2 -1 lines
Add !! blockers on old versions
(Portage version: 2.2_rc33/cvs/Linux x86_64)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.23 2009/07/21 09:29:01 aballier Exp $
4
5 EAPI="2"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
11 EGIT_BOOTSTRAP="bootstrap"
12 if [ "${PV%.9999}" != "${PV}" ] ; then
13 EGIT_BRANCH=${PV%.9999}-bugfix
14 else
15 EGIT_BRANCH=master
16 fi
17 fi
18
19 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
20
21 MY_PV="${PV/_/-}"
22 MY_PV="${MY_PV/-beta/-test}"
23 MY_P="${PN}-${MY_PV}"
24 VLC_SNAPSHOT_TIME="0013"
25
26 PATCHLEVEL="63"
27 M4_TARBALL_VERSION="1"
28 DESCRIPTION="VLC media player - Video player and streamer"
29 HOMEPAGE="http://www.videolan.org/vlc/"
30 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
31 SRC_URI=""
32 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
33 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
34 MY_P="${P/_alpha*/}-git"
35 elif [[ "${MY_P}" == "${P}" ]]; then
36 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
37 else
38 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
39 fi
40
41 SRC_URI="${SRC_URI}
42 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2
43 mirror://gentoo/${PN}-m4-${M4_TARBALL_VERSION}.tar.bz2"
44
45 LICENSE="GPL-2"
46 SLOT="0"
47
48 KEYWORDS=""
49 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddax cddb cdio dbus dc1394
50 debug dirac directfb dts dvb dvd fbcon fluidsynth +ffmpeg flac fontconfig
51 +gcrypt ggi gnome gnutls hal httpd id3tag ieee1394 jack kate libass libcaca
52 libnotify libproxy libsysfs libtiger libv4l2 lirc live lua matroska mmx
53 modplug mp3 mpeg mtp musepack ncurses nsplugin ogg opengl optimisememory oss
54 pda png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
55 schroedinger sdl sdl-image seamonkey shine shout skins speex sse stream
56 svg svga taglib theora truetype twolame upnp v4l v4l2 vcdinfo vcdx vlm
57 vorbis win32codecs wma-fixed X x264 xcb xinerama xml xosd xv zvbi"
58
59 RDEPEND="
60 !!<=media-video/vlc-1.0.99999
61 sys-libs/zlib
62 >=media-libs/libdvbpsi-0.1.6
63 a52? ( >=media-libs/a52dec-0.7.4-r3 )
64 aalib? ( media-libs/aalib )
65 aac? ( >=media-libs/faad2-2.6.1 )
66 alsa? ( media-libs/alsa-lib )
67 avahi? ( >=net-dns/avahi-0.6 )
68 bidi? ( >=dev-libs/fribidi-0.10.4 )
69 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
70 cddax? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
71 cdio? ( >=dev-libs/libcdio-0.78.2 )
72 dbus? ( >=sys-apps/dbus-1.0.2 )
73 dc1394? ( >=sys-libs/libraw1394-2.0.1
74 >=media-libs/libdc1394-2.0.2 )
75 dirac? ( >=media-video/dirac-0.10.0 )
76 directfb? ( dev-libs/DirectFB )
77 dts? ( media-libs/libdca )
78 dvd? ( media-libs/libdvdread
79 media-libs/libdvdcss
80 >=media-libs/libdvdnav-0.1.9
81 media-libs/libdvdplay )
82 ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20090201 )
83 flac? ( media-libs/libogg
84 >=media-libs/flac-1.1.2 )
85 fluidsynth? ( media-sound/fluidsynth )
86 fontconfig? ( media-libs/fontconfig )
87 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
88 ggi? ( media-libs/libggi )
89 gnome? ( gnome-base/gnome-vfs )
90 gnutls? ( >=net-libs/gnutls-1.7.4 )
91 hal? ( sys-apps/hal )
92 id3tag? ( media-libs/libid3tag
93 sys-libs/zlib )
94 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
95 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
96 kate? ( >=media-libs/libkate-0.1.1 )
97 libass? ( >=media-libs/libass-0.9.5 media-libs/fontconfig )
98 libcaca? ( media-libs/libcaca )
99 libnotify? ( x11-libs/libnotify )
100 libproxy? ( net-libs/libproxy )
101 libsysfs? ( sys-fs/sysfsutils )
102 libtiger? ( media-libs/libtiger )
103 lirc? ( app-misc/lirc )
104 live? ( >=media-plugins/live-2008.07.06 )
105 lua? ( >=dev-lang/lua-5.1 )
106 matroska? (
107 >=dev-libs/libebml-0.7.6
108 >=media-libs/libmatroska-0.8.0 )
109 modplug? ( media-libs/libmodplug )
110 mp3? ( media-libs/libmad )
111 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
112 mtp? ( >=media-libs/libmtp-0.3.0 )
113 musepack? ( media-libs/libmpcdec )
114 ncurses? ( sys-libs/ncurses )
115 nsplugin? (
116 seamonkey? ( =www-client/seamonkey-1* )
117 !seamonkey? ( >=net-libs/xulrunner-1.8 )
118 )
119 ogg? ( media-libs/libogg )
120 pda? ( x11-libs/gtk+:2 )
121 png? ( media-libs/libpng )
122 projectm? ( media-libs/libprojectm )
123 pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
124 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
125 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
126 samba? ( net-fs/samba )
127 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
128 sdl? ( >=media-libs/libsdl-1.2.8
129 sdl-image? ( media-libs/sdl-image ) )
130 shout? ( media-libs/libshout )
131 skins? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
132 speex? ( media-libs/speex )
133 svg? ( >=gnome-base/librsvg-2.9.0 )
134 svga? ( media-libs/svgalib )
135 taglib? ( >=media-libs/taglib-1.5 )
136 theora? ( >=media-libs/libtheora-1.0_beta3 )
137 truetype? ( media-libs/freetype
138 media-fonts/ttf-bitstream-vera )
139 twolame? ( media-sound/twolame )
140 upnp? ( net-libs/libupnp )
141 v4l2? ( libv4l2? ( media-libs/libv4l ) )
142 vcdinfo? ( >=media-video/vcdimager-0.7.22 )
143 vorbis? ( media-libs/libvorbis )
144 win32codecs? ( media-libs/win32codecs )
145 X? (
146 x11-libs/libX11
147 x11-libs/libXext
148 xv? ( x11-libs/libXv )
149 xinerama? ( x11-libs/libXinerama )
150 opengl? ( virtual/opengl )
151 )
152 x264? ( media-libs/x264 )
153 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
154 xml? ( dev-libs/libxml2 )
155 xosd? ( x11-libs/xosd )
156 zvbi? ( >=media-libs/zvbi-0.2.25 )
157 "
158
159 # Disabled features and reasons:
160 # xvmc? ( x11-libs/libXvMC )
161 # Will probably compile only on x86
162
163 DEPEND="${RDEPEND}
164 dvb? ( sys-kernel/linux-headers )
165 v4l? ( sys-kernel/linux-headers )
166 v4l2? ( sys-kernel/linux-headers )
167 X? ( xinerama? ( x11-proto/xineramaproto ) )
168 xcb? ( x11-proto/xproto )
169 dev-util/pkgconfig"
170
171 S="${WORKDIR}/${MY_P}"
172
173 # Displays a warning if the first use flag is set but the second is not
174 vlc_use_needs() {
175 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
176 }
177
178 # Notify the user that some useflag have been forced on
179 vlc_use_force() {
180 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
181 }
182
183 # Use when $2 depends strictly on $3
184 # if use $1 then enable $2 and $3, otherwise disable $2
185 vlc_use_enable_force() {
186 if use $1 ; then
187 echo "--enable-$2 --enable-$3"
188 else
189 echo "--disable-$2"
190 fi
191 }
192
193 pkg_setup() {
194 if has_version '<=media-video/vlc-1.0.99999'; then
195 eerror "Please unmerge vlc-1.0.x first before installing ${P}"
196 eerror "If you don't do that, some plugins will get linked against"
197 eerror "the old ${PN} version and will not work."
198 die "Unmerge vlc 1.0.x first"
199 fi
200 vlc_use_needs skins truetype
201 vlc_use_force skins qt4
202 vlc_use_needs cddax cdio
203 vlc_use_needs vcdx cdio
204 vlc_use_needs vcdx vcdinfo
205 vlc_use_needs vcdinfo cdio
206 vlc_use_needs bidi truetype
207 vlc_use_force remoteosd gcrypt
208 vlc_use_needs fontconfig truetype
209 vlc_use_needs libv4l2 v4l2
210 vlc_use_needs libtiger kate
211 use cddb && use !cdda && use !cddax && ewarn "USE=cddb requires either cdda or cddax, cddb will be disabled."
212 if use qt4 || use skins ; then
213 qt4_pkg_setup
214 else
215 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
216 ewarn "graphical interface. Maybe that is not what you want..."
217 fi
218 }
219
220 src_unpack() {
221 unpack ${A}
222 if [ "${PV%9999}" != "${PV}" ] ; then
223 git_src_unpack
224 fi
225 }
226
227 src_prepare() {
228 if [ "${PV%9999}" != "${PV}" ] ; then
229 git_src_prepare
230 fi
231 # Make it build with libtool 1.5
232 rm -f m4/lt* m4/libtool.m4
233
234 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
235 AT_M4DIR="m4 ${WORKDIR}/${PN}-m4" eautoreconf
236 }
237
238 src_configure() {
239
240 # It would fail if -fforce-addr is used due to too few registers...
241 use x86 && filter-flags -fforce-addr
242
243 local MOZILLA_PC
244
245 if use nsplugin; then
246 if use seamonkey; then
247 MOZILLA_PC=seamonkey-plugin
248 else
249 if has_version 'net-libs/xulrunner:1.9' ; then
250 MOZILLA_PC=libxul
251 else
252 MOZILLA_PC=xulrunner-plugin
253 fi
254 fi
255 fi
256
257 econf \
258 $(use_enable a52) \
259 $(use_enable aalib aa) \
260 $(use_enable aac faad) \
261 $(use_enable alsa) \
262 $(use_enable altivec) \
263 --disable-asademux \
264 $(use_enable atmo) \
265 $(use_enable avahi bonjour) \
266 $(use_enable bidi fribidi) \
267 $(use_enable cdda vcd) \
268 $(use_enable cddax)\
269 $(use_enable cddb libcddb) \
270 $(use_enable cdio libcdio) \
271 --disable-csri \
272 $(use_enable dbus) $(use_enable dbus dbus-control) \
273 $(use_enable dirac) \
274 $(use_enable directfb) \
275 $(use_enable dc1394) \
276 $(use_enable debug) \
277 $(use_enable dts dca) \
278 $(use_enable dvb) \
279 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
280 $(use_enable fbcon fb) \
281 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
282 $(use_enable flac) \
283 $(use_enable fluidsynth) \
284 $(use_enable fontconfig) \
285 $(use_enable ggi) \
286 $(use_enable gnome gnomevfs) \
287 $(use_enable gnutls) \
288 $(use_enable hal) \
289 $(use_enable httpd) \
290 $(use_enable id3tag) \
291 $(use_enable ieee1394 dv) \
292 $(use_enable jack) \
293 $(use_enable kate) \
294 $(use_enable libass) \
295 $(use_enable libcaca caca) \
296 $(use_enable gcrypt libgcrypt) \
297 $(use_enable libnotify notify) \
298 $(use_enable libproxy) \
299 --disable-libtar \
300 $(use_enable libtiger tiger) \
301 $(use_enable libsysfs) \
302 $(use_enable libv4l2) \
303 $(use_enable lirc) \
304 $(use_enable live live555) \
305 $(use_enable lua) \
306 $(use_enable matroska mkv) \
307 $(use_enable mmx) \
308 $(use_enable modplug mod) \
309 $(use_enable mp3 mad) \
310 $(use_enable mpeg libmpeg2) \
311 $(use_enable mtp) \
312 $(use_enable musepack mpc) \
313 $(use_enable ncurses) \
314 $(use_enable nsplugin mozilla) --with-mozilla-pkg="${MOZILLA_PC}" \
315 $(use_enable ogg) \
316 $(use_enable opengl glx) $(use_enable opengl) $(use_enable opengl galaktos) \
317 $(use_enable optimisememory optimize-memory) \
318 $(use_enable oss) \
319 $(use_enable pda) \
320 $(use_enable png) \
321 --disable-portaudio \
322 $(use_enable projectm) \
323 $(use_enable pulseaudio pulse) \
324 $(use_enable pvr) \
325 $(use_enable qt4) \
326 $(use_enable rtsp realrtsp) \
327 $(use_enable run-as-root) \
328 $(use_enable samba smb) \
329 $(use_enable schroedinger) \
330 $(use_enable sdl) \
331 $(use_enable sdl-image) \
332 $(use_enable shine) \
333 $(use_enable shout) \
334 $(use_enable skins skins2) \
335 $(use_enable speex) \
336 $(use_enable sse) \
337 $(use_enable stream sout) \
338 $(use_enable svg) \
339 $(use_enable svga svgalib) \
340 $(use_enable taglib) \
341 $(use_enable theora) \
342 $(use_enable truetype freetype) \
343 $(use_enable twolame) \
344 $(use_enable upnp) \
345 $(use_enable v4l) \
346 $(use_enable v4l2) \
347 $(use_enable vcdinfo) \
348 $(use_enable vcdx) \
349 $(use_enable vorbis) \
350 $(use_enable win32codecs loader) \
351 $(use_enable wma-fixed) \
352 $(use_enable X x11) $(use_enable X screen) \
353 $(use_enable x264) \
354 $(use_enable xcb) \
355 $(use_enable xinerama) \
356 $(use_enable xml libxml2) \
357 $(use_enable xosd) \
358 $(use_enable xv xvideo) \
359 --disable-xvmc \
360 $(use_enable zvbi) \
361 --disable-snapshot \
362 --disable-growl \
363 --disable-optimizations \
364 --enable-fast-install \
365 $(vlc_use_enable_force vlm vlm sout) \
366 $(vlc_use_enable_force skins skins2 qt4) \
367 $(vlc_use_enable_force remoteosd remoteosd libgcrypt)
368 }
369
370 src_install() {
371 emake DESTDIR="${D}" install || die "make install failed"
372
373 dodoc AUTHORS MAINTAINERS HACKING THANKS NEWS README \
374 doc/fortunes.txt doc/intf-cdda.txt doc/intf-vcd.txt
375
376 rm -rf "${D}/usr/share/doc/vlc" \
377 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
378
379 if use nsplugin; then
380 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
381 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
382 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
383 fi
384
385 use skins || rm -rf "${D}/usr/share/vlc/skins2"
386
387 for res in 16 32 48; do
388 insinto /usr/share/icons/hicolor/${res}x${res}/apps/
389 newins "${S}"/share/vlc${res}x${res}.png vlc.png
390 done
391 }

  ViewVC Help
Powered by ViewVC 1.1.20