/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.241 - (show annotations) (download)
Sat Jul 4 12:26:23 2015 UTC (3 weeks, 3 days ago) by pacho
Branch: MAIN
CVS Tags: HEAD
Changes since 1.240: +2 -2 lines
It will need to be rebuilt with media-libs/libdvbpsi subslot bumps

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.240 2015/06/08 18:43:38 pacho Exp $
4
5 EAPI="5"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM="git-r3"
10
11 if [ "${PV%.9999}" != "${PV}" ] ; then
12 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
13 else
14 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
15 fi
16 fi
17
18 inherit eutils multilib autotools toolchain-funcs flag-o-matic virtualx ${SCM}
19
20 MY_PV="${PV/_/-}"
21 MY_PV="${MY_PV/-beta/-test}"
22 MY_P="${PN}-${MY_PV}"
23
24 DESCRIPTION="VLC media player - Video player and streamer"
25 HOMEPAGE="http://www.videolan.org/vlc/"
26 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
27 SRC_URI=""
28 elif [[ "${MY_P}" == "${P}" ]]; then
29 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.xz"
30 else
31 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.xz"
32 fi
33
34 LICENSE="LGPL-2.1 GPL-2"
35 SLOT="0/5-8" # vlc - vlccore
36
37 if [ "${PV%9999}" = "${PV}" ] ; then
38 KEYWORDS="~amd64 ~arm ~ppc -sparc ~x86 ~x86-fbsd"
39 else
40 KEYWORDS=""
41 fi
42
43 IUSE="a52 aalib alsa altivec atmo +audioqueue +avcodec
44 +avformat bidi bluray cdda cddb chromaprint dbus dc1394 debug
45 directfb directx dts dvb +dvbpsi dvd dxva2 elibc_glibc +encode faad fdk
46 fluidsynth +ffmpeg flac fontconfig +gcrypt gme gnome gnutls
47 growl httpd ieee1394 jack jpeg kate kde libass libav libcaca libnotify
48 +libsamplerate libtiger linsys libtar lirc live lua
49 macosx-dialog-provider macosx-eyetv macosx-quartztext macosx-qtkit
50 matroska media-library cpu_flags_x86_mmx modplug mp3 mpeg
51 mtp musepack ncurses neon ogg omxil opencv opengl optimisememory opus
52 png +postproc projectm pulseaudio +qt4 qt5 rdp rtsp run-as-root samba
53 schroedinger sdl sdl-image sftp shout sid skins speex cpu_flags_x86_sse svg +swscale
54 taglib theora tremor truetype twolame udev upnp vaapi v4l vcdx vdpau
55 vlm vnc vorbis vpx wma-fixed +X x264 x265 +xcb xml xv zvbi zeroconf"
56
57 RDEPEND="
58 !<media-video/ffmpeg-1.2:0
59 dev-libs/libgpg-error:0
60 net-dns/libidn:0
61 >=sys-libs/zlib-1.2.5.1-r2:0[minizip]
62 virtual/libintl:0
63 a52? ( >=media-libs/a52dec-0.7.4-r3:0 )
64 aalib? ( media-libs/aalib:0 )
65 alsa? ( >=media-libs/alsa-lib-1.0.24:0 )
66 avcodec? (
67 !libav? ( media-video/ffmpeg:0= )
68 libav? ( media-video/libav:0= )
69 )
70 avformat? (
71 !libav? ( media-video/ffmpeg:0= )
72 libav? ( media-video/libav:0= )
73 )
74 bidi? ( >=dev-libs/fribidi-0.10.4:0 )
75 bluray? ( >=media-libs/libbluray-0.3:0 )
76 cddb? ( >=media-libs/libcddb-1.2:0 )
77 chromaprint? ( >=media-libs/chromaprint-0.6:0 )
78 dbus? ( >=sys-apps/dbus-1.6:0 )
79 dc1394? ( >=sys-libs/libraw1394-2.0.1:0 >=media-libs/libdc1394-2.1:2 )
80 directfb? ( dev-libs/DirectFB:0 sys-libs/zlib:0 )
81 dts? ( >=media-libs/libdca-0.0.5:0 )
82 dvbpsi? ( >=media-libs/libdvbpsi-1.0.0:0= )
83 dvd? ( >=media-libs/libdvdread-4.9:0 >=media-libs/libdvdnav-4.9:0 )
84 elibc_glibc? ( >=sys-libs/glibc-2.8:2.2 )
85 faad? ( >=media-libs/faad2-2.6.1:0 )
86 fdk? ( media-libs/fdk-aac:0 )
87 flac? ( >=media-libs/libogg-1:0 >=media-libs/flac-1.1.2:0 )
88 fluidsynth? ( >=media-sound/fluidsynth-1.1.2:0 )
89 fontconfig? ( media-libs/fontconfig:1.0 )
90 gcrypt? ( >=dev-libs/libgcrypt-1.2.0:0= )
91 gme? ( media-libs/game-music-emu:0 )
92 gnome? ( gnome-base/gnome-vfs:2 dev-libs/glib:2 )
93 gnutls? ( >=net-libs/gnutls-3.0.20:0 )
94 ieee1394? ( >=sys-libs/libraw1394-2.0.1:0 >=sys-libs/libavc1394-0.5.3:0 )
95 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1:0 )
96 jpeg? ( virtual/jpeg:0 )
97 kate? ( >=media-libs/libkate-0.3:0 )
98 libass? ( >=media-libs/libass-0.9.8:0 media-libs/fontconfig:1.0 )
99 libcaca? ( >=media-libs/libcaca-0.99_beta14:0 )
100 libnotify? ( x11-libs/libnotify:0 x11-libs/gtk+:2 x11-libs/gdk-pixbuf:2 dev-libs/glib:2 )
101 libsamplerate? ( media-libs/libsamplerate:0 )
102 libtar? ( >=dev-libs/libtar-1.2.11-r3:0 )
103 libtiger? ( >=media-libs/libtiger-0.3.1:0 )
104 linsys? ( >=media-libs/zvbi-0.2.28:0 )
105 lirc? ( app-misc/lirc:0 )
106 live? ( >=media-plugins/live-2011.12.23:0 )
107 lua? ( >=dev-lang/lua-5.1:0 )
108 matroska? ( >=dev-libs/libebml-1:0= >=media-libs/libmatroska-1:0= )
109 modplug? ( >=media-libs/libmodplug-0.8.4:0 !~media-libs/libmodplug-0.8.8 )
110 mp3? ( media-libs/libmad:0 )
111 mpeg? ( >=media-libs/libmpeg2-0.3.2:0 )
112 mtp? ( >=media-libs/libmtp-1:0 )
113 musepack? ( >=media-sound/musepack-tools-444:0 )
114 ncurses? ( sys-libs/ncurses:5[unicode] )
115 ogg? ( >=media-libs/libogg-1:0 )
116 opencv? ( >media-libs/opencv-2:0 )
117 opengl? ( virtual/opengl:0 >=x11-libs/libX11-1.3.99.901:0 )
118 opus? ( >=media-libs/opus-1.0.3:0 )
119 png? ( media-libs/libpng:0= sys-libs/zlib:0 )
120 postproc? (
121 !libav? ( >=media-video/ffmpeg-2.2:0= )
122 libav? ( media-libs/libpostproc:0= )
123 )
124 projectm? ( media-libs/libprojectm:0 media-fonts/dejavu:0 )
125 pulseaudio? ( >=media-sound/pulseaudio-1:0 )
126 qt4? ( >=dev-qt/qtgui-4.6:4 >=dev-qt/qtcore-4.6:4 )
127 qt5? ( >=dev-qt/qtgui-5.1:5 >=dev-qt/qtcore-5.1:5 >=dev-qt/qtwidgets-5.1:5 >=dev-qt/qtx11extras-5.1:5 )
128 rdp? ( >=net-misc/freerdp-1.0.1:0= )
129 samba? ( || ( >=net-fs/samba-3.4.6:0[smbclient] >=net-fs/samba-4:0[client] ) )
130 schroedinger? ( >=media-libs/schroedinger-1.0.10:0 )
131 sdl? ( >=media-libs/libsdl-1.2.10:0
132 sdl-image? ( >=media-libs/sdl-image-1.2.10:0 sys-libs/zlib:0 ) )
133 sftp? ( net-libs/libssh2:0 )
134 shout? ( >=media-libs/libshout-2.1:0 )
135 sid? ( media-libs/libsidplay:2 )
136 skins? ( x11-libs/libXext:0 x11-libs/libXpm:0 x11-libs/libXinerama:0 )
137 speex? ( media-libs/speex:0 )
138 svg? ( >=gnome-base/librsvg-2.9:2 >=x11-libs/cairo-1.13.1:0 )
139 swscale? (
140 !libav? ( media-video/ffmpeg:0= )
141 libav? ( media-video/libav:0= )
142 )
143 taglib? ( >=media-libs/taglib-1.9:0 sys-libs/zlib:0 )
144 theora? ( >=media-libs/libtheora-1.0_beta3:0 )
145 tremor? ( media-libs/tremor:0 )
146 truetype? ( media-libs/freetype:2 virtual/ttf-fonts:0
147 !fontconfig? ( media-fonts/dejavu:0 ) )
148 twolame? ( media-sound/twolame:0 )
149 udev? ( >=virtual/udev-142:0 )
150 upnp? ( net-libs/libupnp:0 )
151 v4l? ( media-libs/libv4l:0 )
152 vaapi? (
153 x11-libs/libva:0[X,drm]
154 !libav? ( media-video/ffmpeg:0=[vaapi] )
155 libav? ( media-video/libav:0=[vaapi] )
156 )
157 vcdx? ( >=dev-libs/libcdio-0.78.2:0 >=media-video/vcdimager-0.7.22:0 )
158 zeroconf? ( >=net-dns/avahi-0.6:0[dbus] )
159 "
160
161 # Temporarily block non-live FFMPEG versions as they break vdpau, 9999 works;
162 # thus we'll have to wait for a new release there.
163 RDEPEND="${RDEPEND}
164 vdpau? (
165 >=x11-libs/libvdpau-0.6:0
166 !libav? ( >=media-video/ffmpeg-2.2:0= )
167 libav? ( >=media-video/libav-10:0= )
168 )
169 vnc? ( >=net-libs/libvncserver-0.9.9:0 )
170 vorbis? ( >=media-libs/libvorbis-1.1:0 )
171 vpx? ( media-libs/libvpx:0 )
172 X? ( x11-libs/libX11:0 )
173 x264? ( >=media-libs/x264-0.0.20090923:0= )
174 x265? ( media-libs/x265:0= )
175 xcb? ( >=x11-libs/libxcb-1.6:0 >=x11-libs/xcb-util-0.3.4:0 >=x11-libs/xcb-util-keysyms-0.3.4:0 )
176 xml? ( >=dev-libs/libxml2-2.5:2 )
177 zvbi? ( >=media-libs/zvbi-0.2.25:0 )
178 "
179
180 DEPEND="${RDEPEND}
181 kde? ( >=kde-base/kdelibs-4:4 )
182 xcb? ( x11-proto/xproto:0 )
183 app-arch/xz-utils:0
184 dev-lang/yasm:*
185 >=sys-devel/gettext-0.19.2:*
186 virtual/pkgconfig:*
187 "
188
189 REQUIRED_USE="
190 aalib? ( X )
191 bidi? ( truetype )
192 cddb? ( cdda )
193 dvb? ( dvbpsi )
194 dxva2? ( avcodec )
195 ffmpeg? ( avcodec avformat swscale postproc )
196 fontconfig? ( truetype )
197 gnutls? ( gcrypt )
198 httpd? ( lua )
199 libcaca? ( X )
200 libtar? ( skins )
201 libtiger? ( kate )
202 qt4? ( X !qt5 )
203 qt5? ( X !qt4 )
204 sdl? ( X )
205 skins? ( truetype X ^^ ( qt4 qt5 ) )
206 vaapi? ( avcodec X )
207 vlm? ( encode )
208 xv? ( xcb )
209 "
210
211 S="${WORKDIR}/${MY_P}"
212
213 pkg_setup() {
214 if [[ "${MERGE_TYPE}" != "binary" && "$(tc-getCC)" == *"gcc"* ]] ; then
215 if [[ $(gcc-major-version) < 4 || ( $(gcc-major-version) == 4 && $(gcc-minor-version) < 5 ) ]] ; then
216 die "You need to have at least >=sys-devel/gcc-4.5 to build and/or have a working vlc, see bug #426754."
217 fi
218 fi
219 }
220
221 src_unpack() {
222 if [ "${PV%9999}" != "${PV}" ] ; then
223 git-r3_src_unpack
224 else
225 unpack ${A}
226 fi
227 }
228
229 src_prepare() {
230 # Remove unnecessary warnings about unimplemented pragmas on gcc for now.
231 # Need to recheck this with gcc 4.9 and every subsequent minor bump of gcc.
232 #
233 # config.h:792: warning: ignoring #pragma STDC FENV_ACCESS [-Wunknown-pragmas]
234 # config.h:793: warning: ignoring #pragma STDC FP_CONTRACT [-Wunknown-pragmas]
235 #
236 # http://gcc.gnu.org/c99status.html
237 if [[ "$(tc-getCC)" == *"gcc"* ]] ; then
238 sed -i 's/ifndef __FAST_MATH__/if 0/g' configure.ac || die
239 fi
240
241 # Bootstrap when we are on a git checkout.
242 if [[ "${PV%9999}" != "${PV}" ]] ; then
243 ./bootstrap
244 fi
245
246 # Make it build with libtool 1.5
247 rm -f m4/lt* m4/libtool.m4 || die
248
249 # We are not in a real git checkout due to the absence of a .git directory.
250 touch src/revision.txt || die
251
252 # Fix build system mistake.
253 epatch "${FILESDIR}"/${PN}-2.1.0-fix-libtremor-libs.patch
254
255 # Patch up incompatibilities and reconfigure autotools.
256 epatch "${FILESDIR}"/${P}-libva-1.2.1-compat.patch
257
258 # Fix up broken audio when skipping using a fixed reversed bisected commit.
259 epatch "${FILESDIR}"/${PN}-2.1.0-TomWij-bisected-PA-broken-underflow.patch
260
261 # Don't use --started-from-file when not using dbus.
262 if ! use dbus ; then
263 sed -i 's/ --started-from-file//' share/vlc.desktop.in || die
264 fi
265
266 epatch_user
267
268 eautoreconf
269
270 # Disable automatic running of tests.
271 find . -name 'Makefile.in' -exec sed -i 's/\(..*\)check-TESTS/\1/' {} \; || die
272
273 # If qtchooser is installed, it may break the build, because moc,rcc and uic binaries for wrong qt version may be used.
274 # Setting QT_SELECT environment variable will enforce correct binaries.
275 if use qt4; then
276 export QT_SELECT=qt4
277 elif use qt5; then
278 export QT_SELECT=qt5
279 fi
280 }
281
282 src_configure() {
283 # Compatibility fix for Samba 4.
284 use samba && append-cppflags "-I/usr/include/samba-4.0"
285
286 # We need to disable -fstack-check if use >=gcc 4.8.0.
287 # See bug #499996
288 use x86 && append-cflags $(test-flags-CC -fno-stack-check)
289
290 # Needs libresid-builder from libsidplay:2 which is in another directory...
291 # FIXME!
292 append-ldflags "-L/usr/$(get_libdir)/sidplay/builders/"
293
294 if use truetype || use projectm ; then
295 local dejavu="/usr/share/fonts/dejavu/"
296 myconf="--with-default-font=${dejavu}/DejaVuSans.ttf \
297 --with-default-font-family=Sans \
298 --with-default-monospace-font=${dejavu}/DejaVuSansMono.ttf
299 --with-default-monospace-font-family=Monospace"
300 fi
301
302 local qt_flag=""
303 if use qt4 || use qt5 ; then
304 qt_flag="--enable-qt"
305 fi
306
307 econf \
308 ${myconf} \
309 --enable-vlc \
310 --docdir=/usr/share/doc/${PF} \
311 --disable-dependency-tracking \
312 --disable-optimizations \
313 --disable-update-check \
314 --enable-fast-install \
315 --enable-screen \
316 $(use_enable a52) \
317 $(use_enable aalib aa) \
318 $(use_enable alsa) \
319 $(use_enable altivec) \
320 $(use_enable atmo) \
321 $(use_enable audioqueue) \
322 $(use_enable avcodec) \
323 $(use_enable avformat) \
324 $(use_enable bidi fribidi) \
325 $(use_enable bluray) \
326 $(use_enable cdda vcd) \
327 $(use_enable cddb libcddb) \
328 $(use_enable chromaprint) \
329 $(use_enable dbus) \
330 $(use_enable directfb) \
331 $(use_enable directx) \
332 $(use_enable dc1394) \
333 $(use_enable debug) \
334 $(use_enable dts dca) \
335 $(use_enable dvbpsi) \
336 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
337 $(use_enable dxva2) \
338 $(use_enable encode sout) \
339 $(use_enable faad) \
340 $(use_enable fdk fdkaac) \
341 $(use_enable flac) \
342 $(use_enable fluidsynth) \
343 $(use_enable fontconfig) \
344 $(use_enable gcrypt libgcrypt) \
345 $(use_enable gme) \
346 $(use_enable gnome gnomevfs) \
347 $(use_enable gnutls) \
348 $(use_enable growl) \
349 $(use_enable httpd) \
350 $(use_enable ieee1394 dv1394) \
351 $(use_enable jack) \
352 $(use_enable jpeg) \
353 $(use_enable kate) \
354 $(use_with kde kde-solid) \
355 $(use_enable libass) \
356 $(use_enable libcaca caca) \
357 $(use_enable libnotify notify) \
358 $(use_enable libsamplerate samplerate) \
359 $(use_enable libtar) \
360 $(use_enable libtiger tiger) \
361 $(use_enable linsys) \
362 $(use_enable lirc) \
363 $(use_enable live live555) \
364 $(use_enable lua) \
365 $(use_enable macosx-dialog-provider) \
366 $(use_enable macosx-eyetv) \
367 $(use_enable macosx-qtkit) \
368 $(use_enable macosx-quartztext) \
369 $(use_enable matroska mkv) \
370 $(use_enable cpu_flags_x86_mmx mmx) \
371 $(use_enable modplug mod) \
372 $(use_enable mp3 mad) \
373 $(use_enable mpeg libmpeg2) \
374 $(use_enable mtp) \
375 $(use_enable musepack mpc) \
376 $(use_enable ncurses) \
377 $(use_enable neon) \
378 $(use_enable ogg) $(use_enable ogg mux_ogg) \
379 $(use_enable omxil) \
380 $(use_enable omxil omxil-vout) \
381 $(use_enable opencv) \
382 $(use_enable opengl glspectrum) \
383 $(use_enable opus) \
384 $(use_enable optimisememory optimize-memory) \
385 $(use_enable png) \
386 $(use_enable postproc) \
387 $(use_enable projectm) \
388 $(use_enable pulseaudio pulse) \
389 ${qt_flag} \
390 $(use_enable rdp freerdp) \
391 $(use_enable rtsp realrtsp) \
392 $(use_enable run-as-root) \
393 $(use_enable samba smbclient) \
394 $(use_enable schroedinger) \
395 $(use_enable sdl) \
396 $(use_enable sdl-image) \
397 $(use_enable sid) \
398 $(use_enable sftp) \
399 $(use_enable shout) \
400 $(use_enable skins skins2) \
401 $(use_enable speex) \
402 $(use_enable cpu_flags_x86_sse sse) \
403 $(use_enable svg) \
404 $(use_enable svg svgdec) \
405 $(use_enable swscale) \
406 $(use_enable taglib) \
407 $(use_enable theora) \
408 $(use_enable tremor) \
409 $(use_enable truetype freetype) \
410 $(use_enable twolame) \
411 $(use_enable udev) \
412 $(use_enable upnp) \
413 $(use_enable v4l v4l2) \
414 $(use_enable vaapi libva) \
415 $(use_enable vcdx) \
416 $(use_enable vdpau) \
417 $(use_enable vlm) \
418 $(use_enable vnc) \
419 $(use_enable vorbis) \
420 $(use_enable vpx) \
421 $(use_enable wma-fixed) \
422 $(use_with X x) \
423 $(use_enable x264) \
424 $(use_enable xcb) \
425 $(use_enable xml libxml2) \
426 $(use_enable xv xvideo) \
427 $(use_enable x265) \
428 $(use_enable zeroconf bonjour) \
429 $(use_enable zvbi) $(use_enable !zvbi telx) \
430 --disable-asdcp \
431 --disable-coverage \
432 --disable-cprof \
433 --disable-crystalhd \
434 --disable-decklink \
435 --disable-gles1 \
436 --disable-gles2 \
437 --disable-goom \
438 --disable-kai \
439 --disable-kva \
440 --disable-maintainer-mode \
441 --disable-merge-ffmpeg \
442 --disable-mfx \
443 --disable-mmal-codec \
444 --disable-mmal-vout \
445 --disable-opensles \
446 --disable-oss \
447 --disable-quicktime \
448 --disable-rpi-omxil \
449 --disable-shine \
450 --disable-sndio \
451 --disable-vda \
452 --disable-vsxu \
453 --disable-wasapi
454
455 # ^ We don't have these disabled libraries in the Portage tree yet.
456
457 # _FORTIFY_SOURCE is set to 2 in config.h, which is also the default value on Gentoo.
458 # Other values of _FORTIFY_SOURCE may break the build (bug 523144), so definition should not be removed from config.h.
459 # To prevent redefinition warnings, we undefine _FORTIFY_SOURCE at the very start of config.h file
460 sed -i '1i#undef _FORTIFY_SOURCE' "${S}"/config.h || die
461 }
462
463 src_test() {
464 Xemake check-TESTS
465 }
466
467 DOCS="AUTHORS THANKS NEWS README doc/fortunes.txt doc/intf-vcd.txt"
468
469 src_install() {
470 default
471
472 # Punt useless libtool's .la files
473 find "${D}" -name '*.la' -delete
474 }
475
476 pkg_postinst() {
477 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
478 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
479 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
480 else
481 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
482 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
483 ewarn "If you do not do it, vlc will take a long time to load."
484 fi
485 }

  ViewVC Help
Powered by ViewVC 1.1.20