/[gentoo-x86]/net-libs/daq/daq-2.0.2.ebuild
Gentoo

Contents of /net-libs/daq/daq-2.0.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Fri Jul 18 14:40:40 2014 UTC (6 years, 4 months ago) by jer
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +19 -19 lines
EAPI bump. Sort dependencies into neat piles.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A792A613)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/daq/daq-2.0.2.ebuild,v 1.2 2014/06/03 16:54:59 vapier Exp $
4
5 EAPI=5
6 inherit eutils multilib autotools
7
8 DESCRIPTION="Data Acquisition library, for packet I/O"
9 HOMEPAGE="http://www.snort.org/"
10 SRC_URI="http://www.snort.org/downloads/2778 -> ${P}.tar.gz"
11
12 LICENSE="GPL-2"
13 SLOT="0"
14 KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~sparc ~x86"
15 IUSE="ipv6 +afpacket +dump +pcap nfq ipq static-libs"
16
17 PCAP_DEPEND=">=net-libs/libpcap-1.0.0"
18 IPT_DEPEND="
19 >=net-firewall/iptables-1.4.10
20 dev-libs/libdnet
21 net-libs/libnetfilter_queue
22
23 "
24 DEPEND="
25 dump? ( ${PCAP_DEPEND} )
26 ipq? ( ${IPT_DEPEND} )
27 nfq? ( ${IPT_DEPEND} )
28 pcap? ( ${PCAP_DEPEND} )
29 "
30 RDEPEND="${DEPEND}"
31
32 src_prepare() {
33 epatch "${FILESDIR}"/${P}-parallel-grammar.patch #511892
34 epatch "${FILESDIR}"/${P}-libpcap-check.patch
35 eautoreconf
36 }
37
38 src_configure() {
39 # We forced libpcap to 1.x, so we can set this cache var so
40 # cross-compiling doesn't break on us.
41 daq_cv_libpcap_version_1x=yes \
42 econf \
43 $(use_enable ipv6) \
44 $(use_enable pcap pcap-module) \
45 $(use_enable afpacket afpacket-module) \
46 $(use_enable dump dump-module) \
47 $(use_enable nfq nfq-module) \
48 $(use_enable ipq ipq-module) \
49 $(use_enable static-libs static) \
50 --disable-ipfw-module \
51 --disable-bundled-modules
52 }
53
54 DOCS=( ChangeLog README )
55
56 src_install() {
57 default
58
59 prune_libtool_files
60
61 # If not using static-libs don't install the static libraries
62 # This has been bugged upstream
63 if ! use static-libs; then
64 for z in libdaq_static libdaq_static_modules; do
65 rm "${D}"usr/$(get_libdir)/${z}.a
66 done
67 fi
68 }
69
70 pkg_postinst() {
71 einfo "The Data Acquisition library (DAQ) for packet I/O replaces direct"
72 einfo "calls to PCAP functions with an abstraction layer that facilitates"
73 einfo "operation on a variety of hardware and software interfaces without"
74 einfo "requiring changes to application such as Snort."
75 einfo
76 einfo "Please see the README file for DAQ for information about specific"
77 einfo "DAQ modules."
78 }

  ViewVC Help
Powered by ViewVC 1.1.20