/[gentoo-x86]/net-libs/libvncserver/libvncserver-0.9.10.ebuild
Gentoo

Contents of /net-libs/libvncserver/libvncserver-0.9.10.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.9 - (show annotations) (download)
Thu May 21 16:32:20 2015 UTC (5 years, 6 months ago) by maekke
Branch: MAIN
CVS Tags: HEAD
Changes since 1.8: +2 -2 lines
arm stable, bug #523590

(Portage version: 2.2.19/cvs/Linux x86_64, RepoMan options: --include-arches="arm", signed Manifest commit with key 072AD062)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/libvncserver/libvncserver-0.9.10.ebuild,v 1.8 2015/04/21 18:43:19 pacho Exp $
4
5 EAPI="5"
6
7 inherit autotools multilib-minimal
8
9 DESCRIPTION="library for creating vnc servers"
10 HOMEPAGE="http://libvncserver.sourceforge.net/"
11 SRC_URI="https://github.com/LibVNC/libvncserver/archive/LibVNCServer-${PV}.tar.gz"
12
13 LICENSE="GPL-2"
14 SLOT="0"
15 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
16 IUSE="+24bpp gcrypt gnutls ipv6 +jpeg +png ssl static-libs test threads vaapi +zlib"
17
18 DEPEND="
19 gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
20 gnutls? (
21 >=net-libs/gnutls-2.12.23-r6[${MULTILIB_USEDEP}]
22 >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}]
23 )
24 !gnutls? (
25 ssl? ( >=dev-libs/openssl-1.0.1h-r2[${MULTILIB_USEDEP}] )
26 )
27 jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
28 png? ( >=media-libs/libpng-1.6.10:0[${MULTILIB_USEDEP}] )
29 vaapi? ( >=x11-libs/libva-1.2.1-r1[${MULTILIB_USEDEP}] )
30 zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
31 RDEPEND="${DEPEND}"
32
33 S="${WORKDIR}"/${PN}-LibVNCServer-${PV}
34
35 DOCS=( AUTHORS ChangeLog NEWS README TODO )
36
37 src_prepare() {
38 # https://github.com/LibVNC/libvncserver/issues/11
39 epatch "${FILESDIR}/${P}-libva-1.0.patch"
40
41 sed -i -r \
42 -e "/^SUBDIRS/s:\<$(usex test 'test|' '')client_examples|examples\>::g" \
43 Makefile.am || die
44
45 eautoreconf
46 }
47
48 multilib_src_configure() {
49 ECONF_SOURCE=${S} \
50 econf \
51 --disable-silent-rules \
52 $(use_enable static-libs static) \
53 $(use_with 24bpp) \
54 $(use_with gnutls) \
55 $(usex gnutls --with-gcrypt $(use_with gcrypt)) \
56 $(usex gnutls --without-ssl $(use_with ssl)) \
57 $(use_with ipv6) \
58 $(use_with jpeg) \
59 $(use_with png) \
60 $(use_with threads pthread) \
61 $(use_with zlib)
62 }
63
64 multilib_src_install_all() {
65 einstalldocs
66 prune_libtool_files
67 }

  ViewVC Help
Powered by ViewVC 1.1.20