/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.49 - (show annotations) (download)
Sat Dec 5 08:43:26 2009 UTC (7 years, 4 months ago) by aballier
Branch: MAIN
Changes since 1.48: +1 -6 lines
xvmc is gone
(Portage version: 2.2_rc55/cvs/Linux x86_64)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.48 2009/11/21 11:39:49 aballier Exp $
4
5 EAPI="2"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
11 EGIT_BOOTSTRAP="bootstrap"
12 if [ "${PV%.9999}" != "${PV}" ] ; then
13 EGIT_BRANCH=${PV%.9999}-bugfix
14 else
15 EGIT_BRANCH=master
16 fi
17 fi
18
19 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
20
21 MY_PV="${PV/_/-}"
22 MY_PV="${MY_PV/-beta/-test}"
23 MY_P="${PN}-${MY_PV}"
24 VLC_SNAPSHOT_TIME="0013"
25
26 PATCHLEVEL="72"
27 DESCRIPTION="VLC media player - Video player and streamer"
28 HOMEPAGE="http://www.videolan.org/vlc/"
29 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
30 SRC_URI=""
31 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
32 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
33 MY_P="${P/_alpha*/}-git"
34 elif [[ "${MY_P}" == "${P}" ]]; then
35 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
36 else
37 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
38 fi
39
40 SRC_URI="${SRC_URI}
41 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
42
43 LICENSE="GPL-2"
44 SLOT="0"
45
46 KEYWORDS=""
47 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddax cddb cdio dbus dc1394
48 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
49 +gcrypt ggi gnome gnutls httpd id3tag ieee1394 jack kate libass libcaca
50 libnotify libproxy libsysfs libtiger libv4l libv4l2 lirc live lua matroska mmx
51 modplug mp3 mpeg mtp musepack ncurses nsplugin ogg opengl optimisememory oss
52 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
53 schroedinger sdl sdl-image seamonkey shine shout skins speex sse stream
54 svg svga taglib theora truetype twolame udev upnp v4l v4l2 vcdinfo vcdx vlm
55 vorbis win32codecs wma-fixed X x264 xcb xml xosd xv zvbi"
56
57 RDEPEND="
58 !!<=media-video/vlc-1.0.99999
59 sys-libs/zlib
60 >=media-libs/libdvbpsi-0.1.6
61 a52? ( >=media-libs/a52dec-0.7.4-r3 )
62 aalib? ( media-libs/aalib )
63 aac? ( >=media-libs/faad2-2.6.1 )
64 alsa? ( media-libs/alsa-lib )
65 avahi? ( >=net-dns/avahi-0.6 )
66 bidi? ( >=dev-libs/fribidi-0.10.4 )
67 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
68 cddax? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
69 cdio? ( >=dev-libs/libcdio-0.78.2 )
70 dbus? ( >=sys-apps/dbus-1.0.2 )
71 dc1394? ( >=sys-libs/libraw1394-2.0.1
72 >=media-libs/libdc1394-2.0.2 )
73 dirac? ( >=media-video/dirac-0.10.0 )
74 directfb? ( dev-libs/DirectFB sys-libs/zlib )
75 dts? ( media-libs/libdca )
76 dvd? ( media-libs/libdvdread
77 >=media-libs/libdvdnav-0.1.9
78 media-libs/libdvdplay )
79 elibc_glibc? ( >=sys-libs/glibc-2.8 )
80 ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20090201 )
81 flac? ( media-libs/libogg
82 >=media-libs/flac-1.1.2 )
83 fluidsynth? ( media-sound/fluidsynth )
84 fontconfig? ( media-libs/fontconfig )
85 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
86 ggi? ( media-libs/libggi )
87 gnome? ( gnome-base/gnome-vfs )
88 gnutls? ( >=net-libs/gnutls-1.7.4 )
89 id3tag? ( media-libs/libid3tag sys-libs/zlib )
90 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
91 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
92 kate? ( >=media-libs/libkate-0.1.1 )
93 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
94 libcaca? ( media-libs/libcaca )
95 libnotify? ( x11-libs/libnotify )
96 libproxy? ( net-libs/libproxy )
97 libsysfs? ( sys-fs/sysfsutils )
98 libtiger? ( media-libs/libtiger )
99 lirc? ( app-misc/lirc )
100 live? ( >=media-plugins/live-2008.07.06 )
101 lua? ( >=dev-lang/lua-5.1 )
102 matroska? (
103 >=dev-libs/libebml-0.7.6
104 >=media-libs/libmatroska-0.8.0 )
105 modplug? ( media-libs/libmodplug )
106 mp3? ( media-libs/libmad )
107 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
108 mtp? ( >=media-libs/libmtp-0.3.0 )
109 musepack? ( >=media-sound/musepack-tools-444 )
110 ncurses? ( sys-libs/ncurses )
111 nsplugin? (
112 seamonkey? ( =www-client/seamonkey-1* )
113 !seamonkey? ( >=net-libs/xulrunner-1.8 )
114 )
115 ogg? ( media-libs/libogg )
116 png? ( media-libs/libpng sys-libs/zlib )
117 projectm? ( media-libs/libprojectm )
118 pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
119 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
120 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
121 samba? ( || ( >=net-fs/samba-libs-3.4[smbclient]
122 <net-fs/samba-3.4 ) )
123 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
124 sdl? ( >=media-libs/libsdl-1.2.8
125 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
126 shout? ( media-libs/libshout )
127 skins? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libXext x11-libs/libX11 )
128 speex? ( media-libs/speex )
129 svg? ( >=gnome-base/librsvg-2.9.0 )
130 svga? ( media-libs/svgalib )
131 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
132 theora? ( >=media-libs/libtheora-1.0_beta3 )
133 truetype? ( media-libs/freetype
134 media-fonts/dejavu )
135 twolame? ( media-sound/twolame )
136 udev? ( >=sys-fs/udev-142 )
137 upnp? ( net-libs/libupnp )
138 v4l2? ( libv4l2? ( media-libs/libv4l ) )
139 v4l? ( libv4l? ( media-libs/libv4l ) )
140 vcdinfo? ( >=media-video/vcdimager-0.7.22 )
141 vorbis? ( media-libs/libvorbis )
142 win32codecs? ( media-libs/win32codecs )
143 X? (
144 x11-libs/libX11
145 opengl? ( virtual/opengl x11-libs/libXext )
146 )
147 x264? ( >=media-libs/x264-0.0.20090923 )
148 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
149 xml? ( dev-libs/libxml2 )
150 xosd? ( x11-libs/xosd )
151 zvbi? ( >=media-libs/zvbi-0.2.25 )
152 "
153
154 DEPEND="${RDEPEND}
155 dvb? ( sys-kernel/linux-headers )
156 v4l? ( sys-kernel/linux-headers )
157 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
158 xcb? ( x11-proto/xproto )
159 dev-util/pkgconfig"
160
161 S="${WORKDIR}/${MY_P}"
162
163 # Displays a warning if the first use flag is set but the second is not
164 vlc_use_needs() {
165 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
166 }
167
168 # Notify the user that some useflag have been forced on
169 vlc_use_force() {
170 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
171 }
172
173 # Use when $2 depends strictly on $3
174 # if use $1 then enable $2 and $3, otherwise disable $2
175 vlc_use_enable_force() {
176 if use $1 ; then
177 echo "--enable-$2 --enable-$3"
178 else
179 echo "--disable-$2"
180 fi
181 }
182
183 pkg_setup() {
184 if has_version '<=media-video/vlc-1.0.99999'; then
185 eerror "Please unmerge vlc-1.0.x first before installing ${P}"
186 eerror "If you don't do that, some plugins will get linked against"
187 eerror "the old ${PN} version and will not work."
188 die "Unmerge vlc 1.0.x first"
189 fi
190 vlc_use_needs skins truetype
191 vlc_use_force skins qt4
192 vlc_use_needs cddax cdio
193 vlc_use_needs vcdx cdio
194 vlc_use_needs vcdx vcdinfo
195 vlc_use_needs vcdinfo cdio
196 vlc_use_needs bidi truetype
197 vlc_use_force remoteosd gcrypt
198 vlc_use_needs fontconfig truetype
199 vlc_use_needs libv4l2 v4l2
200 vlc_use_needs libv4l v4l
201 vlc_use_needs libtiger kate
202 vlc_use_needs xv xcb
203 use cddb && use !cdda && use !cddax && ewarn "USE=cddb requires either cdda or cddax, cddb will be disabled."
204 if use qt4 || use skins ; then
205 qt4_pkg_setup
206 else
207 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
208 ewarn "graphical interface. Maybe that is not what you want..."
209 fi
210 }
211
212 src_unpack() {
213 unpack ${A}
214 if [ "${PV%9999}" != "${PV}" ] ; then
215 git_src_unpack
216 fi
217 }
218
219 src_prepare() {
220 if [ "${PV%9999}" != "${PV}" ] ; then
221 git_src_prepare
222 fi
223 # Make it build with libtool 1.5
224 rm -f m4/lt* m4/libtool.m4
225
226 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
227 eautoreconf
228 }
229
230 src_configure() {
231
232 # It would fail if -fforce-addr is used due to too few registers...
233 use x86 && filter-flags -fforce-addr
234
235 local MOZILLA_PC
236
237 if use nsplugin; then
238 if use seamonkey; then
239 MOZILLA_PC=seamonkey-plugin
240 else
241 if has_version 'net-libs/xulrunner:1.9' ; then
242 MOZILLA_PC=libxul
243 else
244 MOZILLA_PC=xulrunner-plugin
245 fi
246 fi
247 fi
248
249 econf \
250 $(use_enable a52) \
251 $(use_enable aalib aa) \
252 $(use_enable aac faad) \
253 $(use_enable alsa) \
254 $(use_enable altivec) \
255 --disable-asademux \
256 $(use_enable atmo) \
257 $(use_enable avahi bonjour) \
258 $(use_enable bidi fribidi) \
259 $(use_enable cdda vcd) \
260 $(use_enable cddax)\
261 $(use_enable cddb libcddb) \
262 $(use_enable cdio libcdio) \
263 $(use_enable dbus) $(use_enable dbus dbus-control) \
264 $(use_enable dirac) \
265 $(use_enable directfb) \
266 $(use_enable dc1394) \
267 $(use_enable debug) \
268 $(use_enable dts dca) \
269 $(use_enable dvb) \
270 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
271 $(use_enable fbcon fb) \
272 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
273 $(use_enable flac) \
274 $(use_enable fluidsynth) \
275 $(use_enable fontconfig) \
276 $(use_enable ggi) \
277 $(use_enable gnome gnomevfs) \
278 $(use_enable gnutls) \
279 $(use_enable httpd) \
280 $(use_enable id3tag) \
281 $(use_enable ieee1394 dv) \
282 $(use_enable jack) \
283 $(use_enable kate) \
284 $(use_enable libass) \
285 $(use_enable libcaca caca) \
286 $(use_enable gcrypt libgcrypt) \
287 $(use_enable libnotify notify) \
288 $(use_enable libproxy) \
289 --disable-libtar \
290 $(use_enable libtiger tiger) \
291 $(use_enable libsysfs) \
292 $(use_enable libv4l) \
293 $(use_enable libv4l2) \
294 $(use_enable lirc) \
295 $(use_enable live live555) \
296 $(use_enable lua) \
297 $(use_enable matroska mkv) \
298 $(use_enable mmx) \
299 $(use_enable modplug mod) \
300 $(use_enable mp3 mad) \
301 $(use_enable mpeg libmpeg2) \
302 $(use_enable mtp) \
303 $(use_enable musepack mpc) \
304 $(use_enable ncurses) \
305 $(use_enable nsplugin mozilla) --with-mozilla-pkg="${MOZILLA_PC}" \
306 $(use_enable ogg) \
307 $(use_enable opengl glx) $(use_enable opengl) \
308 $(use_enable optimisememory optimize-memory) \
309 $(use_enable oss) \
310 $(use_enable png) \
311 --disable-portaudio \
312 $(use_enable projectm) \
313 $(use_enable pulseaudio pulse) \
314 $(use_enable pvr) \
315 $(use_enable qt4) \
316 $(use_enable rtsp realrtsp) \
317 $(use_enable run-as-root) \
318 $(use_enable samba smb) \
319 $(use_enable schroedinger) \
320 $(use_enable sdl) \
321 $(use_enable sdl-image) \
322 $(use_enable shine) \
323 $(use_enable shout) \
324 $(use_enable skins skins2) \
325 $(use_enable speex) \
326 $(use_enable sse) \
327 $(use_enable stream sout) \
328 $(use_enable svg) \
329 $(use_enable svga svgalib) \
330 $(use_enable taglib) \
331 $(use_enable theora) \
332 $(use_enable truetype freetype) \
333 $(use_enable twolame) \
334 $(use_enable udev) \
335 $(use_enable upnp) \
336 $(use_enable v4l) \
337 $(use_enable v4l2) \
338 $(use_enable vcdinfo) \
339 $(use_enable vcdx) \
340 $(use_enable vorbis) \
341 $(use_enable win32codecs loader) \
342 $(use_enable wma-fixed) \
343 $(use_enable X x11) $(use_enable X screen) \
344 $(use_enable x264) \
345 $(use_enable xcb) \
346 $(use_enable xml libxml2) \
347 $(use_enable xosd) \
348 $(use_enable xv xvideo) \
349 $(use_enable zvbi) $(use_enable !zvbi telx) \
350 --disable-snapshot \
351 --disable-growl \
352 --disable-optimizations \
353 --enable-fast-install \
354 $(vlc_use_enable_force vlm vlm sout) \
355 $(vlc_use_enable_force skins skins2 qt4) \
356 $(vlc_use_enable_force remoteosd remoteosd libgcrypt)
357 }
358
359 src_install() {
360 emake DESTDIR="${D}" install || die "make install failed"
361
362 dodoc AUTHORS HACKING THANKS NEWS README \
363 doc/fortunes.txt doc/intf-cdda.txt doc/intf-vcd.txt
364
365 rm -rf "${D}/usr/share/doc/vlc" \
366 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
367
368 if use nsplugin; then
369 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
370 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
371 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
372 fi
373
374 use skins || rm -rf "${D}/usr/share/vlc/skins2"
375
376 for res in 16 32 48; do
377 insinto /usr/share/icons/hicolor/${res}x${res}/apps/
378 newins "${S}"/share/vlc${res}x${res}.png vlc.png
379 done
380 }

  ViewVC Help
Powered by ViewVC 1.1.20