net-libs/neon/neon-0.29.6-r1.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/neon/neon-0.29.6-r1.ebuild,v 1.14 2012/09/05 19:43:54 floppym Exp $

EAPI="4"

inherit autotools eutils libtool

DESCRIPTION="HTTP and WebDAV client library"
HOMEPAGE="http://www.webdav.org/neon/"
SRC_URI="http://www.webdav.org/neon/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="doc expat gnutls kerberos libproxy nls pkcs11 ssl static-libs zlib"
IUSE_LINGUAS="cs de fr ja nn pl ru tr zh_CN"
for lingua in ${IUSE_LINGUAS}; do
        IUSE+=" linguas_${lingua}"
done
unset lingua
RESTRICT="test"

RDEPEND="expat? ( dev-libs/expat )
        !expat? ( dev-libs/libxml2 )
        gnutls? (
                app-misc/ca-certificates
                >=net-libs/gnutls-2.0
                pkcs11? ( dev-libs/pakchois )
        )
        !gnutls? ( ssl? (
                >=dev-libs/openssl-0.9.6f
                pkcs11? ( dev-libs/pakchois )
        ) )
        kerberos? ( virtual/krb5 )
        libproxy? ( net-libs/libproxy )
        nls? ( virtual/libintl )
        zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
        virtual/pkgconfig"

src_prepare() {
        local lingua linguas
        for lingua in ${IUSE_LINGUAS}; do
                use linguas_${lingua} && linguas+=" ${lingua}"
        done
        sed -i -e "s/ALL_LINGUAS=.*/ALL_LINGUAS=\"${linguas}\"/g" configure.in

        epatch "${FILESDIR}"/${PN}-0.29.6-no-ssl-check.patch
        epatch "${FILESDIR}"/${PN}-0.29.6-gnutls-3-functions.patch
        epatch "${FILESDIR}"/${PN}-0.29.6-gnutls-3-types.patch
        AT_M4DIR="macros" eautoreconf

        elibtoolize
}

src_configure() {
        local myconf=()

        if has_version sys-libs/glibc; then
                einfo "Enabling SSL library thread-safety using POSIX threads..."
                myconf+=(--enable-threadsafe-ssl=posix)
        fi

        if use expat; then
                myconf+=(--with-expat)
        else
                myconf+=(--with-libxml2)
        fi

        if use gnutls; then
                myconf+=(--with-ssl=gnutls --with-ca-bundle="${EPREFIX}/etc/ssl/certs/ca-certificates.crt")
        elif use ssl; then
                myconf+=(--with-ssl=openssl)
        fi

        # work around broken check, we really need -lintl on Solaris
        [[ ${CHOST} == *-solaris* ]] && export ne_cv_libsfor_bindtextdomain=-lintl

        econf \
                --enable-shared \
                $(use_with kerberos gssapi) \
                $(use_with libproxy) \
                $(use_enable nls) \
                $(use_with pkcs11 pakchois) \
                $(use_enable static-libs static) \
                $(use_with zlib) \
                "${myconf[@]}"
}

