/[gentoo-x86]/net-im/licq/licq-1.3.8.ebuild
Gentoo

Contents of /net-im/licq/licq-1.3.8.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Tue Jan 5 12:01:05 2010 UTC (8 years, 4 months ago) by ssuominen
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +1 -1 lines
FILE REMOVED
Fix memory leak and hebrew support wrt #299734, thanks to Andy Crook for reporting. Remove USE="kde" since it's broken (upstream) with default Oxygen theme wrt #296929, thanks to Marcel Semancik for reporting.
(Portage version: 2.2_rc61/cvs/Linux x86_64)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-im/licq/licq-1.3.8.ebuild,v 1.2 2009/12/14 14:23:16 ssuominen Exp $
4
5 EAPI=2
6 CMAKE_USE_DIR="${S}/plugins/qt4-gui"
7 inherit cmake-utils
8
9 DESCRIPTION="ICQ Client with v8 support"
10 HOMEPAGE="http://www.licq.org/"
11 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
12
13 LICENSE="GPL-2"
14 SLOT="2"
15 KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
16 IUSE="debug linguas_he ncurses msn nls crypt kde socks5 ssl qt4 xosd"
17
18 RDEPEND="crypt? ( >=app-crypt/gpgme-1 )
19 ncurses? ( sys-libs/ncurses
20 dev-libs/cdk )
21 ssl? ( >=dev-libs/openssl-0.9.5a )
22 qt4? ( x11-libs/qt-gui:4
23 kde? ( >=kde-base/kdelibs-4
24 !kde-base/kdelibs[kdeprefix] ) )
25 xosd? ( x11-libs/xosd )"
26 DEPEND="${RDEPEND}
27 nls? ( sys-devel/gettext )
28 dev-libs/boost"
29
30 pkg_setup() {
31 licq_plugins="auto-reply email rms"
32 use ncurses && licq_plugins="${licq_plugins} console"
33 use msn && licq_plugins="${licq_plugins} msn"
34 use xosd && licq_plugins="${licq_plugins} osd"
35 }
36
37 src_configure() {
38 econf \
39 $(use_enable linguas_he hebrew) \
40 --disable-dependency-tracking \
41 $(use_enable debug) \
42 $(use_enable socks5) \
43 $(use_enable ssl openssl) \
44 $(use_enable nls)
45
46 local x
47 for x in ${licq_plugins}; do
48 cd "${S}"/plugins/${x}
49 econf
50 done
51
52 mycmakeargs="${mycmakeargs}
53 $(cmake-utils_use_with kde)"
54 use qt4 && cmake-utils_src_configure
55 }
56
57 src_compile() {
58 emake || die
59
60 local x
61 for x in ${licq_plugins}; do
62 cd "${S}"/plugins/${x}
63 emake || die
64 done
65
66 use qt4 && cmake-utils_src_compile
67 }
68
69 src_install() {
70 emake DESTDIR="${D}" install || die
71 dodoc README
72
73 docinto doc
74 dodoc doc/*
75
76 use crypt && dodoc README.GPG
77 use ssl && dodoc README.OPENSSL
78
79 exeinto /usr/share/${PN}/upgrade
80 doexe upgrade/*.pl || die
81
82 local x
83 for x in ${licq_plugins}; do
84 cd "${S}"/plugins/${x}
85 emake DESTDIR="${D}" install || die
86 docinto ${x}
87 dodoc README* *.conf
88 done
89
90 if use qt4; then
91 docinto qt4
92 DOCS="README" cmake-utils_src_install
93 fi
94
95 rm -rf "${D}"/var
96 }

  ViewVC Help
Powered by ViewVC 1.1.20