/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.42 - (show annotations) (download)
Sat Oct 10 12:58:32 2009 UTC (8 years ago) by patrick
Branch: MAIN
Changes since 1.41: +3 -2 lines
Fixing samba deps in live ebuilds too
(Portage version: 2.2_rc44/cvs/Linux x86_64)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.41 2009/09/30 12:56:40 lxnay Exp $
4
5 EAPI="2"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
11 EGIT_BOOTSTRAP="bootstrap"
12 if [ "${PV%.9999}" != "${PV}" ] ; then
13 EGIT_BRANCH=${PV%.9999}-bugfix
14 else
15 EGIT_BRANCH=master
16 fi
17 fi
18
19 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
20
21 MY_PV="${PV/_/-}"
22 MY_PV="${MY_PV/-beta/-test}"
23 MY_P="${PN}-${MY_PV}"
24 VLC_SNAPSHOT_TIME="0013"
25
26 PATCHLEVEL="72"
27 M4_TARBALL_VERSION="1"
28 DESCRIPTION="VLC media player - Video player and streamer"
29 HOMEPAGE="http://www.videolan.org/vlc/"
30 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
31 SRC_URI=""
32 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
33 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
34 MY_P="${P/_alpha*/}-git"
35 elif [[ "${MY_P}" == "${P}" ]]; then
36 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
37 else
38 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
39 fi
40
41 SRC_URI="${SRC_URI}
42 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2
43 mirror://gentoo/${PN}-m4-${M4_TARBALL_VERSION}.tar.bz2"
44
45 LICENSE="GPL-2"
46 SLOT="0"
47
48 KEYWORDS=""
49 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddax cddb cdio dbus dc1394
50 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
51 +gcrypt ggi gnome gnutls hal httpd id3tag ieee1394 jack kate libass libcaca
52 libnotify libproxy libsysfs libtiger libv4l2 lirc live lua matroska mmx
53 modplug mp3 mpeg mtp musepack ncurses nsplugin ogg opengl optimisememory oss
54 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
55 schroedinger sdl sdl-image seamonkey shine shout skins speex sse stream
56 svg svga taglib theora truetype twolame upnp v4l v4l2 vcdinfo vcdx vlm
57 vorbis win32codecs wma-fixed X x264 xcb xml xosd xv zvbi"
58
59 RDEPEND="
60 !!<=media-video/vlc-1.0.99999
61 sys-libs/zlib
62 >=media-libs/libdvbpsi-0.1.6
63 a52? ( >=media-libs/a52dec-0.7.4-r3 )
64 aalib? ( media-libs/aalib )
65 aac? ( >=media-libs/faad2-2.6.1 )
66 alsa? ( media-libs/alsa-lib )
67 avahi? ( >=net-dns/avahi-0.6 )
68 bidi? ( >=dev-libs/fribidi-0.10.4 )
69 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
70 cddax? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
71 cdio? ( >=dev-libs/libcdio-0.78.2 )
72 dbus? ( >=sys-apps/dbus-1.0.2 )
73 dc1394? ( >=sys-libs/libraw1394-2.0.1
74 >=media-libs/libdc1394-2.0.2 )
75 dirac? ( >=media-video/dirac-0.10.0 )
76 directfb? ( dev-libs/DirectFB sys-libs/zlib )
77 dts? ( media-libs/libdca )
78 dvd? ( media-libs/libdvdread
79 >=media-libs/libdvdnav-0.1.9
80 media-libs/libdvdplay )
81 elibc_glibc? ( >=sys-libs/glibc-2.8 )
82 ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20090201 )
83 flac? ( media-libs/libogg
84 >=media-libs/flac-1.1.2 )
85 fluidsynth? ( media-sound/fluidsynth )
86 fontconfig? ( media-libs/fontconfig )
87 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
88 ggi? ( media-libs/libggi )
89 gnome? ( gnome-base/gnome-vfs )
90 gnutls? ( >=net-libs/gnutls-1.7.4 )
91 hal? ( sys-apps/hal )
92 id3tag? ( media-libs/libid3tag sys-libs/zlib )
93 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
94 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
95 kate? ( >=media-libs/libkate-0.1.1 )
96 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
97 libcaca? ( media-libs/libcaca )
98 libnotify? ( x11-libs/libnotify )
99 libproxy? ( net-libs/libproxy )
100 libsysfs? ( sys-fs/sysfsutils )
101 libtiger? ( media-libs/libtiger )
102 lirc? ( app-misc/lirc )
103 live? ( >=media-plugins/live-2008.07.06 )
104 lua? ( >=dev-lang/lua-5.1 )
105 matroska? (
106 >=dev-libs/libebml-0.7.6
107 >=media-libs/libmatroska-0.8.0 )
108 modplug? ( media-libs/libmodplug )
109 mp3? ( media-libs/libmad )
110 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
111 mtp? ( >=media-libs/libmtp-0.3.0 )
112 musepack? ( || ( >=media-sound/musepack-tools-444
113 media-libs/libmpcdec ) )
114 ncurses? ( sys-libs/ncurses )
115 nsplugin? (
116 seamonkey? ( =www-client/seamonkey-1* )
117 !seamonkey? ( >=net-libs/xulrunner-1.8 )
118 )
119 ogg? ( media-libs/libogg )
120 png? ( media-libs/libpng sys-libs/zlib )
121 projectm? ( media-libs/libprojectm )
122 pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
123 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
124 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
125 samba? ( || ( >=net-fs/samba-libs-3.4[smbclient]
126 <net-fs/samba-3.4 ) )
127 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
128 sdl? ( >=media-libs/libsdl-1.2.8
129 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
130 shout? ( media-libs/libshout )
131 skins? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libXext x11-libs/libX11 )
132 speex? ( media-libs/speex )
133 svg? ( >=gnome-base/librsvg-2.9.0 )
134 svga? ( media-libs/svgalib )
135 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
136 theora? ( >=media-libs/libtheora-1.0_beta3 )
137 truetype? ( media-libs/freetype
138 media-fonts/dejavu )
139 twolame? ( media-sound/twolame )
140 upnp? ( net-libs/libupnp )
141 v4l2? ( libv4l2? ( media-libs/libv4l ) )
142 vcdinfo? ( >=media-video/vcdimager-0.7.22 )
143 vorbis? ( media-libs/libvorbis )
144 win32codecs? ( media-libs/win32codecs )
145 X? (
146 x11-libs/libX11
147 opengl? ( virtual/opengl x11-libs/libXext )
148 )
149 x264? ( >=media-libs/x264-0.0.20090923 )
150 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
151 xml? ( dev-libs/libxml2 )
152 xosd? ( x11-libs/xosd )
153 zvbi? ( >=media-libs/zvbi-0.2.25 )
154 "
155
156 # Disabled features and reasons:
157 # xvmc? ( x11-libs/libXvMC )
158 # Will probably compile only on x86
159
160 DEPEND="${RDEPEND}
161 dvb? ( sys-kernel/linux-headers )
162 v4l? ( sys-kernel/linux-headers )
163 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
164 xcb? ( x11-proto/xproto )
165 dev-util/pkgconfig"
166
167 S="${WORKDIR}/${MY_P}"
168
169 # Displays a warning if the first use flag is set but the second is not
170 vlc_use_needs() {
171 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
172 }
173
174 # Notify the user that some useflag have been forced on
175 vlc_use_force() {
176 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
177 }
178
179 # Use when $2 depends strictly on $3
180 # if use $1 then enable $2 and $3, otherwise disable $2
181 vlc_use_enable_force() {
182 if use $1 ; then
183 echo "--enable-$2 --enable-$3"
184 else
185 echo "--disable-$2"
186 fi
187 }
188
189 pkg_setup() {
190 if has_version '<=media-video/vlc-1.0.99999'; then
191 eerror "Please unmerge vlc-1.0.x first before installing ${P}"
192 eerror "If you don't do that, some plugins will get linked against"
193 eerror "the old ${PN} version and will not work."
194 die "Unmerge vlc 1.0.x first"
195 fi
196 vlc_use_needs skins truetype
197 vlc_use_force skins qt4
198 vlc_use_needs cddax cdio
199 vlc_use_needs vcdx cdio
200 vlc_use_needs vcdx vcdinfo
201 vlc_use_needs vcdinfo cdio
202 vlc_use_needs bidi truetype
203 vlc_use_force remoteosd gcrypt
204 vlc_use_needs fontconfig truetype
205 vlc_use_needs libv4l2 v4l2
206 vlc_use_needs libtiger kate
207 vlc_use_needs xv xcb
208 use cddb && use !cdda && use !cddax && ewarn "USE=cddb requires either cdda or cddax, cddb will be disabled."
209 if use qt4 || use skins ; then
210 qt4_pkg_setup
211 else
212 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
213 ewarn "graphical interface. Maybe that is not what you want..."
214 fi
215 }
216
217 src_unpack() {
218 unpack ${A}
219 if [ "${PV%9999}" != "${PV}" ] ; then
220 git_src_unpack
221 fi
222 }
223
224 src_prepare() {
225 if [ "${PV%9999}" != "${PV}" ] ; then
226 git_src_prepare
227 fi
228 # Make it build with libtool 1.5
229 rm -f m4/lt* m4/libtool.m4
230
231 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
232 AT_M4DIR="m4 ${WORKDIR}/${PN}-m4" eautoreconf
233 }
234
235 src_configure() {
236
237 # It would fail if -fforce-addr is used due to too few registers...
238 use x86 && filter-flags -fforce-addr
239
240 local MOZILLA_PC
241
242 if use nsplugin; then
243 if use seamonkey; then
244 MOZILLA_PC=seamonkey-plugin
245 else
246 if has_version 'net-libs/xulrunner:1.9' ; then
247 MOZILLA_PC=libxul
248 else
249 MOZILLA_PC=xulrunner-plugin
250 fi
251 fi
252 fi
253
254 econf \
255 $(use_enable a52) \
256 $(use_enable aalib aa) \
257 $(use_enable aac faad) \
258 $(use_enable alsa) \
259 $(use_enable altivec) \
260 --disable-asademux \
261 $(use_enable atmo) \
262 $(use_enable avahi bonjour) \
263 $(use_enable bidi fribidi) \
264 $(use_enable cdda vcd) \
265 $(use_enable cddax)\
266 $(use_enable cddb libcddb) \
267 $(use_enable cdio libcdio) \
268 $(use_enable dbus) $(use_enable dbus dbus-control) \
269 $(use_enable dirac) \
270 $(use_enable directfb) \
271 $(use_enable dc1394) \
272 $(use_enable debug) \
273 $(use_enable dts dca) \
274 $(use_enable dvb) \
275 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
276 $(use_enable fbcon fb) \
277 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
278 $(use_enable flac) \
279 $(use_enable fluidsynth) \
280 $(use_enable fontconfig) \
281 $(use_enable ggi) \
282 $(use_enable gnome gnomevfs) \
283 $(use_enable gnutls) \
284 $(use_enable hal) \
285 $(use_enable httpd) \
286 $(use_enable id3tag) \
287 $(use_enable ieee1394 dv) \
288 $(use_enable jack) \
289 $(use_enable kate) \
290 $(use_enable libass) \
291 $(use_enable libcaca caca) \
292 $(use_enable gcrypt libgcrypt) \
293 $(use_enable libnotify notify) \
294 $(use_enable libproxy) \
295 --disable-libtar \
296 $(use_enable libtiger tiger) \
297 $(use_enable libsysfs) \
298 $(use_enable libv4l2) \
299 $(use_enable lirc) \
300 $(use_enable live live555) \
301 $(use_enable lua) \
302 $(use_enable matroska mkv) \
303 $(use_enable mmx) \
304 $(use_enable modplug mod) \
305 $(use_enable mp3 mad) \
306 $(use_enable mpeg libmpeg2) \
307 $(use_enable mtp) \
308 $(use_enable musepack mpc) \
309 $(use_enable ncurses) \
310 $(use_enable nsplugin mozilla) --with-mozilla-pkg="${MOZILLA_PC}" \
311 $(use_enable ogg) \
312 $(use_enable opengl glx) $(use_enable opengl) \
313 $(use_enable optimisememory optimize-memory) \
314 $(use_enable oss) \
315 $(use_enable png) \
316 --disable-portaudio \
317 $(use_enable projectm) \
318 $(use_enable pulseaudio pulse) \
319 $(use_enable pvr) \
320 $(use_enable qt4) \
321 $(use_enable rtsp realrtsp) \
322 $(use_enable run-as-root) \
323 $(use_enable samba smb) \
324 $(use_enable schroedinger) \
325 $(use_enable sdl) \
326 $(use_enable sdl-image) \
327 $(use_enable shine) \
328 $(use_enable shout) \
329 $(use_enable skins skins2) \
330 $(use_enable speex) \
331 $(use_enable sse) \
332 $(use_enable stream sout) \
333 $(use_enable svg) \
334 $(use_enable svga svgalib) \
335 $(use_enable taglib) \
336 $(use_enable theora) \
337 $(use_enable truetype freetype) \
338 $(use_enable twolame) \
339 $(use_enable upnp) \
340 $(use_enable v4l) \
341 $(use_enable v4l2) \
342 $(use_enable vcdinfo) \
343 $(use_enable vcdx) \
344 $(use_enable vorbis) \
345 $(use_enable win32codecs loader) \
346 $(use_enable wma-fixed) \
347 $(use_enable X x11) $(use_enable X screen) \
348 $(use_enable x264) \
349 $(use_enable xcb) \
350 $(use_enable xml libxml2) \
351 $(use_enable xosd) \
352 $(use_enable xv xvideo) \
353 --disable-xvmc \
354 $(use_enable zvbi) $(use_enable !zvbi telx) \
355 --disable-snapshot \
356 --disable-growl \
357 --disable-optimizations \
358 --enable-fast-install \
359 $(vlc_use_enable_force vlm vlm sout) \
360 $(vlc_use_enable_force skins skins2 qt4) \
361 $(vlc_use_enable_force remoteosd remoteosd libgcrypt)
362 }
363
364 src_install() {
365 emake DESTDIR="${D}" install || die "make install failed"
366
367 dodoc AUTHORS MAINTAINERS HACKING THANKS NEWS README \
368 doc/fortunes.txt doc/intf-cdda.txt doc/intf-vcd.txt
369
370 rm -rf "${D}/usr/share/doc/vlc" \
371 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
372
373 if use nsplugin; then
374 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
375 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
376 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
377 fi
378
379 use skins || rm -rf "${D}/usr/share/vlc/skins2"
380
381 for res in 16 32 48; do
382 insinto /usr/share/icons/hicolor/${res}x${res}/apps/
383 newins "${S}"/share/vlc${res}x${res}.png vlc.png
384 done
385 }

  ViewVC Help
Powered by ViewVC 1.1.20