/[gentoo-x86]/net-libs/glib-networking/glib-networking-2.42.1.ebuild
Gentoo

Contents of /net-libs/glib-networking/glib-networking-2.42.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.11 - (show annotations) (download)
Thu Jul 30 13:23:59 2015 UTC (5 years, 4 months ago) by ago
Branch: MAIN
CVS Tags: HEAD
Changes since 1.10: +2 -2 lines
Stable for sparc, wrt bug #551814

(Portage version: 2.2.20/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key 7194459F)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/glib-networking/glib-networking-2.42.1.ebuild,v 1.10 2015/07/29 10:31:43 klausman Exp $
4
5 EAPI="5"
6 GCONF_DEBUG="no"
7 GNOME2_LA_PUNT="yes"
8
9 inherit autotools eutils gnome2 multilib-minimal virtualx
10
11 DESCRIPTION="Network-related giomodules for glib"
12 HOMEPAGE="http://git.gnome.org/browse/glib-networking/"
13
14 LICENSE="LGPL-2+"
15 SLOT="0"
16 IUSE="+gnome +libproxy smartcard +ssl test"
17 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
18
19 RDEPEND="
20 >=dev-libs/glib-2.42:2[${MULTILIB_USEDEP}]
21 gnome? ( gnome-base/gsettings-desktop-schemas )
22 libproxy? ( >=net-libs/libproxy-0.4.11-r1:=[${MULTILIB_USEDEP}] )
23 smartcard? (
24 >=app-crypt/p11-kit-0.18.4[${MULTILIB_USEDEP}]
25 >=net-libs/gnutls-3:=[pkcs11,${MULTILIB_USEDEP}] )
26 ssl? (
27 app-misc/ca-certificates
28 >=net-libs/gnutls-3:=[${MULTILIB_USEDEP}] )
29 "
30 DEPEND="${RDEPEND}
31 >=dev-util/intltool-0.35.0
32 sys-devel/gettext
33 >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
34 test? ( sys-apps/dbus[X] )
35 "
36 # eautoreconf needs >=sys-devel/autoconf-2.65:2.5
37
38 src_prepare() {
39 # Fix test build failure with USE=-smartcard
40 epatch "${FILESDIR}"/${PN}-2.40.1-unittests.patch
41
42 eautoreconf
43 gnome2_src_prepare
44 }
45
46 multilib_src_configure() {
47 ECONF_SOURCE=${S} \
48 gnome2_src_configure \
49 --disable-static \
50 --with-ca-certificates="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
51 $(use_with gnome gnome-proxy) \
52 $(use_with libproxy) \
53 $(use_with smartcard pkcs11) \
54 $(use_with ssl gnutls)
55 }
56
57 multilib_src_test() {
58 # non-native tests fail if glib-networking is already installed.
59 # have no idea what's wrong. would appreciate some help.
60 multilib_is_native_abi || return 0
61
62 Xemake check
63 }
64
65 multilib_src_install() {
66 gnome2_src_install
67 }

  ViewVC Help
Powered by ViewVC 1.1.20