/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.76 - (show annotations) (download)
Tue Jun 22 12:26:03 2010 UTC (7 years, 3 months ago) by aballier
Branch: MAIN
Changes since 1.75: +1 -6 lines
remove custom handling of icons; its done properly by upstream's makefiles now, by    Rafał Mużyło <galtgendo@o2.pl>, bug #325049
(Portage version: 2.2_rc67/cvs/Linux x86_64)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.75 2010/06/11 10:51:18 aballier Exp $
4
5 EAPI="2"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25 VLC_SNAPSHOT_TIME="0013"
26
27 PATCHLEVEL="85"
28 DESCRIPTION="VLC media player - Video player and streamer"
29 HOMEPAGE="http://www.videolan.org/vlc/"
30 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
31 SRC_URI=""
32 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
33 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
34 MY_P="${P/_alpha*/}-git"
35 elif [[ "${MY_P}" == "${P}" ]]; then
36 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
37 else
38 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
39 fi
40
41 SRC_URI="${SRC_URI}
42 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
43
44 LICENSE="GPL-2"
45 SLOT="0"
46
47 KEYWORDS=""
48 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddb dbus dc1394
49 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
50 +gcrypt ggi gnome gnutls httpd id3tag ieee1394 jack kate kde libass libcaca
51 libnotify libproxy libtiger libv4l libv4l2 lirc live lua matroska mmx
52 modplug mp3 mpeg mtp musepack ncurses nsplugin ogg opengl optimisememory oss
53 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
54 schroedinger sdl sdl-image shine shout skins speex sqlite sse stream
55 svg svga taglib theora truetype twolame udev upnp v4l v4l2 vaapi vcdx vlm
56 vorbis win32codecs wma-fixed +X x264 +xcb xml xosd xv zvbi"
57
58 RDEPEND="
59 !!<=media-video/vlc-1.0.99999
60 sys-libs/zlib
61 >=media-libs/libdvbpsi-0.1.6
62 a52? ( >=media-libs/a52dec-0.7.4-r3 )
63 aalib? ( media-libs/aalib )
64 aac? ( >=media-libs/faad2-2.6.1 )
65 alsa? ( media-libs/alsa-lib )
66 avahi? ( >=net-dns/avahi-0.6[dbus] )
67 bidi? ( >=dev-libs/fribidi-0.10.4 )
68 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
69 dbus? ( >=sys-apps/dbus-1.0.2 )
70 dc1394? ( >=sys-libs/libraw1394-2.0.1
71 >=media-libs/libdc1394-2.0.2 )
72 dirac? ( >=media-video/dirac-0.10.0 )
73 directfb? ( dev-libs/DirectFB sys-libs/zlib )
74 dts? ( media-libs/libdca )
75 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
76 elibc_glibc? ( >=sys-libs/glibc-2.8 )
77 ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20090201 )
78 flac? ( media-libs/libogg
79 >=media-libs/flac-1.1.2 )
80 fluidsynth? ( media-sound/fluidsynth )
81 fontconfig? ( media-libs/fontconfig )
82 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
83 ggi? ( media-libs/libggi )
84 gnome? ( gnome-base/gnome-vfs )
85 gnutls? ( >=net-libs/gnutls-1.7.4 )
86 id3tag? ( media-libs/libid3tag sys-libs/zlib )
87 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
88 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
89 kate? ( >=media-libs/libkate-0.1.1 )
90 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
91 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
92 libnotify? ( x11-libs/libnotify )
93 libproxy? ( net-libs/libproxy )
94 libtiger? ( media-libs/libtiger )
95 lirc? ( app-misc/lirc )
96 live? ( >=media-plugins/live-2008.07.06 )
97 lua? ( >=dev-lang/lua-5.1 )
98 matroska? (
99 >=dev-libs/libebml-0.7.6
100 >=media-libs/libmatroska-0.8.0 )
101 modplug? ( >=media-libs/libmodplug-0.8 )
102 mp3? ( media-libs/libmad )
103 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
104 mtp? ( >=media-libs/libmtp-1.0.0 )
105 musepack? ( >=media-sound/musepack-tools-444 )
106 ncurses? ( sys-libs/ncurses )
107 nsplugin? ( >=net-libs/xulrunner-1.9.2 x11-libs/libXpm x11-libs/libXt )
108 ogg? ( media-libs/libogg )
109 opengl? ( virtual/opengl )
110 png? ( media-libs/libpng sys-libs/zlib )
111 projectm? ( media-libs/libprojectm )
112 pulseaudio? ( >=media-sound/pulseaudio-0.9.11
113 !X? ( >=media-sound/pulseaudio-0.9.11[-X] ) )
114 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
115 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
116 samba? ( || ( >=net-fs/samba-3.4.6[smbclient]
117 <net-fs/samba-3.4 ) )
118 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
119 sdl? ( >=media-libs/libsdl-1.2.8
120 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
121 shout? ( media-libs/libshout )
122 skins? (
123 x11-libs/qt-gui:4 x11-libs/qt-core:4
124 x11-libs/libXext x11-libs/libX11
125 media-libs/freetype media-fonts/dejavu
126 )
127 speex? ( media-libs/speex )
128 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
129 svg? ( >=gnome-base/librsvg-2.9.0 )
130 svga? ( media-libs/svgalib )
131 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
132 theora? ( >=media-libs/libtheora-1.0_beta3 )
133 truetype? ( media-libs/freetype
134 media-fonts/dejavu )
135 twolame? ( media-sound/twolame )
136 udev? ( >=sys-fs/udev-142 )
137 upnp? ( net-libs/libupnp )
138 v4l2? ( libv4l2? ( media-libs/libv4l ) )
139 v4l? ( libv4l? ( media-libs/libv4l ) )
140 vaapi? ( x11-libs/libva >=media-video/ffmpeg-0.5_p22846 )
141 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
142 vorbis? ( media-libs/libvorbis )
143 win32codecs? ( media-libs/win32codecs )
144 X? ( x11-libs/libX11 )
145 x264? ( >=media-libs/x264-0.0.20090923 )
146 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
147 xml? ( dev-libs/libxml2 )
148 xosd? ( x11-libs/xosd )
149 zvbi? ( >=media-libs/zvbi-0.2.25 )
150 "
151
152 DEPEND="${RDEPEND}
153 dvb? ( sys-kernel/linux-headers )
154 kde? ( >=kde-base/kdelibs-4 )
155 v4l? ( sys-kernel/linux-headers )
156 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
157 xcb? ( x11-proto/xproto )
158 dev-util/pkgconfig"
159
160 S="${WORKDIR}/${MY_P}"
161
162 # Displays a warning if the first use flag is set but the second is not
163 vlc_use_needs() {
164 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
165 }
166
167 # Notify the user that some useflag have been forced on
168 vlc_use_force() {
169 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
170 }
171
172 # Use when $1 depends strictly on $2
173 # if use $1 then enable $2
174 vlc_use_enable_force() {
175 use $1 && echo "--enable-$2"
176 }
177
178 pkg_setup() {
179 if has_version '<=media-video/vlc-1.0.99999'; then
180 eerror "Please unmerge vlc-1.0.x first before installing ${P}"
181 eerror "If you don't do that, some plugins will get linked against"
182 eerror "the old ${PN} version and will not work."
183 die "Unmerge vlc 1.0.x first"
184 fi
185
186 # Useflags we need to forcefuly enable
187 vlc_use_force remoteosd gcrypt
188 vlc_use_force skins truetype
189 vlc_use_force skins qt4
190 vlc_use_force vlm stream
191 vlc_use_force vaapi ffmpeg
192
193 # Useflags that will be automagically discarded if deps are not met
194 vlc_use_needs bidi truetype
195 vlc_use_needs cddb cdda
196 vlc_use_needs fontconfig truetype
197 vlc_use_needs libv4l2 v4l2
198 vlc_use_needs libv4l v4l
199 vlc_use_needs libtiger kate
200 vlc_use_needs xv xcb
201
202 if use qt4 || use skins ; then
203 qt4_pkg_setup
204 else
205 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
206 ewarn "graphical interface. Maybe that is not what you want..."
207 fi
208 }
209
210 src_unpack() {
211 unpack ${A}
212 if [ "${PV%9999}" != "${PV}" ] ; then
213 git_src_unpack
214 fi
215 }
216
217 src_prepare() {
218 if [ "${PV%9999}" != "${PV}" ] ; then
219 git_src_prepare
220 fi
221 # Make it build with libtool 1.5
222 rm -f m4/lt* m4/libtool.m4
223
224 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
225 eautoreconf
226 }
227
228 src_configure() {
229
230 # It would fail if -fforce-addr is used due to too few registers...
231 use x86 && filter-flags -fforce-addr
232
233 econf \
234 $(use_enable a52) \
235 $(use_enable aalib aa) \
236 $(use_enable aac faad) \
237 $(use_enable alsa) \
238 $(use_enable altivec) \
239 --disable-asademux \
240 $(use_enable atmo) \
241 $(use_enable avahi bonjour) \
242 $(use_enable bidi fribidi) \
243 $(use_enable cdda vcd) \
244 $(use_enable cddb libcddb) \
245 $(use_enable dbus) $(use_enable dbus dbus-control) \
246 $(use_enable dirac) \
247 $(use_enable directfb) \
248 $(use_enable dc1394) \
249 $(use_enable debug) \
250 $(use_enable dts dca) \
251 $(use_enable dvb) \
252 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
253 $(use_enable fbcon fb) \
254 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
255 $(use_enable flac) \
256 $(use_enable fluidsynth) \
257 $(use_enable fontconfig) \
258 $(use_enable ggi) \
259 $(use_enable gnome gnomevfs) \
260 $(use_enable gnutls) \
261 $(use_enable httpd) \
262 $(use_enable id3tag) \
263 $(use_enable ieee1394 dv) \
264 $(use_enable jack) \
265 $(use_enable kate) \
266 $(use_with kde kde-solid) \
267 $(use_enable libass) \
268 $(use_enable libcaca caca) \
269 $(use_enable gcrypt libgcrypt) \
270 $(use_enable libnotify notify) \
271 $(use_enable libproxy) \
272 --disable-libtar \
273 $(use_enable libtiger tiger) \
274 $(use_enable libv4l) \
275 $(use_enable libv4l2) \
276 $(use_enable lirc) \
277 $(use_enable live live555) \
278 $(use_enable lua) \
279 $(use_enable matroska mkv) \
280 $(use_enable mmx) \
281 $(use_enable modplug mod) \
282 $(use_enable mp3 mad) \
283 $(use_enable mpeg libmpeg2) \
284 $(use_enable mtp) \
285 $(use_enable musepack mpc) \
286 $(use_enable ncurses) \
287 $(use_enable nsplugin mozilla) --with-mozilla-pkg=libxul \
288 $(use_enable ogg) \
289 $(use_enable opengl glx) $(use_enable opengl) \
290 $(use_enable optimisememory optimize-memory) \
291 $(use_enable oss) \
292 $(use_enable png) \
293 --disable-portaudio \
294 $(use_enable projectm) \
295 $(use_enable pulseaudio pulse) \
296 $(use_enable pvr) \
297 $(use_enable qt4) \
298 $(use_enable remoteosd) \
299 $(use_enable rtsp realrtsp) \
300 $(use_enable run-as-root) \
301 $(use_enable samba smb) \
302 $(use_enable schroedinger) \
303 $(use_enable sdl) \
304 $(use_enable sdl-image) \
305 $(use_enable shine) \
306 $(use_enable shout) \
307 $(use_enable skins skins2) \
308 $(use_enable speex) \
309 $(use_enable sqlite) \
310 $(use_enable sse) \
311 $(use_enable stream sout) \
312 $(use_enable svg) \
313 $(use_enable svga svgalib) \
314 $(use_enable taglib) \
315 $(use_enable theora) \
316 $(use_enable truetype freetype) \
317 $(use_enable twolame) \
318 $(use_enable udev) \
319 $(use_enable upnp) \
320 $(use_enable v4l) \
321 $(use_enable v4l2) \
322 $(use_enable vcdx) \
323 $(use_enable vaapi libva) \
324 $(use_enable vlm) \
325 $(use_enable vorbis) \
326 $(use_enable win32codecs loader) \
327 $(use_enable wma-fixed) \
328 $(use_with X x) \
329 $(use_enable x264) \
330 $(use_enable xcb) \
331 $(use_enable xml libxml2) \
332 $(use_enable xosd) \
333 $(use_enable xv xvideo) \
334 $(use_enable zvbi) $(use_enable !zvbi telx) \
335 --disable-snapshot \
336 --disable-growl \
337 --disable-optimizations \
338 --enable-fast-install \
339 $(vlc_use_enable_force vlm sout) \
340 $(vlc_use_enable_force skins qt4) \
341 $(vlc_use_enable_force skins freetype) \
342 $(vlc_use_enable_force remoteosd libgcrypt) \
343 $(vlc_use_enable_force vaapi avcodec)
344 }
345
346 src_install() {
347 emake DESTDIR="${D}" install || die "make install failed"
348
349 dodoc AUTHORS HACKING THANKS NEWS README \
350 doc/fortunes.txt doc/intf-vcd.txt
351
352 rm -rf "${D}/usr/share/doc/vlc" \
353 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
354
355 if use nsplugin; then
356 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
357 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
358 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
359 fi
360
361 use skins || rm -rf "${D}/usr/share/vlc/skins2"
362 }
363
364 pkg_postinst() {
365 gnome2_pkg_postinst
366
367 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
368 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
369 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
370 else
371 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
372 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
373 ewarn "If you do not do it, vlc will take a long time to load."
374 fi
375 }

  ViewVC Help
Powered by ViewVC 1.1.20