/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.46 - (show annotations) (download)
Sun Oct 18 21:20:22 2009 UTC (7 years, 8 months ago) by aballier
Branch: MAIN
Changes since 1.45: +2 -4 lines
hal support is gone in master, udev is preferred.
(Portage version: 2.2_rc46/cvs/Linux x86_64)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.45 2009/10/18 21:12:30 aballier Exp $
4
5 EAPI="2"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
11 EGIT_BOOTSTRAP="bootstrap"
12 if [ "${PV%.9999}" != "${PV}" ] ; then
13 EGIT_BRANCH=${PV%.9999}-bugfix
14 else
15 EGIT_BRANCH=master
16 fi
17 fi
18
19 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
20
21 MY_PV="${PV/_/-}"
22 MY_PV="${MY_PV/-beta/-test}"
23 MY_P="${PN}-${MY_PV}"
24 VLC_SNAPSHOT_TIME="0013"
25
26 PATCHLEVEL="72"
27 M4_TARBALL_VERSION="1"
28 DESCRIPTION="VLC media player - Video player and streamer"
29 HOMEPAGE="http://www.videolan.org/vlc/"
30 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
31 SRC_URI=""
32 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
33 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
34 MY_P="${P/_alpha*/}-git"
35 elif [[ "${MY_P}" == "${P}" ]]; then
36 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
37 else
38 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
39 fi
40
41 SRC_URI="${SRC_URI}
42 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2
43 mirror://gentoo/${PN}-m4-${M4_TARBALL_VERSION}.tar.bz2"
44
45 LICENSE="GPL-2"
46 SLOT="0"
47
48 KEYWORDS=""
49 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddax cddb cdio dbus dc1394
50 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
51 +gcrypt ggi gnome gnutls httpd id3tag ieee1394 jack kate libass libcaca
52 libnotify libproxy libsysfs libtiger libv4l2 lirc live lua matroska mmx
53 modplug mp3 mpeg mtp musepack ncurses nsplugin ogg opengl optimisememory oss
54 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
55 schroedinger sdl sdl-image seamonkey shine shout skins speex sse stream
56 svg svga taglib theora truetype twolame udev upnp v4l v4l2 vcdinfo vcdx vlm
57 vorbis win32codecs wma-fixed X x264 xcb xml xosd xv zvbi"
58
59 RDEPEND="
60 !!<=media-video/vlc-1.0.99999
61 sys-libs/zlib
62 >=media-libs/libdvbpsi-0.1.6
63 a52? ( >=media-libs/a52dec-0.7.4-r3 )
64 aalib? ( media-libs/aalib )
65 aac? ( >=media-libs/faad2-2.6.1 )
66 alsa? ( media-libs/alsa-lib )
67 avahi? ( >=net-dns/avahi-0.6 )
68 bidi? ( >=dev-libs/fribidi-0.10.4 )
69 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
70 cddax? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
71 cdio? ( >=dev-libs/libcdio-0.78.2 )
72 dbus? ( >=sys-apps/dbus-1.0.2 )
73 dc1394? ( >=sys-libs/libraw1394-2.0.1
74 >=media-libs/libdc1394-2.0.2 )
75 dirac? ( >=media-video/dirac-0.10.0 )
76 directfb? ( dev-libs/DirectFB sys-libs/zlib )
77 dts? ( media-libs/libdca )
78 dvd? ( media-libs/libdvdread
79 >=media-libs/libdvdnav-0.1.9
80 media-libs/libdvdplay )
81 elibc_glibc? ( >=sys-libs/glibc-2.8 )
82 ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20090201 )
83 flac? ( media-libs/libogg
84 >=media-libs/flac-1.1.2 )
85 fluidsynth? ( media-sound/fluidsynth )
86 fontconfig? ( media-libs/fontconfig )
87 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
88 ggi? ( media-libs/libggi )
89 gnome? ( gnome-base/gnome-vfs )
90 gnutls? ( >=net-libs/gnutls-1.7.4 )
91 id3tag? ( media-libs/libid3tag sys-libs/zlib )
92 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
93 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
94 kate? ( >=media-libs/libkate-0.1.1 )
95 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
96 libcaca? ( media-libs/libcaca )
97 libnotify? ( x11-libs/libnotify )
98 libproxy? ( net-libs/libproxy )
99 libsysfs? ( sys-fs/sysfsutils )
100 libtiger? ( media-libs/libtiger )
101 lirc? ( app-misc/lirc )
102 live? ( >=media-plugins/live-2008.07.06 )
103 lua? ( >=dev-lang/lua-5.1 )
104 matroska? (
105 >=dev-libs/libebml-0.7.6
106 >=media-libs/libmatroska-0.8.0 )
107 modplug? ( media-libs/libmodplug )
108 mp3? ( media-libs/libmad )
109 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
110 mtp? ( >=media-libs/libmtp-0.3.0 )
111 musepack? ( >=media-sound/musepack-tools-444 )
112 ncurses? ( sys-libs/ncurses )
113 nsplugin? (
114 seamonkey? ( =www-client/seamonkey-1* )
115 !seamonkey? ( >=net-libs/xulrunner-1.8 )
116 )
117 ogg? ( media-libs/libogg )
118 png? ( media-libs/libpng sys-libs/zlib )
119 projectm? ( media-libs/libprojectm )
120 pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
121 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
122 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
123 samba? ( || ( >=net-fs/samba-libs-3.4[smbclient]
124 <net-fs/samba-3.4 ) )
125 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
126 sdl? ( >=media-libs/libsdl-1.2.8
127 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
128 shout? ( media-libs/libshout )
129 skins? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libXext x11-libs/libX11 )
130 speex? ( media-libs/speex )
131 svg? ( >=gnome-base/librsvg-2.9.0 )
132 svga? ( media-libs/svgalib )
133 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
134 theora? ( >=media-libs/libtheora-1.0_beta3 )
135 truetype? ( media-libs/freetype
136 media-fonts/dejavu )
137 twolame? ( media-sound/twolame )
138 udev? ( >=sys-fs/udev-142 )
139 upnp? ( net-libs/libupnp )
140 v4l2? ( libv4l2? ( media-libs/libv4l ) )
141 vcdinfo? ( >=media-video/vcdimager-0.7.22 )
142 vorbis? ( media-libs/libvorbis )
143 win32codecs? ( media-libs/win32codecs )
144 X? (
145 x11-libs/libX11
146 opengl? ( virtual/opengl x11-libs/libXext )
147 )
148 x264? ( >=media-libs/x264-0.0.20090923 )
149 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
150 xml? ( dev-libs/libxml2 )
151 xosd? ( x11-libs/xosd )
152 zvbi? ( >=media-libs/zvbi-0.2.25 )
153 "
154
155 # Disabled features and reasons:
156 # xvmc? ( x11-libs/libXvMC )
157 # Will probably compile only on x86
158
159 DEPEND="${RDEPEND}
160 dvb? ( sys-kernel/linux-headers )
161 v4l? ( sys-kernel/linux-headers )
162 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
163 xcb? ( x11-proto/xproto )
164 dev-util/pkgconfig"
165
166 S="${WORKDIR}/${MY_P}"
167
168 # Displays a warning if the first use flag is set but the second is not
169 vlc_use_needs() {
170 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
171 }
172
173 # Notify the user that some useflag have been forced on
174 vlc_use_force() {
175 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
176 }
177
178 # Use when $2 depends strictly on $3
179 # if use $1 then enable $2 and $3, otherwise disable $2
180 vlc_use_enable_force() {
181 if use $1 ; then
182 echo "--enable-$2 --enable-$3"
183 else
184 echo "--disable-$2"
185 fi
186 }
187
188 pkg_setup() {
189 if has_version '<=media-video/vlc-1.0.99999'; then
190 eerror "Please unmerge vlc-1.0.x first before installing ${P}"
191 eerror "If you don't do that, some plugins will get linked against"
192 eerror "the old ${PN} version and will not work."
193 die "Unmerge vlc 1.0.x first"
194 fi
195 vlc_use_needs skins truetype
196 vlc_use_force skins qt4
197 vlc_use_needs cddax cdio
198 vlc_use_needs vcdx cdio
199 vlc_use_needs vcdx vcdinfo
200 vlc_use_needs vcdinfo cdio
201 vlc_use_needs bidi truetype
202 vlc_use_force remoteosd gcrypt
203 vlc_use_needs fontconfig truetype
204 vlc_use_needs libv4l2 v4l2
205 vlc_use_needs libtiger kate
206 vlc_use_needs xv xcb
207 use cddb && use !cdda && use !cddax && ewarn "USE=cddb requires either cdda or cddax, cddb will be disabled."
208 if use qt4 || use skins ; then
209 qt4_pkg_setup
210 else
211 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
212 ewarn "graphical interface. Maybe that is not what you want..."
213 fi
214 }
215
216 src_unpack() {
217 unpack ${A}
218 if [ "${PV%9999}" != "${PV}" ] ; then
219 git_src_unpack
220 fi
221 }
222
223 src_prepare() {
224 if [ "${PV%9999}" != "${PV}" ] ; then
225 git_src_prepare
226 fi
227 # Make it build with libtool 1.5
228 rm -f m4/lt* m4/libtool.m4
229
230 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
231 AT_M4DIR="m4 ${WORKDIR}/${PN}-m4" eautoreconf
232 }
233
234 src_configure() {
235
236 # It would fail if -fforce-addr is used due to too few registers...
237 use x86 && filter-flags -fforce-addr
238
239 local MOZILLA_PC
240
241 if use nsplugin; then
242 if use seamonkey; then
243 MOZILLA_PC=seamonkey-plugin
244 else
245 if has_version 'net-libs/xulrunner:1.9' ; then
246 MOZILLA_PC=libxul
247 else
248 MOZILLA_PC=xulrunner-plugin
249 fi
250 fi
251 fi
252
253 econf \
254 $(use_enable a52) \
255 $(use_enable aalib aa) \
256 $(use_enable aac faad) \
257 $(use_enable alsa) \
258 $(use_enable altivec) \
259 --disable-asademux \
260 $(use_enable atmo) \
261 $(use_enable avahi bonjour) \
262 $(use_enable bidi fribidi) \
263 $(use_enable cdda vcd) \
264 $(use_enable cddax)\
265 $(use_enable cddb libcddb) \
266 $(use_enable cdio libcdio) \
267 $(use_enable dbus) $(use_enable dbus dbus-control) \
268 $(use_enable dirac) \
269 $(use_enable directfb) \
270 $(use_enable dc1394) \
271 $(use_enable debug) \
272 $(use_enable dts dca) \
273 $(use_enable dvb) \
274 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
275 $(use_enable fbcon fb) \
276 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
277 $(use_enable flac) \
278 $(use_enable fluidsynth) \
279 $(use_enable fontconfig) \
280 $(use_enable ggi) \
281 $(use_enable gnome gnomevfs) \
282 $(use_enable gnutls) \
283 $(use_enable httpd) \
284 $(use_enable id3tag) \
285 $(use_enable ieee1394 dv) \
286 $(use_enable jack) \
287 $(use_enable kate) \
288 $(use_enable libass) \
289 $(use_enable libcaca caca) \
290 $(use_enable gcrypt libgcrypt) \
291 $(use_enable libnotify notify) \
292 $(use_enable libproxy) \
293 --disable-libtar \
294 $(use_enable libtiger tiger) \
295 $(use_enable libsysfs) \
296 $(use_enable libv4l2) \
297 $(use_enable lirc) \
298 $(use_enable live live555) \
299 $(use_enable lua) \
300 $(use_enable matroska mkv) \
301 $(use_enable mmx) \
302 $(use_enable modplug mod) \
303 $(use_enable mp3 mad) \
304 $(use_enable mpeg libmpeg2) \
305 $(use_enable mtp) \
306 $(use_enable musepack mpc) \
307 $(use_enable ncurses) \
308 $(use_enable nsplugin mozilla) --with-mozilla-pkg="${MOZILLA_PC}" \
309 $(use_enable ogg) \
310 $(use_enable opengl glx) $(use_enable opengl) \
311 $(use_enable optimisememory optimize-memory) \
312 $(use_enable oss) \
313 $(use_enable png) \
314 --disable-portaudio \
315 $(use_enable projectm) \
316 $(use_enable pulseaudio pulse) \
317 $(use_enable pvr) \
318 $(use_enable qt4) \
319 $(use_enable rtsp realrtsp) \
320 $(use_enable run-as-root) \
321 $(use_enable samba smb) \
322 $(use_enable schroedinger) \
323 $(use_enable sdl) \
324 $(use_enable sdl-image) \
325 $(use_enable shine) \
326 $(use_enable shout) \
327 $(use_enable skins skins2) \
328 $(use_enable speex) \
329 $(use_enable sse) \
330 $(use_enable stream sout) \
331 $(use_enable svg) \
332 $(use_enable svga svgalib) \
333 $(use_enable taglib) \
334 $(use_enable theora) \
335 $(use_enable truetype freetype) \
336 $(use_enable twolame) \
337 $(use_enable udev) \
338 $(use_enable upnp) \
339 $(use_enable v4l) \
340 $(use_enable v4l2) \
341 $(use_enable vcdinfo) \
342 $(use_enable vcdx) \
343 $(use_enable vorbis) \
344 $(use_enable win32codecs loader) \
345 $(use_enable wma-fixed) \
346 $(use_enable X x11) $(use_enable X screen) \
347 $(use_enable x264) \
348 $(use_enable xcb) \
349 $(use_enable xml libxml2) \
350 $(use_enable xosd) \
351 $(use_enable xv xvideo) \
352 --disable-xvmc \
353 $(use_enable zvbi) $(use_enable !zvbi telx) \
354 --disable-snapshot \
355 --disable-growl \
356 --disable-optimizations \
357 --enable-fast-install \
358 $(vlc_use_enable_force vlm vlm sout) \
359 $(vlc_use_enable_force skins skins2 qt4) \
360 $(vlc_use_enable_force remoteosd remoteosd libgcrypt)
361 }
362
363 src_install() {
364 emake DESTDIR="${D}" install || die "make install failed"
365
366 dodoc AUTHORS MAINTAINERS HACKING THANKS NEWS README \
367 doc/fortunes.txt doc/intf-cdda.txt doc/intf-vcd.txt
368
369 rm -rf "${D}/usr/share/doc/vlc" \
370 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
371
372 if use nsplugin; then
373 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
374 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
375 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
376 fi
377
378 use skins || rm -rf "${D}/usr/share/vlc/skins2"
379
380 for res in 16 32 48; do
381 insinto /usr/share/icons/hicolor/${res}x${res}/apps/
382 newins "${S}"/share/vlc${res}x${res}.png vlc.png
383 done
384 }

  ViewVC Help
Powered by ViewVC 1.1.20