/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.8 - (show annotations) (download)
Sun May 10 10:26:14 2009 UTC (8 years, 3 months ago) by aballier
Branch: MAIN
Changes since 1.7: +2 -2 lines
bump gnutls requirement
(Portage version: 2.2_rc33/cvs/Linux x86_64)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.7 2009/04/16 17:25:23 aballier Exp $
4
5 EAPI="1"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
11 EGIT_BOOTSTRAP="bootstrap"
12 if [ "${PV%.9999}" != "${PV}" ] ; then
13 EGIT_BRANCH=${PV%.9999}-bugfix
14 else
15 EGIT_BRANCH=master
16 fi
17 fi
18
19 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
20
21 MY_PV="${PV/_/-}"
22 MY_PV="${MY_PV/-beta/-test}"
23 MY_P="${PN}-${MY_PV}"
24 VLC_SNAPSHOT_TIME="0013"
25
26 PATCHLEVEL="59"
27 M4_TARBALL_VERSION="1"
28 DESCRIPTION="VLC media player - Video player and streamer"
29 HOMEPAGE="http://www.videolan.org/vlc/"
30 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
31 SRC_URI=""
32 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
33 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
34 MY_P="${P/_alpha*/}-git"
35 elif [[ "${MY_P}" == "${P}" ]]; then
36 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
37 else
38 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
39 fi
40
41 SRC_URI="${SRC_URI}
42 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2
43 mirror://gentoo/${PN}-m4-${M4_TARBALL_VERSION}.tar.bz2"
44
45 LICENSE="GPL-2"
46 SLOT="0"
47
48 KEYWORDS=""
49 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddax cddb cdio dbus dc1394
50 debug dirac directfb dts dvb dvd fbcon fluidsynth +ffmpeg flac fontconfig ggi gnome gnutls hal httpd
51 id3tag jack kate libass libcaca +libgcrypt libnotify libsysfs libv4l2 lirc live lua matroska mmx modplug mp3 mpeg mtp
52 musepack ncurses nsplugin ogg opengl optimisememory oss pda png pulseaudio pvr +qt4
53 remoteosd rtsp run-as-root samba schroedinger sdl sdl-image seamonkey shine shout skins speex sse stream svg svga taglib
54 theora truetype twolame upnp v4l v4l2 vcdinfo vcdx vlm vorbis win32codecs wma-fixed
55 X x264 xcb xinerama xml xosd xv zvbi"
56
57 RDEPEND="
58 sys-libs/zlib
59 media-libs/libdvbpsi
60 a52? ( >=media-libs/a52dec-0.7.4-r3 )
61 aalib? ( media-libs/aalib )
62 aac? ( >=media-libs/faad2-2.6.1 )
63 alsa? ( media-libs/alsa-lib )
64 avahi? ( >=net-dns/avahi-0.6 )
65 bidi? ( >=dev-libs/fribidi-0.10.4 )
66 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
67 cddax? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
68 cdio? ( >=dev-libs/libcdio-0.78.2 )
69 dbus? ( >=sys-apps/dbus-1.0.2 )
70 dc1394? ( sys-libs/libraw1394
71 <media-libs/libdc1394-1.9.99 )
72 dirac? ( >=media-video/dirac-0.10.0 )
73 directfb? ( dev-libs/DirectFB )
74 dts? ( media-libs/libdca )
75 dvd? ( media-libs/libdvdread
76 media-libs/libdvdcss
77 >=media-libs/libdvdnav-0.1.9
78 media-libs/libdvdplay )
79 ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20090201 )
80 flac? ( media-libs/libogg
81 >=media-libs/flac-1.1.2 )
82 fluidsynth? ( media-sound/fluidsynth )
83 fontconfig? ( media-libs/fontconfig )
84 ggi? ( media-libs/libggi )
85 gnome? ( gnome-base/gnome-vfs )
86 gnutls? ( >=net-libs/gnutls-1.7.4 )
87 hal? ( sys-apps/hal )
88 id3tag? ( media-libs/libid3tag
89 sys-libs/zlib )
90 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
91 kate? ( >=media-libs/libkate-0.1.1 )
92 libass? ( >=media-libs/libass-0.9.5 media-libs/fontconfig )
93 libcaca? ( media-libs/libcaca )
94 libgcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
95 libnotify? ( x11-libs/libnotify )
96 libsysfs? ( sys-fs/sysfsutils )
97 lirc? ( app-misc/lirc )
98 live? ( >=media-plugins/live-2008.07.06 )
99 lua? ( >=dev-lang/lua-5.1 )
100 matroska? (
101 >=dev-libs/libebml-0.7.6
102 >=media-libs/libmatroska-0.8.0 )
103 modplug? ( media-libs/libmodplug )
104 mp3? ( media-libs/libmad )
105 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
106 mtp? ( >=media-libs/libmtp-0.3.0 )
107 musepack? ( media-libs/libmpcdec )
108 ncurses? ( sys-libs/ncurses )
109 nsplugin? (
110 seamonkey? ( =www-client/seamonkey-1* )
111 !seamonkey? ( >=net-libs/xulrunner-1.8 )
112 )
113 ogg? ( media-libs/libogg )
114 pda? ( x11-libs/gtk+:2 )
115 png? ( media-libs/libpng )
116 pulseaudio? ( >=media-sound/pulseaudio-0.9.8 )
117 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
118 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
119 samba? ( net-fs/samba )
120 schroedinger? ( >=media-libs/schroedinger-1.0 )
121 sdl? ( >=media-libs/libsdl-1.2.8
122 sdl-image? ( media-libs/sdl-image ) )
123 shout? ( media-libs/libshout )
124 skins? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
125 speex? ( media-libs/speex )
126 svg? ( >=gnome-base/librsvg-2.9.0 )
127 svga? ( media-libs/svgalib )
128 taglib? ( >=media-libs/taglib-1.5 )
129 theora? ( >=media-libs/libtheora-1.0_beta3 )
130 truetype? ( media-libs/freetype
131 media-fonts/ttf-bitstream-vera )
132 twolame? ( media-sound/twolame )
133 upnp? ( net-libs/libupnp )
134 v4l2? ( libv4l2? ( media-libs/libv4l ) )
135 vcdinfo? ( >=media-video/vcdimager-0.7.22 )
136 vorbis? ( media-libs/libvorbis )
137 win32codecs? ( media-libs/win32codecs )
138 X? (
139 x11-libs/libX11
140 x11-libs/libXext
141 xv? ( x11-libs/libXv )
142 xinerama? ( x11-libs/libXinerama )
143 opengl? ( virtual/opengl )
144 )
145 x264? ( media-libs/x264 )
146 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
147 xml? ( dev-libs/libxml2 )
148 xosd? ( x11-libs/xosd )
149 zvbi? ( >=media-libs/zvbi-0.2.25 )
150 "
151
152 # Disabled features and reasons:
153 # xvmc? ( x11-libs/libXvMC )
154 # Will probably compile only on x86
155
156 DEPEND="${RDEPEND}
157 dvb? ( sys-kernel/linux-headers )
158 v4l? ( sys-kernel/linux-headers )
159 v4l2? ( sys-kernel/linux-headers )
160 X? ( xinerama? ( x11-proto/xineramaproto ) )
161 xcb? ( x11-proto/xproto )
162 dev-util/pkgconfig"
163
164 S="${WORKDIR}/${MY_P}"
165
166 # Displays a warning if the first use flag is set but the second is not
167 vlc_use_needs() {
168 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
169 }
170
171 # Notify the user that some useflag have been forced on
172 vlc_use_force() {
173 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
174 }
175
176 # Use when $2 depends strictly on $3
177 # if use $1 then enable $2 and $3, otherwise disable $2
178 vlc_use_enable_force() {
179 if use $1 ; then
180 echo "--enable-$2 --enable-$3"
181 else
182 echo "--disable-$2"
183 fi
184 }
185
186 pkg_setup() {
187 vlc_use_needs skins truetype
188 vlc_use_force skins qt4
189 vlc_use_needs cddax cdio
190 vlc_use_needs vcdx cdio
191 vlc_use_needs vcdx vcdinfo
192 vlc_use_needs vcdinfo cdio
193 vlc_use_needs bidi truetype
194 vlc_use_force remoteosd libgcrypt
195 vlc_use_needs fontconfig truetype
196 vlc_use_needs libv4l2 v4l2
197 use cddb && use !cdda && use !cddax && ewarn "USE=cddb requires either cdda or cddax, cddb will be disabled."
198 if use qt4 || use skins ; then
199 qt4_pkg_setup
200 else
201 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
202 ewarn "graphical interface. Maybe that is not what you want..."
203 fi
204 }
205
206 src_unpack() {
207 unpack ${A}
208 if [ "${PV%9999}" != "${PV}" ] ; then
209 git_src_unpack
210 fi
211 cd "${S}"
212
213 # Make it build with libtool 1.5
214 rm -f m4/lt* m4/libtool.m4
215
216 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
217 AT_M4DIR="m4 ${WORKDIR}/${PN}-m4" eautoreconf
218 }
219
220 src_compile () {
221
222 # It would fail if -fforce-addr is used due to too few registers...
223 use x86 && filter-flags -fforce-addr
224
225 local MOZILLA_PC
226
227 if use nsplugin; then
228 if use seamonkey; then
229 MOZILLA_PC=seamonkey-plugin
230 else
231 if has_version 'net-libs/xulrunner:1.9' ; then
232 MOZILLA_PC=libxul
233 else
234 MOZILLA_PC=xulrunner-plugin
235 fi
236 fi
237 fi
238
239 econf \
240 $(use_enable a52) \
241 $(use_enable aalib aa) \
242 $(use_enable aac faad) \
243 $(use_enable alsa) \
244 $(use_enable altivec) \
245 --disable-asademux \
246 $(use_enable atmo) \
247 $(use_enable avahi bonjour) \
248 $(use_enable bidi fribidi) \
249 $(use_enable cdda vcd) \
250 $(use_enable cddax)\
251 $(use_enable cddb libcddb) \
252 $(use_enable cdio libcdio) \
253 --disable-csri \
254 $(use_enable dbus) $(use_enable dbus dbus-control) \
255 $(use_enable dirac) \
256 $(use_enable directfb) \
257 $(use_enable dc1394) \
258 $(use_enable debug) \
259 $(use_enable dts dca) \
260 --disable-dv \
261 $(use_enable dvb) \
262 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
263 $(use_enable fbcon fb) \
264 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) --disable-imgresample $(use_enable ffmpeg postproc) \
265 $(use_enable flac) \
266 $(use_enable fluidsynth) \
267 $(use_enable fontconfig) \
268 $(use_enable ggi) \
269 $(use_enable gnome gnomevfs) \
270 $(use_enable gnutls) \
271 $(use_enable hal) \
272 $(use_enable httpd) \
273 $(use_enable id3tag) \
274 $(use_enable jack) \
275 $(use_enable kate) \
276 $(use_enable libass) \
277 $(use_enable libcaca caca) \
278 $(use_enable libgcrypt) \
279 $(use_enable libnotify notify) \
280 --disable-libproxy \
281 --disable-libtar \
282 $(use_enable libsysfs) \
283 $(use_enable libv4l2) \
284 $(use_enable lirc) \
285 $(use_enable live live555) \
286 $(use_enable lua) \
287 $(use_enable matroska mkv) \
288 $(use_enable mmx) \
289 $(use_enable modplug mod) \
290 $(use_enable mp3 mad) \
291 $(use_enable mpeg libmpeg2) \
292 $(use_enable mtp) \
293 $(use_enable musepack mpc) \
294 $(use_enable ncurses) \
295 $(use_enable nsplugin mozilla) --with-mozilla-pkg="${MOZILLA_PC}" \
296 $(use_enable ogg) \
297 $(use_enable opengl glx) $(use_enable opengl) $(use_enable opengl galaktos) \
298 $(use_enable optimisememory optimize-memory) \
299 $(use_enable oss) \
300 $(use_enable pda) \
301 $(use_enable png) \
302 --disable-portaudio \
303 $(use_enable pulseaudio pulse) \
304 $(use_enable pvr) \
305 $(use_enable qt4) \
306 $(use_enable rtsp realrtsp) \
307 $(use_enable run-as-root) \
308 $(use_enable samba smb) \
309 $(use_enable schroedinger) \
310 $(use_enable sdl) \
311 $(use_enable sdl-image) \
312 $(use_enable shine) \
313 $(use_enable shout) \
314 $(use_enable skins skins2) \
315 $(use_enable speex) \
316 $(use_enable sse) \
317 $(use_enable stream sout) \
318 $(use_enable svg) \
319 $(use_enable svga svgalib) \
320 $(use_enable taglib) \
321 $(use_enable theora) \
322 $(use_enable truetype freetype) \
323 $(use_enable twolame) \
324 $(use_enable upnp) \
325 $(use_enable v4l) \
326 $(use_enable v4l2) \
327 $(use_enable vcdinfo) \
328 $(use_enable vcdx) \
329 $(use_enable vorbis) \
330 $(use_enable win32codecs loader) \
331 $(use_enable wma-fixed) \
332 $(use_enable X x11) $(use_enable X screen) \
333 $(use_enable x264) \
334 $(use_enable xcb) \
335 $(use_enable xinerama) \
336 $(use_enable xml libxml2) \
337 $(use_enable xosd) \
338 $(use_enable xv xvideo) \
339 --disable-xvmc \
340 $(use_enable zvbi) \
341 --disable-snapshot \
342 --disable-growl \
343 --disable-optimizations \
344 --enable-fast-install \
345 $(vlc_use_enable_force vlm vlm sout) \
346 $(vlc_use_enable_force skins skins2 qt4) \
347 $(vlc_use_enable_force remoteosd remoteosd libgcrypt)
348
349 emake || die "make of VLC failed"
350 }
351
352 src_install() {
353 emake DESTDIR="${D}" install || die "make install failed"
354
355 dodoc AUTHORS MAINTAINERS HACKING THANKS NEWS README \
356 doc/fortunes.txt doc/intf-cdda.txt doc/intf-vcd.txt
357
358 rm -rf "${D}/usr/share/doc/vlc" \
359 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
360
361 if use nsplugin; then
362 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
363 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
364 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
365 fi
366
367 use skins || rm -rf "${D}/usr/share/vlc/skins2"
368
369 for res in 16 32 48; do
370 insinto /usr/share/icons/hicolor/${res}x${res}/apps/
371 newins "${S}"/share/vlc${res}x${res}.png vlc.png
372 done
373 }

  ViewVC Help
Powered by ViewVC 1.1.20