/[gentoo-x86]/net-irc/kvirc/kvirc-9999.ebuild
Gentoo

Contents of /net-irc/kvirc/kvirc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.39 - (show annotations) (download)
Wed Dec 31 13:38:03 2014 UTC (3 years, 6 months ago) by kensington
Branch: MAIN
CVS Tags: HEAD
Changes since 1.38: +3 -3 lines
Enforce USE dependency for media-libs/phonon.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-irc/kvirc/kvirc-9999.ebuild,v 1.38 2013/10/17 20:51:41 floppym Exp $
4
5 EAPI="5"
6 PYTHON_DEPEND="python? 2"
7
8 inherit cmake-utils flag-o-matic multilib python subversion
9
10 DESCRIPTION="Advanced IRC Client"
11 HOMEPAGE="http://www.kvirc.net/"
12 SRC_URI=""
13 ESVN_REPO_URI="https://svn.kvirc.de/svn/trunk/kvirc"
14 ESVN_PROJECT="kvirc"
15
16 LICENSE="kvirc"
17 SLOT="4"
18 KEYWORDS=""
19 IUSE="audiofile dcc_video +dcc_voice debug doc gsm +ipc ipv6 kde +nls oss +perl +phonon profile +python +qt-dbus +ssl theora +transparency webkit"
20
21 RDEPEND=">=dev-qt/qtcore-4.6:4
22 >=dev-qt/qtgui-4.6:4
23 >=dev-qt/qtsql-4.6:4
24 sys-libs/zlib
25 x11-libs/libX11
26 dcc_video? (
27 media-libs/libv4l
28 theora? ( media-libs/libogg media-libs/libtheora )
29 )
30 kde? ( >=kde-base/kdelibs-4 )
31 oss? ( audiofile? ( media-libs/audiofile ) )
32 perl? ( dev-lang/perl )
33 phonon? ( || ( media-libs/phonon[qt4] >=dev-qt/qtphonon-4.6:4 ) )
34 qt-dbus? ( >=dev-qt/qtdbus-4.6:4 )
35 ssl? ( dev-libs/openssl )
36 webkit? ( >=dev-qt/qtwebkit-4.6:4 )"
37 DEPEND="${RDEPEND}
38 virtual/pkgconfig
39 x11-proto/scrnsaverproto
40 nls? ( sys-devel/gettext )
41 doc? ( app-doc/doxygen )"
42 RDEPEND="${RDEPEND}
43 gsm? ( media-sound/gsm )"
44 REQUIRED_USE="audiofile? ( oss ) theora? ( dcc_video )"
45
46 DOCS="ChangeLog doc/FAQ"
47
48 pkg_setup() {
49 if use python; then
50 python_set_active_version 2
51 python_pkg_setup
52 fi
53 }
54
55 src_prepare() {
56 subversion_wc_info
57 VERSIO_PRAESENS="${ESVN_WC_REVISION}"
58 einfo "Setting of revision number to ${VERSIO_PRAESENS}"
59 sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" r${VERSIO_PRAESENS}\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
60 }
61
62 src_configure() {
63 append-flags -fno-strict-aliasing
64
65 local libdir="$(get_libdir)"
66 local mycmakeargs=(
67 -DLIB_SUFFIX=${libdir#lib}
68 -DMANUAL_REVISION=${VERSIO_PRAESENS}
69 -DWANT_COEXISTENCE=1
70 -DWANT_CRYPT=1
71 -DWANT_ENV_FLAGS=1
72 -DWANT_VERBOSE=1
73 $(cmake-utils_use_want audiofile AUDIOFILE)
74 $(cmake-utils_use_want dcc_video DCC_VIDEO)
75 $(cmake-utils_use_want dcc_voice DCC_VOICE)
76 $(cmake-utils_use_want debug DEBUG)
77 $(cmake-utils_use_want doc DOXYGEN)
78 $(cmake-utils_use_want gsm GSM)
79 $(cmake-utils_use_want ipc IPC)
80 $(cmake-utils_use_want ipv6 IPV6)
81 $(cmake-utils_use_want kde KDE4)
82 $(cmake-utils_use_want nls GETTEXT)
83 $(cmake-utils_use_want oss OSS)
84 $(cmake-utils_use_want perl PERL)
85 $(cmake-utils_use_want phonon PHONON)
86 $(cmake-utils_use_want profile MEMORY_PROFILE)
87 $(cmake-utils_use_want python PYTHON)
88 $(cmake-utils_use_want qt-dbus QTDBUS)
89 $(cmake-utils_use_want ssl OPENSSL)
90 $(cmake-utils_use_want theora OGG_THEORA)
91 $(cmake-utils_use_want transparency TRANSPARENCY)
92 $(cmake-utils_use_want webkit QTWEBKIT)
93 )
94
95 cmake-utils_src_configure
96 }

  ViewVC Help
Powered by ViewVC 1.1.20