/[gentoo-x86]/net-libs/ldns/ldns-1.6.17.ebuild
Gentoo

Contents of /net-libs/ldns/ldns-1.6.17.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.9 - (show annotations) (download)
Fri May 8 05:05:41 2015 UTC (5 years, 2 months ago) by jer
Branch: MAIN
CVS Tags: HEAD
Changes since 1.8: +2 -2 lines
Stable for PPC64 (bug #525270).

(Portage version: 2.2.18/cvs/Linux x86_64, RepoMan options: --ignore-arches, signed Manifest commit with key A792A613)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/ldns/ldns-1.6.17.ebuild,v 1.8 2015/03/02 09:34:29 ago Exp $
4
5 EAPI="5"
6 PYTHON_COMPAT=( python2_7 )
7
8 inherit eutils multilib-minimal python-single-r1
9
10 DESCRIPTION="a library with the aim to simplify DNS programming in C"
11 HOMEPAGE="http://www.nlnetlabs.nl/projects/ldns/"
12 SRC_URI="http://www.nlnetlabs.nl/downloads/${PN}/${P}.tar.gz"
13
14 LICENSE="BSD"
15 SLOT="0"
16 KEYWORDS="alpha amd64 arm hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~ppc-macos ~x64-macos ~x64-solaris"
17 IUSE="dane doc +ecdsa gost python +ssl static-libs vim-syntax"
18
19 # configure will die if ecdsa is enabled and ssl is not
20 REQUIRED_USE="ecdsa? ( ssl )
21 python? ( ${PYTHON_REQUIRED_USE} )"
22
23 RDEPEND="
24 dane? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
25 ecdsa? ( >=dev-libs/openssl-1.0.1h-r2:0[-bindist,${MULTILIB_USEDEP}] )
26 gost? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
27 python? ( ${PYTHON_DEPS} )
28 ssl? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
29 "
30 DEPEND="${RDEPEND}
31 python? ( dev-lang/swig )
32 doc? ( app-doc/doxygen )
33 "
34
35 RESTRICT="test" # 1.6.9 has no test directory
36
37 MULTILIB_CHOST_TOOLS=(
38 /usr/bin/ldns-config
39 )
40
41 pkg_setup() {
42 use python && python-single-r1_pkg_setup
43 }
44
45 multilib_src_configure() {
46 ECONF_SOURCE=${S} \
47 econf \
48 $(use_enable static-libs static) \
49 $(use_enable ssl sha2) \
50 $(use_enable gost) \
51 $(use_enable ecdsa) \
52 $(use_enable dane) \
53 $(use_with ssl ssl "${EPREFIX}"/usr) \
54 $(multilib_native_use_with python pyldns) \
55 $(multilib_native_use_with python pyldnsx) \
56 --without-drill \
57 --without-examples \
58 --disable-rpath
59 }
60
61 multilib_src_compile() {
62 default
63
64 if multilib_is_native_abi && use doc ; then
65 emake doxygen
66 fi
67 }
68
69 multilib_src_install() {
70 default
71
72 if multilib_is_native_abi && use doc ; then
73 dohtml -r doc/html/.
74 fi
75 }
76
77 multilib_src_install_all() {
78 dodoc Changelog README*
79
80 prune_libtool_files --modules
81 use python && python_optimize
82
83 if use vim-syntax ; then
84 insinto /usr/share/vim/vimfiles/ftdetect
85 doins libdns.vim
86 fi
87
88 einfo
89 elog "Install net-dns/ldns-utils if you want drill and examples"
90 einfo
91 }

  ViewVC Help
Powered by ViewVC 1.1.20