/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.89 - (show annotations) (download)
Thu Jul 22 20:06:20 2010 UTC (7 years ago) by aballier
Branch: MAIN
Changes since 1.88: +6 -2 lines
Put keywords inside an if to make bumps even easier
(Portage version: 2.2_rc67/cvs/Linux x86_64)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.88 2010/07/22 06:39:54 aballier Exp $
4
5 EAPI="3"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25 VLC_SNAPSHOT_TIME="0013"
26
27 PATCHLEVEL="86"
28 DESCRIPTION="VLC media player - Video player and streamer"
29 HOMEPAGE="http://www.videolan.org/vlc/"
30 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
31 SRC_URI=""
32 elif [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
33 SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
34 MY_P="${P/_alpha*/}-git"
35 elif [[ "${MY_P}" == "${P}" ]]; then
36 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
37 else
38 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
39 fi
40
41 SRC_URI="${SRC_URI}
42 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
43
44 LICENSE="GPL-2"
45 SLOT="0"
46
47 if [ "${PV%9999}" = "${PV}" ] ; then
48 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
49 else
50 KEYWORDS=""
51 fi
52 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddb dbus dc1394
53 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
54 +gcrypt gnome gnutls httpd ieee1394 jack kate kde libass libcaca
55 libnotify libproxy libtiger libv4l libv4l2 lirc live lua matroska mmx
56 modplug mp3 mpeg mtp musepack ncurses nsplugin ogg opengl optimisememory oss
57 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
58 schroedinger sdl sdl-image shine shout skins speex sqlite sse stream
59 svg taglib theora truetype twolame udev upnp v4l v4l2 vaapi vcdx vlm
60 vorbis win32codecs wma-fixed +X x264 +xcb xml xosd xv zvbi"
61
62 RDEPEND="
63 sys-libs/zlib
64 >=media-libs/libdvbpsi-0.1.6
65 a52? ( >=media-libs/a52dec-0.7.4-r3 )
66 aalib? ( media-libs/aalib )
67 aac? ( >=media-libs/faad2-2.6.1 )
68 alsa? ( media-libs/alsa-lib )
69 avahi? ( >=net-dns/avahi-0.6[dbus] )
70 bidi? ( >=dev-libs/fribidi-0.10.4 )
71 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
72 dbus? ( >=sys-apps/dbus-1.0.2 )
73 dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
74 dirac? ( >=media-video/dirac-0.10.0 )
75 directfb? ( dev-libs/DirectFB sys-libs/zlib )
76 dts? ( media-libs/libdca )
77 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
78 elibc_glibc? ( >=sys-libs/glibc-2.8 )
79 ffmpeg? ( >=media-video/ffmpeg-0.6 )
80 flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
81 fluidsynth? ( media-sound/fluidsynth )
82 fontconfig? ( media-libs/fontconfig )
83 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
84 gnome? ( gnome-base/gnome-vfs )
85 gnutls? ( >=net-libs/gnutls-1.7.4 >=dev-libs/libgcrypt-1.2.0 )
86 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
87 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
88 kate? ( >=media-libs/libkate-0.1.1 )
89 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
90 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
91 libnotify? ( x11-libs/libnotify )
92 libproxy? ( net-libs/libproxy )
93 libtiger? ( media-libs/libtiger )
94 lirc? ( app-misc/lirc )
95 live? ( >=media-plugins/live-2008.07.06 )
96 lua? ( >=dev-lang/lua-5.1 )
97 matroska? ( >=dev-libs/libebml-0.7.6 >=media-libs/libmatroska-0.8.0 )
98 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
99 mp3? ( media-libs/libmad )
100 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
101 mtp? ( >=media-libs/libmtp-1.0.0 )
102 musepack? ( >=media-sound/musepack-tools-444 )
103 ncurses? ( sys-libs/ncurses )
104 nsplugin? ( >=net-libs/xulrunner-1.9.2 x11-libs/libXpm x11-libs/libXt x11-libs/libxcb x11-libs/xcb-util )
105 ogg? ( media-libs/libogg )
106 opengl? ( virtual/opengl x11-libs/libX11[xcb] )
107 png? ( media-libs/libpng sys-libs/zlib )
108 projectm? ( media-libs/libprojectm )
109 pulseaudio? ( >=media-sound/pulseaudio-0.9.11
110 !X? ( >=media-sound/pulseaudio-0.9.11[-X] ) )
111 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
112 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
113 samba? ( || ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.4 ) )
114 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
115 sdl? ( >=media-libs/libsdl-1.2.8
116 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
117 shout? ( media-libs/libshout )
118 skins? (
119 x11-libs/qt-gui:4 x11-libs/qt-core:4
120 x11-libs/libXext x11-libs/libX11
121 media-libs/freetype media-fonts/dejavu
122 )
123 speex? ( media-libs/speex )
124 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
125 svg? ( >=gnome-base/librsvg-2.9.0 )
126 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
127 theora? ( >=media-libs/libtheora-1.0_beta3 )
128 truetype? ( media-libs/freetype media-fonts/dejavu )
129 twolame? ( media-sound/twolame )
130 udev? ( >=sys-fs/udev-142 )
131 upnp? ( net-libs/libupnp )
132 v4l2? ( libv4l2? ( media-libs/libv4l ) )
133 v4l? ( libv4l? ( media-libs/libv4l ) )
134 vaapi? ( x11-libs/libva >=media-video/ffmpeg-0.6 )
135 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
136 vorbis? ( media-libs/libvorbis )
137 win32codecs? ( media-libs/win32codecs )
138 X? ( x11-libs/libX11 )
139 x264? ( >=media-libs/x264-0.0.20090923 )
140 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
141 xml? ( dev-libs/libxml2 )
142 xosd? ( x11-libs/xosd )
143 zvbi? ( >=media-libs/zvbi-0.2.25 )
144 "
145
146 DEPEND="${RDEPEND}
147 !!<=media-video/vlc-1.1.99999
148 dvb? ( sys-kernel/linux-headers )
149 kde? ( >=kde-base/kdelibs-4 )
150 v4l? ( sys-kernel/linux-headers )
151 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
152 xcb? ( x11-proto/xproto )
153 dev-util/pkgconfig"
154
155 S="${WORKDIR}/${MY_P}"
156
157 # Displays a warning if the first use flag is set but the second is not
158 vlc_use_needs() {
159 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
160 }
161
162 # Notify the user that some useflag have been forced on
163 vlc_use_force() {
164 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
165 }
166
167 # Use when $1 depends strictly on $2
168 # if use $1 then enable $2
169 vlc_use_enable_force() {
170 use $1 && echo "--enable-$2"
171 }
172
173 pkg_setup() {
174 # Useflags we need to forcefuly enable
175 vlc_use_force remoteosd gcrypt
176 vlc_use_force gnutls gcrypt
177 vlc_use_force skins truetype
178 vlc_use_force skins qt4
179 vlc_use_force vlm stream
180 vlc_use_force vaapi ffmpeg
181 vlc_use_force nsplugin xcb
182
183 # Useflags that will be automagically discarded if deps are not met
184 vlc_use_needs bidi truetype
185 vlc_use_needs cddb cdda
186 vlc_use_needs fontconfig truetype
187 vlc_use_needs libv4l2 v4l2
188 vlc_use_needs libv4l v4l
189 vlc_use_needs libtiger kate
190 vlc_use_needs xv xcb
191
192 if use qt4 || use skins ; then
193 qt4_pkg_setup
194 else
195 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
196 ewarn "graphical interface. Maybe that is not what you want..."
197 fi
198 }
199
200 src_unpack() {
201 unpack ${A}
202 if [ "${PV%9999}" != "${PV}" ] ; then
203 git_src_unpack
204 fi
205 }
206
207 src_prepare() {
208 if [ "${PV%9999}" != "${PV}" ] ; then
209 git_src_prepare
210 fi
211 # Make it build with libtool 1.5
212 rm -f m4/lt* m4/libtool.m4
213
214 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
215 eautoreconf
216 }
217
218 src_configure() {
219
220 # It would fail if -fforce-addr is used due to too few registers...
221 use x86 && filter-flags -fforce-addr
222
223 econf \
224 $(use_enable a52) \
225 $(use_enable aalib aa) \
226 $(use_enable aac faad) \
227 $(use_enable alsa) \
228 $(use_enable altivec) \
229 --disable-asademux \
230 $(use_enable atmo) \
231 $(use_enable avahi bonjour) \
232 $(use_enable bidi fribidi) \
233 $(use_enable cdda vcd) \
234 $(use_enable cddb libcddb) \
235 $(use_enable dbus) $(use_enable dbus dbus-control) \
236 $(use_enable dirac) \
237 $(use_enable directfb) \
238 $(use_enable dc1394) \
239 $(use_enable debug) \
240 $(use_enable dts dca) \
241 $(use_enable dvb) \
242 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
243 $(use_enable fbcon fb) \
244 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
245 $(use_enable flac) \
246 $(use_enable fluidsynth) \
247 $(use_enable fontconfig) \
248 $(use_enable gnome gnomevfs) \
249 $(use_enable gnutls) \
250 $(use_enable httpd) \
251 $(use_enable ieee1394 dv) \
252 $(use_enable jack) \
253 $(use_enable kate) \
254 $(use_with kde kde-solid) \
255 $(use_enable libass) \
256 $(use_enable libcaca caca) \
257 $(use_enable gcrypt libgcrypt) \
258 $(use_enable libnotify notify) \
259 $(use_enable libproxy) \
260 --disable-libtar \
261 $(use_enable libtiger tiger) \
262 $(use_enable libv4l) \
263 $(use_enable libv4l2) \
264 $(use_enable lirc) \
265 $(use_enable live live555) \
266 $(use_enable lua) \
267 $(use_enable matroska mkv) \
268 $(use_enable mmx) \
269 $(use_enable modplug mod) \
270 $(use_enable mp3 mad) \
271 $(use_enable mpeg libmpeg2) \
272 $(use_enable mtp) \
273 $(use_enable musepack mpc) \
274 $(use_enable ncurses) \
275 $(use_enable nsplugin mozilla) --with-mozilla-pkg=libxul \
276 $(use_enable ogg) \
277 $(use_enable opengl glx) \
278 $(use_enable optimisememory optimize-memory) \
279 $(use_enable oss) \
280 $(use_enable png) \
281 --disable-portaudio \
282 $(use_enable projectm) \
283 $(use_enable pulseaudio pulse) \
284 $(use_enable pvr) \
285 $(use_enable qt4) \
286 $(use_enable remoteosd) \
287 $(use_enable rtsp realrtsp) \
288 $(use_enable run-as-root) \
289 $(use_enable samba smb) \
290 $(use_enable schroedinger) \
291 $(use_enable sdl) \
292 $(use_enable sdl-image) \
293 $(use_enable shine) \
294 $(use_enable shout) \
295 $(use_enable skins skins2) \
296 $(use_enable speex) \
297 $(use_enable sqlite) \
298 $(use_enable sse) \
299 $(use_enable stream sout) \
300 $(use_enable svg) \
301 $(use_enable taglib) \
302 $(use_enable theora) \
303 $(use_enable truetype freetype) \
304 $(use_enable twolame) \
305 $(use_enable udev) \
306 $(use_enable upnp) \
307 $(use_enable v4l) \
308 $(use_enable v4l2) \
309 $(use_enable vcdx) \
310 $(use_enable vaapi libva) \
311 $(use_enable vlm) \
312 $(use_enable vorbis) \
313 $(use_enable win32codecs loader) \
314 $(use_enable wma-fixed) \
315 $(use_with X x) \
316 $(use_enable x264) \
317 $(use_enable xcb) \
318 $(use_enable xml libxml2) \
319 $(use_enable xosd) \
320 $(use_enable xv xvideo) \
321 $(use_enable zvbi) $(use_enable !zvbi telx) \
322 --disable-snapshot \
323 --disable-growl \
324 --disable-optimizations \
325 --enable-fast-install \
326 $(vlc_use_enable_force vlm sout) \
327 $(vlc_use_enable_force skins qt4) \
328 $(vlc_use_enable_force skins freetype) \
329 $(vlc_use_enable_force remoteosd libgcrypt) \
330 $(vlc_use_enable_force gnutls libgcrypt) \
331 $(vlc_use_enable_force vaapi avcodec) \
332 $(vlc_use_enable_force nsplugin xcb)
333 }
334
335 src_install() {
336 emake DESTDIR="${D}" install || die "make install failed"
337
338 dodoc AUTHORS HACKING THANKS NEWS README \
339 doc/fortunes.txt doc/intf-vcd.txt
340
341 rm -rf "${D}/usr/share/doc/vlc" \
342 "${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
343
344 if use nsplugin; then
345 dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
346 mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
347 "${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
348 fi
349
350 use skins || rm -rf "${D}/usr/share/vlc/skins2"
351
352 # Punt useless libtool's .la files
353 find "${D}" -name '*.la' -delete
354 }
355
356 pkg_postinst() {
357 gnome2_pkg_postinst
358
359 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
360 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
361 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
362 else
363 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
364 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
365 ewarn "If you do not do it, vlc will take a long time to load."
366 fi
367 }

  ViewVC Help
Powered by ViewVC 1.1.20