src_install() {
        emake DESTDIR="${D}" install-lib install-headers install-config install-nls || die "emake install failed"

        find "${ED}" -name "*.la" -print0 | xargs -0 rm -f

        if use doc; then
                emake DESTDIR="${D}" install-docs || die "emake install-docs failed"
        fi

        dodoc AUTHORS BUGS NEWS README THANKS TODO
        doman doc/man/*.[1-8]
}
1	vapier	1.1	# Copyright 1999-2012 Gentoo Foundation
2			# Distributed under the terms of the GNU General Public License v2
3	qnikst	1.15	# $Header: /var/cvsroot/gentoo-x86/net-libs/neon/neon-0.29.6-r1.ebuild,v 1.14 2012/09/05 19:43:54 floppym Exp $
4	vapier	1.1
5	floppym	1.13	EAPI="4"
6	vapier	1.1
7	floppym	1.13	inherit autotools eutils libtool
8	vapier	1.1
9			DESCRIPTION="HTTP and WebDAV client library"
10			HOMEPAGE="http://www.webdav.org/neon/"
11			SRC_URI="http://www.webdav.org/neon/${P}.tar.gz"
12
13			LICENSE="GPL-2"
14			SLOT="0"
15	armin76	1.11	KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
16	vapier	1.1	IUSE="doc expat gnutls kerberos libproxy nls pkcs11 ssl static-libs zlib"
17			IUSE_LINGUAS="cs de fr ja nn pl ru tr zh_CN"
18			for lingua in ${IUSE_LINGUAS}; do
19			IUSE+=" linguas_${lingua}"
20			done
21			unset lingua
22			RESTRICT="test"
23
24			RDEPEND="expat? ( dev-libs/expat )
25			!expat? ( dev-libs/libxml2 )
26			gnutls? (
27			app-misc/ca-certificates
28			>=net-libs/gnutls-2.0
29			pkcs11? ( dev-libs/pakchois )
30			)
31			!gnutls? ( ssl? (
32			>=dev-libs/openssl-0.9.6f
33			pkcs11? ( dev-libs/pakchois )
34			) )
35			kerberos? ( virtual/krb5 )
36			libproxy? ( net-libs/libproxy )
37			nls? ( virtual/libintl )
38			zlib? ( sys-libs/zlib )"
39			DEPEND="${RDEPEND}
40	jdhore	1.2	virtual/pkgconfig"
41	vapier	1.1
42			src_prepare() {
43			local lingua linguas
44			for lingua in ${IUSE_LINGUAS}; do
45			use linguas_${lingua} && linguas+=" ${lingua}"
46			done
47			sed -i -e "s/ALL_LINGUAS=.*/ALL_LINGUAS=\"${linguas}\"/g" configure.in
48
49			epatch "${FILESDIR}"/${PN}-0.29.6-no-ssl-check.patch
50	qnikst	1.15	epatch "${FILESDIR}"/${PN}-0.29.6-gnutls-3-functions.patch
51			epatch "${FILESDIR}"/${PN}-0.29.6-gnutls-3-types.patch
52	vapier	1.1	AT_M4DIR="macros" eautoreconf
53
54			elibtoolize
55			}
56
57			src_configure() {
58	floppym	1.14	local myconf=()
59	vapier	1.1
60			if has_version sys-libs/glibc; then
61			einfo "Enabling SSL library thread-safety using POSIX threads..."
62	floppym	1.14	myconf+=(--enable-threadsafe-ssl=posix)
63	vapier	1.1	fi
64
65			if use expat; then
66	floppym	1.14	myconf+=(--with-expat)
67	vapier	1.1	else
68	floppym	1.14	myconf+=(--with-libxml2)
69	vapier	1.1	fi
70
71			if use gnutls; then
72	floppym	1.14	myconf+=(--with-ssl=gnutls --with-ca-bundle="${EPREFIX}/etc/ssl/certs/ca-certificates.crt")
73	vapier	1.1	elif use ssl; then
74	floppym	1.14	myconf+=(--with-ssl=openssl)
75	vapier	1.1	fi
76
77			# work around broken check, we really need -lintl on Solaris
78			[[ ${CHOST} == -solaris ]] && export ne_cv_libsfor_bindtextdomain=-lintl
79
80			econf \
81			--enable-shared \
82			$(use_with kerberos gssapi) \
83			$(use_with libproxy) \
84			$(use_enable nls) \
85			$(use_with pkcs11 pakchois) \
86			$(use_enable static-libs static) \
87			$(use_with zlib) \
88	floppym	1.14	"${myconf[@]}"
89	vapier	1.1	}
90
91			src_install() {
92			emake DESTDIR="${D}" install-lib install-headers install-config install-nls \|\| die "emake install failed"
93
94			find "${ED}" -name "*.la" -print0 \| xargs -0 rm -f
95
96			if use doc; then
97			emake DESTDIR="${D}" install-docs \|\| die "emake install-docs failed"
98			fi
99
100			dodoc AUTHORS BUGS NEWS README THANKS TODO
101			doman doc/man/*.[1-8]
102			}