/[gentoo-x86]/net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild
Gentoo

Contents of /net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Sun Jun 21 08:54:05 2015 UTC (5 years, 5 months ago) by jer
Branch: MAIN
CVS Tags: HEAD
Changes since 1.3: +3 -3 lines
Stable for PPC64 (bug #551814).

(Portage version: 2.2.20/cvs/Linux x86_64, RepoMan options: --ignore-arches, signed Manifest commit with key A792A613)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild,v 1.3 2014/10/23 14:29:55 pacho Exp $
4
5 EAPI=5
6
7 PYTHON_COMPAT=( python2_7 )
8 AUTOTOOLS_AUTORECONF=true
9
10 inherit eutils gnome.org python-r1 multilib-minimal
11
12 DESCRIPTION="Library to handle UPnP IGD port mapping for GUPnP"
13 HOMEPAGE="http://gupnp.org"
14
15 LICENSE="LGPL-2"
16 SLOT="0"
17 KEYWORDS="~alpha amd64 ~arm hppa ~ia64 ~ppc ppc64 ~sparc x86"
18 IUSE="+introspection python"
19
20 RDEPEND="
21 >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
22 >=net-libs/gssdp-0.14.7[${MULTILIB_USEDEP}]
23 >=net-libs/gupnp-0.20.10[${MULTILIB_USEDEP}]
24 introspection? ( >=dev-libs/gobject-introspection-0.10 )
25 python? (
26 >=dev-libs/gobject-introspection-0.10
27 >=dev-python/pygobject-2.16:2[${PYTHON_USEDEP}]
28 )"
29 DEPEND="${RDEPEND}
30 dev-util/gtk-doc-am
31 sys-devel/gettext
32 >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
33 "
34
35 # The only existing test is broken
36 RESTRICT="test"
37
38 PATCHES=(
39 "${FILESDIR}"/${PN}-0.1.11-disable_static_modules.patch
40 )
41
42 multilib_src_configure() {
43 local myconf=(
44 --disable-static
45 --disable-gtk-doc
46 $(multilib_native_use_enable introspection)
47 # python is built separately
48 --disable-python
49 )
50
51 ECONF_SOURCE=${S} \
52 econf "${myconf[@]}"
53
54 if multilib_is_native_abi; then
55 ln -s "${S}"/doc/html doc/html || die
56
57 python_configure() {
58 mkdir -p "${BUILD_DIR}" || die
59 cd "${BUILD_DIR}" || die
60
61 ECONF_SOURCE=${S} \
62 econf "${myconf[@]}" \
63 --enable-python
64 }
65
66 use python && python_parallel_foreach_impl python_configure
67 fi
68 }
69
70 multilib_src_compile() {
71 default
72
73 if multilib_is_native_abi && use python; then
74 local native_builddir=${BUILD_DIR}
75
76 python_compile() {
77 emake -C "${BUILD_DIR}"/python \
78 VPATH="${S}/python:${native_builddir}/python" \
79 igd_la_LIBADD="\$(PYGUPNP_IGD_LIBS) ${native_builddir}/libgupnp-igd/libgupnp-igd-1.0.la"
80 }
81
82 python_foreach_impl python_compile
83 fi
84 }
85
86 multilib_src_install() {
87 default
88
89 if multilib_is_native_abi && use python; then
90 local native_builddir=${BUILD_DIR}
91
92 python_install() {
93 emake -C "${BUILD_DIR}"/python \
94 VPATH="${S}/python:${native_builddir}/python" \
95 DESTDIR="${D}" install
96 }
97
98 python_foreach_impl python_install
99 fi
100 }
101
102 multilib_src_install_all() {
103 einstalldocs
104 prune_libtool_files
105 }

  ViewVC Help
Powered by ViewVC 1.1.20