/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.82 - (show annotations) (download)
Sun Jul 18 10:16:06 2010 UTC (7 years, 1 month ago) by aballier
Branch: MAIN
Changes since 1.81: +2 -2 lines
update the patchset for master
(Portage version: 2.2_rc67/cvs/Linux x86_64)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.81 2010/07/17 15:38:23 aballier Exp $
4
5 EAPI="3"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25 VLC_SNAPSHOT_TIME="0013"
26
27 PATCHLEVEL="86"
28 DESCRIPTION="VLC media player - Video player and streamer"
29 HOMEPAGE="http://www.videolan.org/vlc/"
30 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
31 SRC_URI=""
32 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
33 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
34 MY_P="${P/_alpha*/}-git"
35 elif [[ "${MY_P}" == "${P}" ]]; then
36 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
37 else
38 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
39 fi
40
41 SRC_URI="${SRC_URI}
42 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
43
44 LICENSE="GPL-2"
45 SLOT="0"
46
47 KEYWORDS=""
48 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddb dbus dc1394
49 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
50 +gcrypt ggi gnome gnutls httpd id3tag ieee1394 jack kate kde libass libcaca
51 libnotify libproxy libtiger libv4l libv4l2 lirc live lua matroska mmx
52 modplug mp3 mpeg mtp musepack ncurses nsplugin ogg opengl optimisememory oss
53 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
54 schroedinger sdl sdl-image shine shout skins speex sqlite sse stream
55 svg svga taglib theora truetype twolame udev upnp v4l v4l2 vaapi vcdx vlm
56 vorbis win32codecs wma-fixed +X x264 +xcb xml xosd xv zvbi"
57
58 RDEPEND="
59 sys-libs/zlib
60 >=media-libs/libdvbpsi-0.1.6
61 a52? ( >=media-libs/a52dec-0.7.4-r3 )
62 aalib? ( media-libs/aalib )
63 aac? ( >=media-libs/faad2-2.6.1 )
64 alsa? ( media-libs/alsa-lib )
65 avahi? ( >=net-dns/avahi-0.6[dbus] )
66 bidi? ( >=dev-libs/fribidi-0.10.4 )
67 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
68 dbus? ( >=sys-apps/dbus-1.0.2 )
69 dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
70 dirac? ( >=media-video/dirac-0.10.0 )
71 directfb? ( dev-libs/DirectFB sys-libs/zlib )
72 dts? ( media-libs/libdca )
73 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
74 elibc_glibc? ( >=sys-libs/glibc-2.8 )
75 ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20090201 )
76 flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
77 fluidsynth? ( media-sound/fluidsynth )
78 fontconfig? ( media-libs/fontconfig )
79 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
80 ggi? ( media-libs/libggi )
81 gnome? ( gnome-base/gnome-vfs )
82 gnutls? ( >=net-libs/gnutls-1.7.4 >=dev-libs/libgcrypt-1.2.0 )
83 id3tag? ( media-libs/libid3tag sys-libs/zlib )
84 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
85 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
86 kate? ( >=media-libs/libkate-0.1.1 )
87 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
88 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
89 libnotify? ( x11-libs/libnotify )
90 libproxy? ( net-libs/libproxy )
91 libtiger? ( media-libs/libtiger )
92 lirc? ( app-misc/lirc )
93 live? ( >=media-plugins/live-2008.07.06 )
94 lua? ( >=dev-lang/lua-5.1 )
95 matroska? ( >=dev-libs/libebml-0.7.6 >=media-libs/libmatroska-0.8.0 )
96 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
97 mp3? ( media-libs/libmad )
98 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
99 mtp? ( >=media-libs/libmtp-1.0.0 )
100 musepack? ( >=media-sound/musepack-tools-444 )
101 ncurses? ( sys-libs/ncurses )
102 nsplugin? ( >=net-libs/xulrunner-1.9.2 x11-libs/libXpm x11-libs/libXt )
103 ogg? ( media-libs/libogg )
104 opengl? ( virtual/opengl x11-libs/libX11[xcb] )
105 png? ( media-libs/libpng sys-libs/zlib )
106 projectm? ( media-libs/libprojectm )
107 pulseaudio? ( >=media-sound/pulseaudio-0.9.11
108 !X? ( >=media-sound/pulseaudio-0.9.11[-X] ) )
109 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
110 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
111 samba? ( || ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.4 ) )
112 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
113 sdl? ( >=media-libs/libsdl-1.2.8
114 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
115 shout? ( media-libs/libshout )
116 skins? (
117 x11-libs/qt-gui:4 x11-libs/qt-core:4
118 x11-libs/libXext x11-libs/libX11
119 media-libs/freetype media-fonts/dejavu
120 )
121 speex? ( media-libs/speex )
122 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
123 svg? ( >=gnome-base/librsvg-2.9.0 )
124 svga? ( media-libs/svgalib )
125 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
126 theora? ( >=media-libs/libtheora-1.0_beta3 )
127 truetype? ( media-libs/freetype media-fonts/dejavu )
128 twolame? ( media-sound/twolame )
129 udev? ( >=sys-fs/udev-142 )
130 upnp? ( net-libs/libupnp )
131 v4l2? ( libv4l2? ( media-libs/libv4l ) )
132 v4l? ( libv4l? ( media-libs/libv4l ) )
133 vaapi? ( x11-libs/libva >=media-video/ffmpeg-0.5_p22846 )
134 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
135 vorbis? ( media-libs/libvorbis )
136 win32codecs? ( media-libs/win32codecs )
137 X? ( x11-libs/libX11 )
138 x264? ( >=media-libs/x264-0.0.20090923 )
139 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
140 xml? ( dev-libs/libxml2 )
141 xosd? ( x11-libs/xosd )
142 zvbi? ( >=media-libs/zvbi-0.2.25 )
143 "
144
145 DEPEND="${RDEPEND}
146 !!<=media-video/vlc-1.0.99999
147 dvb? ( sys-kernel/linux-headers )
148 kde? ( >=kde-base/kdelibs-4 )
149 v4l? ( sys-kernel/linux-headers )
150 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
151 xcb? ( x11-proto/xproto )
152 dev-util/pkgconfig"
153
154 S="${WORKDIR}/${MY_P}"
155
156 # Displays a warning if the first use flag is set but the second is not
157 vlc_use_needs() {
158 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
159 }
160
161 # Notify the user that some useflag have been forced on
162 vlc_use_force() {
163 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
164 }
165
166 # Use when $1 depends strictly on $2
167 # if use $1 then enable $2
168 vlc_use_enable_force() {
169 use $1 && echo "--enable-$2"
170 }
171
172 pkg_setup() {
173 # Useflags we need to forcefuly enable
174 vlc_use_force remoteosd gcrypt
175 vlc_use_force gnutls gcrypt
176 vlc_use_force skins truetype
177 vlc_use_force skins qt4
178 vlc_use_force vlm stream
179 vlc_use_force vaapi ffmpeg
180
181 # Useflags that will be automagically discarded if deps are not met
182 vlc_use_needs bidi truetype
183 vlc_use_needs cddb cdda
184 vlc_use_needs fontconfig truetype
185 vlc_use_needs libv4l2 v4l2
186 vlc_use_needs libv4l v4l
187 vlc_use_needs libtiger kate
188 vlc_use_needs xv xcb
189
190 if use qt4 || use skins ; then
191 qt4_pkg_setup
192 else
193 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
194 ewarn "graphical interface. Maybe that is not what you want..."
195 fi
196 }
197
198 src_unpack() {
199 unpack ${A}
200 if [ "${PV%9999}" != "${PV}" ] ; then
201 git_src_unpack
202 fi
203 }
204
205 src_prepare() {
206 if [ "${PV%9999}" != "${PV}" ] ; then
207 git_src_prepare
208 fi
209 # Make it build with libtool 1.5
210 rm -f m4/lt* m4/libtool.m4
211
212 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
213 eautoreconf
214 }
215
216 src_configure() {
217
218 # It would fail if -fforce-addr is used due to too few registers...
219 use x86 && filter-flags -fforce-addr
220
221 econf \
222 $(use_enable a52) \
223 $(use_enable aalib aa) \
224 $(use_enable aac faad) \
225 $(use_enable alsa) \
226 $(use_enable altivec) \
227 --disable-asademux \
228 $(use_enable atmo) \
229 $(use_enable avahi bonjour) \
230 $(use_enable bidi fribidi) \
231 $(use_enable cdda vcd) \
232 $(use_enable cddb libcddb) \
233 $(use_enable dbus) $(use_enable dbus dbus-control) \
234 $(use_enable dirac) \
235 $(use_enable directfb) \
236 $(use_enable dc1394) \
237 $(use_enable debug) \
238 $(use_enable dts dca) \
239 $(use_enable dvb) \
240 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
241 $(use_enable fbcon fb) \
242 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
243 $(use_enable flac) \
244 $(use_enable fluidsynth) \
245 $(use_enable fontconfig) \
246 $(use_enable ggi) \
247 $(use_enable gnome gnomevfs) \
248 $(use_enable gnutls) \
249 $(use_enable httpd) \
250 $(use_enable id3tag) \
251 $(use_enable ieee1394 dv) \
252 $(use_enable jack) \
253 $(use_enable kate) \
254 $(use_with kde kde-solid) \
255 $(use_enable libass) \
256 $(use_enable libcaca caca) \
257 $(use_enable gcrypt libgcrypt) \
258 $(use_enable libnotify notify) \
259 $(use_enable libproxy) \
260 --disable-libtar \
261 $(use_enable libtiger tiger) \
262 $(use_enable libv4l) \
263 $(use_enable libv4l2) \
264 $(use_enable lirc) \
265 $(use_enable live live555) \
266 $(use_enable lua) \
267 $(use_enable matroska mkv) \
268 $(use_enable mmx) \
269 $(use_enable modplug mod) \
270 $(use_enable mp3 mad) \
271 $(use_enable mpeg libmpeg2) \
272 $(use_enable mtp) \
273 $(use_enable musepack mpc) \
274 $(use_enable ncurses) \
275 $(use_enable nsplugin mozilla) --with-mozilla-pkg=libxul \
276 $(use_enable ogg) \
277 $(use_enable opengl glx) $(use_enable opengl) \
278 $(use_enable optimisememory optimize-memory) \
279 $(use_enable oss) \
280 $(use_enable png) \
281 --disable-portaudio \
282 $(use_enable projectm) \
283 $(use_enable pulseaudio pulse) \
284 $(use_enable pvr) \
285 $(use_enable qt4) \
286 $(use_enable remoteosd) \
287 $(use_enable rtsp realrtsp) \
288 $(use_enable run-as-root) \
289 $(use_enable samba smb) \
290 $(use_enable schroedinger) \
291 $(use_enable sdl) \
292 $(use_enable sdl-image) \
293 $(use_enable shine) \
294 $(use_enable shout) \
295 $(use_enable skins skins2) \
296 $(use_enable speex) \
297 $(use_enable sqlite) \
298 $(use_enable sse) \
299 $(use_enable stream sout) \
300 $(use_enable svg) \
301 $(use_enable svga svgalib) \
302 $(use_enable taglib) \
303 $(use_enable theora) \
304 $(use_enable truetype freetype) \
305 $(use_enable twolame) \
306 $(use_enable udev) \
307 $(use_enable upnp) \
308 $(use_enable v4l) \
309 $(use_enable v4l2) \
310 $(use_enable vcdx) \
311 $(use_enable vaapi libva) \
312 $(use_enable vlm) \
313 $(use_enable vorbis) \
314 $(use_enable win32codecs loader) \
315 $(use_enable wma-fixed) \
316 $(use_with X x) \
317 $(use_enable x264) \
318 $(use_enable xcb) \
319 $(use_enable xml libxml2) \
320 $(use_enable xosd) \
321 $(use_enable xv xvideo) \
322 $(use_enable zvbi) $(use_enable !zvbi telx) \
323 --disable-snapshot \
324 --disable-growl \
325 --disable-optimizations \
326 --enable-fast-install \
327 $(vlc_use_enable_force vlm sout) \
328 $(vlc_use_enable_force skins qt4) \
329 $(vlc_use_enable_force skins freetype) \
330 $(vlc_use_enable_force remoteosd libgcrypt) \
331 $(vlc_use_enable_force gnutls libgcrypt) \
332 $(vlc_use_enable_force vaapi avcodec)
333 }
334
335 src_install() {
336 emake DESTDIR="${D}" install || die "make install failed"
337
338 dodoc AUTHORS HACKING THANKS NEWS README \
339 doc/fortunes.txt doc/intf-vcd.txt
340
341 rm -rf "${D}/usr/share/doc/vlc" \
342 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
343
344 if use nsplugin; then
345 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
346 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
347 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
348 fi
349
350 use skins || rm -rf "${D}/usr/share/vlc/skins2"
351 }
352
353 pkg_postinst() {
354 gnome2_pkg_postinst
355
356 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
357 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
358 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
359 else
360 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
361 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
362 ewarn "If you do not do it, vlc will take a long time to load."
363 fi
364 }

  ViewVC Help
Powered by ViewVC 1.1.20